<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package experimental;
$experimental::VERSION = '0.032';
use strict;
use warnings;
use version ();

BEGIN { eval { require feature } };
use Carp qw/croak carp/;

my %warnings = map { $_ =&gt; 1 } grep { /^experimental::/ } keys %warnings::Offsets;
my %removed_warnings = map { $_ =&gt; 1 } grep { /^experimental::/ } keys %warnings::NoOp;
my %features = map { $_ =&gt; 1 } $] &gt; 5.015006 ? keys %feature::feature : do {
	my @features;
	if ($] &gt;= 5.010) {
		push @features, qw/switch say state/;
		push @features, 'unicode_strings' if $] &gt; 5.011002;
	}
	@features;
};

my %min_version = (
	args_array_with_signatures =&gt; '5.20.0',
	array_base      =&gt; '5',
	autoderef       =&gt; '5.14.0',
	bitwise         =&gt; '5.22.0',
	builtin         =&gt; '5.35.7',
	const_attr      =&gt; '5.22.0',
	current_sub     =&gt; '5.16.0',
	declared_refs   =&gt; '5.26.0',
	defer           =&gt; '5.35.4',
	evalbytes       =&gt; '5.16.0',
	extra_paired_delimiters =&gt; '5.35.9',
	fc              =&gt; '5.16.0',
	for_list        =&gt; '5.35.5',
	isa             =&gt; '5.31.7',
	lexical_topic   =&gt; '5.10.0',
	lexical_subs    =&gt; '5.18.0',
	postderef       =&gt; '5.20.0',
	postderef_qq    =&gt; '5.20.0',
	refaliasing     =&gt; '5.22.0',
	regex_sets      =&gt; '5.18.0',
	say             =&gt; '5.10.0',
	smartmatch      =&gt; '5.10.0',
	signatures      =&gt; '5.20.0',
	state           =&gt; '5.10.0',
	switch          =&gt; '5.10.0',
	try             =&gt; '5.34.0',
	unicode_eval    =&gt; '5.16.0',
	unicode_strings =&gt; '5.12.0',
);
my %removed_in_version = (
	array_base      =&gt; '5.30.0',
	autoderef       =&gt; '5.24.0',
	lexical_topic   =&gt; '5.24.0',
);

$_ = version-&gt;new($_) for values %min_version;
$_ = version-&gt;new($_) for values %removed_in_version;

my %additional = (
	postderef     =&gt; ['postderef_qq'],
	switch        =&gt; ['smartmatch'],
	declared_refs =&gt; ['refaliasing'],
);

sub _enable {
	my $pragma = shift;
	if ($warnings{"experimental::$pragma"}) {
		warnings-&gt;unimport("experimental::$pragma");
		feature-&gt;import($pragma) if exists $features{$pragma};
		_enable(@{ $additional{$pragma} }) if $additional{$pragma};
	}
	elsif ($features{$pragma}) {
		feature-&gt;import($pragma);
		_enable(@{ $additional{$pragma} }) if $additional{$pragma};
	}
	elsif ($removed_warnings{"experimental::$pragma"}) {
		_enable(@{ $additional{$pragma} }) if $additional{$pragma};
	}
	elsif (not exists $min_version{$pragma}) {
		croak "Can't enable unknown feature $pragma";
	}
	elsif ($] &lt; $min_version{$pragma}) {
		my $stable = $min_version{$pragma}-&gt;stringify;
		$stable =~ s/^ 5\. ([0-9]?[13579]) \. \d+ $/"5." . ($1 + 1) . ".0"/xe;
		croak "Need perl $stable or later for feature $pragma";
	}
	elsif ($] &gt;= ($removed_in_version{$pragma} || 7)) {
		croak "Experimental feature $pragma has been removed from perl in version $removed_in_version{$pragma}";
	}
}

sub import {
	my ($self, @pragmas) = @_;

	for my $pragma (@pragmas) {
		_enable($pragma);
	}
	return;
}

sub _disable {
	my $pragma = shift;
	if ($warnings{"experimental::$pragma"}) {
		warnings-&gt;import("experimental::$pragma");
		feature-&gt;unimport($pragma) if exists $features{$pragma};
		_disable(@{ $additional{$pragma} }) if $additional{$pragma};
	}
	elsif ($features{$pragma}) {
		feature-&gt;unimport($pragma);
		_disable(@{ $additional{$pragma} }) if $additional{$pragma};
	}
	elsif (not exists $min_version{$pragma}) {
		carp "Can't disable unknown feature $pragma, ignoring";
	}
}

sub unimport {
	my ($self, @pragmas) = @_;

	for my $pragma (@pragmas) {
		_disable($pragma);
	}
	return;
}

1;

#ABSTRACT: Experimental features made easy

__END__

=pod

=encoding UTF-8

=head1 NAME

experimental - Experimental features made easy

=head1 VERSION

version 0.032

=head1 SYNOPSIS

 use experimental 'lexical_subs', 'signatures';
 my sub plus_one($value) { $value + 1 }

=head1 DESCRIPTION

This pragma provides an easy and convenient way to enable or disable
experimental features.

Every version of perl has some number of features present but considered
"experimental."  For much of the life of Perl 5, this was only a designation
found in the documentation.  Starting in Perl v5.10.0, and more aggressively in
v5.18.0, experimental features were placed behind pragmata used to enable the
feature and disable associated warnings.

The C&lt;experimental&gt; pragma exists to combine the required incantations into a
single interface stable across releases of perl.  For every experimental
feature, this should enable the feature and silence warnings for the enclosing
lexical scope:

  use experimental 'feature-name';

To disable the feature and, if applicable, re-enable any warnings, use:

  no experimental 'feature-name';

The supported features, documented further below, are:

=over 4

=item * C&lt;args_array_with_signatures&gt; - allow C&lt;@_&gt; to be used in signatured subs.

This is supported on perl 5.20.0 and above, but is likely to be removed in the future.

=item * C&lt;array_base&gt; - allow the use of C&lt;$[&gt; to change the starting index of C&lt;@array&gt;.

This was removed in perl 5.30.0.

=item * C&lt;autoderef&gt; - allow push, each, keys, and other built-ins on references.

This was added in perl 5.14.0 and removed in perl 5.24.0.

=item * C&lt;bitwise&gt; - allow the new stringwise bit operators

This was added in perl 5.22.0.

=item * C&lt;builtin&gt; - allow the use of the functions in the builtin:: namespace

This was added in perl 5.36.0

=item * C&lt;const_attr&gt; - allow the :const attribute on subs

This was added in perl 5.22.0.

=item * C&lt;declared_refs&gt; - enables aliasing via assignment to references

This was added in perl 5.26.0.

=item * C&lt;defer&gt; - enables the use of defer blocks

This was added in perl 5.36.0

=item * C&lt;extra_paired_delimiters&gt; - enables the use of more paired string delimiters than the
traditional four, S&lt;C&lt;&lt; &lt;  &gt; &gt;&gt;&gt;, S&lt;C&lt;( )&gt;&gt;, S&lt;C&lt;{ }&gt;&gt;, and S&lt;C&lt;[ ]&gt;&gt;.

This was added in perl 5.36.

=item * C&lt;for_list&gt; - allows iterating over multiple values at a time with C&lt;for&gt;

This was added in perl 5.36.0

=item * C&lt;isa&gt; - allow the use of the C&lt;isa&gt; infix operator

This was added in perl 5.32.0.

=item * C&lt;lexical_topic&gt; - allow the use of lexical C&lt;$_&gt; via C&lt;my $_&gt;.

This was added in perl 5.10.0 and removed in perl 5.24.0.

=item * C&lt;lexical_subs&gt; - allow the use of lexical subroutines.

This was added in 5.18.0, and became non-experimental (and always enabled) in 5.26.0.

=item * C&lt;postderef&gt; - allow the use of postfix dereferencing expressions

This was added in perl 5.20.0, and became non-experimental (and always enabled) in 5.24.0.

=item * C&lt;postderef_qq&gt; - allow the use of postfix dereferencing expressions inside interpolating strings

This was added in perl 5.20.0, and became non-experimental (and always enabled) in 5.24.0.

=item * C&lt;re_strict&gt; - enables strict mode in regular expressions

This was added in perl 5.22.0.

=item * C&lt;refaliasing&gt; - allow aliasing via C&lt;\$x = \$y&gt;

This was added in perl 5.22.0.

=item * C&lt;regex_sets&gt; - allow extended bracketed character classes in regexps

This was added in perl 5.18.0.

=item * C&lt;signatures&gt; - allow subroutine signatures (for named arguments)

This was added in perl 5.20.0.

=item * C&lt;smartmatch&gt; - allow the use of C&lt;~~&gt;

This was added in perl 5.10.0, but it should be noted there are significant
incompatibilities between 5.10.0 and 5.10.1.

The feature is going to be deprecated in perl 5.38.0, and removed in 5.42.0.

=item * C&lt;switch&gt; - allow the use of C&lt;~~&gt;, given, and when

This was added in perl 5.10.0.

The feature is going to be deprecated in perl 5.38.0, and removed in 5.42.0.

=item * C&lt;try&gt; - allow the use of C&lt;try&gt; and C&lt;catch&gt;

This was added in perl 5.34.0

=item * C&lt;win32_perlio&gt; - allows the use of the :win32 IO layer.

This was added on perl 5.22.0.

=back

=head2 Ordering matters

Using this pragma to 'enable an experimental feature' is another way of saying
that this pragma will disable the warnings which would result from using that
feature.  Therefore, the order in which pragmas are applied is important.  In
particular, you probably want to enable experimental features I&lt;after&gt; you
enable warnings:

  use warnings;
  use experimental 'smartmatch';

You also need to take care with modules that enable warnings for you.  A common
example being Moose.  In this example, warnings for the 'smartmatch' feature are
first turned on by the warnings pragma, off by the experimental pragma and back
on again by the Moose module (fix is to switch the last two lines):

  use warnings;
  use experimental 'smartmatch';
  use Moose;

=head2 Disclaimer

Because of the nature of the features it enables, forward compatibility can not
be guaranteed in any way.

=head1 SEE ALSO

L&lt;perlexperiment|perlexperiment&gt; contains more information about experimental features.

=head1 AUTHOR

Leon Timmermans &lt;leont@cpan.org&gt;

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2013 by Leon Timmermans.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</pre></body></html>