<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;"># -*- coding: utf-8-unix -*-

package Math::BigInt;

#
# "Mike had an infinite amount to do and a negative amount of time in which
# to do it." - Before and After
#

# The following hash values are used:
#
#          sign : "+", "-", "+inf", "-inf", or "NaN"
#         value : unsigned int with actual value ($LIB thingy)
#      accuracy : accuracy (scalar)
#     precision : precision (scalar)

# Remember not to take shortcuts ala $xs = $x-&gt;{value}; $LIB-&gt;foo($xs); since
# underlying lib might change the reference!

use 5.006001;
use strict;
use warnings;

use Carp          qw&lt; carp croak &gt;;
use Scalar::Util  qw&lt; blessed refaddr &gt;;

our $VERSION = '2.003002';
$VERSION =~ tr/_//d;

require Exporter;
our @ISA = qw(Exporter);
our @EXPORT_OK = qw(objectify bgcd blcm);

# Inside overload, the first arg is always an object. If the original code had
# it reversed (like $x = 2 * $y), then the third parameter is true.
# In some cases (like add, $x = $x + 2 is the same as $x = 2 + $x) this makes
# no difference, but in some cases it does.

# For overloaded ops with only one argument we simple use $_[0]-&gt;copy() to
# preserve the argument.

# Thus inheritance of overload operators becomes possible and transparent for
# our subclasses without the need to repeat the entire overload section there.

use overload

  # overload key: with_assign

  '+'     =&gt;      sub { $_[0] -&gt; copy() -&gt; badd($_[1]); },

  '-'     =&gt;      sub { my $c = $_[0] -&gt; copy();
                        $_[2] ? $c -&gt; bneg() -&gt; badd($_[1])
                              : $c -&gt; bsub($_[1]); },

  '*'     =&gt;      sub { $_[0] -&gt; copy() -&gt; bmul($_[1]); },

  '/'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bdiv($_[0])
                              : $_[0] -&gt; copy() -&gt; bdiv($_[1]); },

  '%'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bmod($_[0])
                              : $_[0] -&gt; copy() -&gt; bmod($_[1]); },

  '**'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bpow($_[0])
                              : $_[0] -&gt; copy() -&gt; bpow($_[1]); },

  '&lt;&lt;'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bblsft($_[0])
                              : $_[0] -&gt; copy() -&gt; bblsft($_[1]); },

  '&gt;&gt;'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bbrsft($_[0])
                              : $_[0] -&gt; copy() -&gt; bbrsft($_[1]); },

  # overload key: assign

  '+='    =&gt;      sub { $_[0] -&gt; badd($_[1]); },

  '-='    =&gt;      sub { $_[0] -&gt; bsub($_[1]); },

  '*='    =&gt;      sub { $_[0] -&gt; bmul($_[1]); },

  '/='    =&gt;      sub { scalar $_[0] -&gt; bdiv($_[1]); },

  '%='    =&gt;      sub { $_[0] -&gt; bmod($_[1]); },

  '**='   =&gt;      sub { $_[0] -&gt; bpow($_[1]); },

  '&lt;&lt;='   =&gt;      sub { $_[0] -&gt; bblsft($_[1]); },

  '&gt;&gt;='   =&gt;      sub { $_[0] -&gt; bbrsft($_[1]); },

#  'x='    =&gt;      sub { },

#  '.='    =&gt;      sub { },

  # overload key: num_comparison

  '&lt;'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; blt($_[0])
                              : $_[0] -&gt; blt($_[1]); },

  '&lt;='    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; ble($_[0])
                              : $_[0] -&gt; ble($_[1]); },

  '&gt;'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bgt($_[0])
                              : $_[0] -&gt; bgt($_[1]); },

  '&gt;='    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bge($_[0])
                              : $_[0] -&gt; bge($_[1]); },

  '=='    =&gt;      sub { $_[0] -&gt; beq($_[1]); },

  '!='    =&gt;      sub { $_[0] -&gt; bne($_[1]); },

  # overload key: 3way_comparison

  '&lt;=&gt;'   =&gt;      sub { my $cmp = $_[0] -&gt; bcmp($_[1]);
                        defined($cmp) &amp;&amp; $_[2] ? -$cmp : $cmp; },

  'cmp'   =&gt;      sub { $_[2] ? "$_[1]" cmp $_[0] -&gt; bstr()
                              : $_[0] -&gt; bstr() cmp "$_[1]"; },

  # overload key: str_comparison

#  'lt'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bstrlt($_[0])
#                              : $_[0] -&gt; bstrlt($_[1]); },
#
#  'le'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bstrle($_[0])
#                              : $_[0] -&gt; bstrle($_[1]); },
#
#  'gt'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bstrgt($_[0])
#                              : $_[0] -&gt; bstrgt($_[1]); },
#
#  'ge'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bstrge($_[0])
#                              : $_[0] -&gt; bstrge($_[1]); },
#
#  'eq'    =&gt;      sub { $_[0] -&gt; bstreq($_[1]); },
#
#  'ne'    =&gt;      sub { $_[0] -&gt; bstrne($_[1]); },

  # overload key: binary

  '&amp;'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; band($_[0])
                              : $_[0] -&gt; copy() -&gt; band($_[1]); },

  '&amp;='    =&gt;      sub { $_[0] -&gt; band($_[1]); },

  '|'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bior($_[0])
                              : $_[0] -&gt; copy() -&gt; bior($_[1]); },

  '|='    =&gt;      sub { $_[0] -&gt; bior($_[1]); },

  '^'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bxor($_[0])
                              : $_[0] -&gt; copy() -&gt; bxor($_[1]); },

  '^='    =&gt;      sub { $_[0] -&gt; bxor($_[1]); },

#  '&amp;.'    =&gt;      sub { },

#  '&amp;.='   =&gt;      sub { },

#  '|.'    =&gt;      sub { },

#  '|.='   =&gt;      sub { },

#  '^.'    =&gt;      sub { },

#  '^.='   =&gt;      sub { },

  # overload key: unary

  'neg'   =&gt;      sub { $_[0] -&gt; copy() -&gt; bneg(); },

#  '!'     =&gt;      sub { },

  '~'     =&gt;      sub { $_[0] -&gt; copy() -&gt; bnot(); },

#  '~.'    =&gt;      sub { },

  # overload key: mutators

  '++'    =&gt;      sub { $_[0] -&gt; binc() },

  '--'    =&gt;      sub { $_[0] -&gt; bdec() },

  # overload key: func

  'atan2' =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; batan2($_[0])
                              : $_[0] -&gt; copy() -&gt; batan2($_[1]); },

  'cos'   =&gt;      sub { $_[0] -&gt; copy() -&gt; bcos(); },

  'sin'   =&gt;      sub { $_[0] -&gt; copy() -&gt; bsin(); },

  'exp'   =&gt;      sub { $_[0] -&gt; copy() -&gt; bexp($_[1]); },

  'abs'   =&gt;      sub { $_[0] -&gt; copy() -&gt; babs(); },

  'log'   =&gt;      sub { $_[0] -&gt; copy() -&gt; blog(); },

  'sqrt'  =&gt;      sub { $_[0] -&gt; copy() -&gt; bsqrt(); },

  'int'   =&gt;      sub { $_[0] -&gt; copy() -&gt; bint(); },

  # overload key: conversion

  'bool'  =&gt;      sub { $_[0] -&gt; is_zero() ? '' : 1; },

  '""'    =&gt;      sub { $_[0] -&gt; bstr(); },

  '0+'    =&gt;      sub { $_[0] -&gt; numify(); },

  '='     =&gt;      sub { $_[0] -&gt; copy(); },

  ;

##############################################################################
# global constants, flags and accessory

# These vars are public, but their direct usage is not recommended, use the
# accessor methods instead

# $round_mode is 'even', 'odd', '+inf', '-inf', 'zero', 'trunc', or 'common'.
our $round_mode = 'even';
our $accuracy   = undef;
our $precision  = undef;
our $div_scale  = 40;
our $upgrade    = undef;                    # default is no upgrade
our $downgrade  = undef;                    # default is no downgrade

# These are internally, and not to be used from the outside at all

our $_trap_nan = 0;                         # are NaNs ok? set w/ config()
our $_trap_inf = 0;                         # are infs ok? set w/ config()

my $nan = 'NaN';                        # constants for easier life

# Module to do the low level math.

my $DEFAULT_LIB = 'Math::BigInt::Calc';
my $LIB;

# Has import() been called yet? This variable is needed to make "require" work.

my $IMPORT = 0;

##############################################################################
# the old code had $rnd_mode, so we need to support it, too

our $rnd_mode   = 'even';

sub TIESCALAR {
    my ($class) = @_;
    bless \$round_mode, $class;
}

sub FETCH {
    return $round_mode;
}

sub STORE {
    $rnd_mode = (ref $_[0]) -&gt; round_mode($_[1]);
}

BEGIN {
    # tie to enable $rnd_mode to work transparently
    tie $rnd_mode, 'Math::BigInt';

    # set up some handy alias names
    *is_pos = \&amp;is_positive;
    *is_neg = \&amp;is_negative;
    *as_number = \&amp;as_int;
}

###############################################################################
# Configuration methods
###############################################################################

sub round_mode {
    my $self = shift;
    my $class = ref($self) || $self || __PACKAGE__;

    # setter/mutator

    if (@_) {
        my $m = shift;
        croak("The value for 'round_mode' must be defined")
          unless defined $m;
        croak("Unknown round mode '$m'")
          unless $m =~ /^(even|odd|\+inf|\-inf|zero|trunc|common)$/;

        if (ref($self) &amp;&amp; exists $self -&gt; {round_mode}) {
            $self-&gt;{round_mode} = $m;
        } else {
            no strict 'refs';
            ${"${class}::round_mode"}  = $m;
        }
    }

    # getter/accessor

    else {
        if (ref($self) &amp;&amp; exists $self -&gt; {round_mode}) {
            return $self-&gt;{round_mode};
        } else {
            no strict 'refs';
            my $m = ${"${class}::round_mode"};
            return defined($m) ? $m : $round_mode;
        }
    }
}

sub upgrade {
    my $self = shift;
    my $class = ref($self) || $self || __PACKAGE__;

    # setter/mutator

    if (@_) {
        my $u = shift;
        if (ref($self) &amp;&amp; exists $self -&gt; {upgrade}) {
            $self -&gt; {upgrade} = $u;
        } else {
            no strict 'refs';
            ${"${class}::upgrade"} = $u;
        }
    }

    # getter/accessor

    else {
        if (ref($self) &amp;&amp; exists $self -&gt; {upgrade}) {
            return $self -&gt; {upgrade};
        } else {
            no strict 'refs';
            return ${"${class}::upgrade"};
        }
    }
}

sub downgrade {
    my $self = shift;
    my $class = ref($self) || $self || __PACKAGE__;

    # setter/mutator

    if (@_) {
        my $d = shift;
        if (ref($self) &amp;&amp; exists $self -&gt; {downgrade}) {
            $self -&gt; {downgrade} = $d;
        } else {
            no strict 'refs';
            ${"${class}::downgrade"} = $d;
        }
    }

    # getter/accessor

    else {
        if (ref($self) &amp;&amp; exists $self -&gt; {downgrade}) {
            return $self -&gt; {downgrade};
        } else {
            no strict 'refs';
            return ${"${class}::downgrade"};
        }
    }
}

sub div_scale {
    my $self = shift;
    my $class = ref($self) || $self || __PACKAGE__;

    # setter/mutator

    if (@_) {
        my $f = shift;
        croak("The value for 'div_scale' must be defined") unless defined $f;
        $f = $f -&gt; can('numify') ? $f -&gt; numify() : 0 + "$f" if ref($f);
        # also croak on non-numerical
        croak "div_scale must be a number, not '$f'"
          unless $f =~/^[+-]?(?:\d+(?:\.\d*)?|\.\d+)(?:[Ee][+-]?\d+)?\z/;
        croak "div_scale must be an integer, not '$f'"
          if $f != int $f;
        # It is not documented what div_scale &lt;= 0 means, but Astro::Units sets
        # div_scale to 0 and fails its tests if this is not supported. So we
        # silently support div_scale = 0.
        croak "div_scale must be positive, not '$f'" if $f &lt; 0;

        if (ref($self) &amp;&amp; exists $self -&gt; {div_scale}) {
            $self -&gt; {div_scale} = $f;
        } else {
            no strict 'refs';
            ${"${class}::div_scale"} = $f;
        }
    }

    # getter/accessor

    else {
        if (ref($self) &amp;&amp; exists $self -&gt; {div_scale}) {
            return $self -&gt; {div_scale};
        } else {
            no strict 'refs';
            my $f = ${"${class}::div_scale"};
            return defined($f) ? $f : $div_scale;
        }
    }
}

sub accuracy {
    my $x = shift;
    my $class = ref($x) || $x || __PACKAGE__;

    # setter/mutator

    if (@_) {
        my $a = shift;

        if (defined $a) {
            $a = $a -&gt; can('numify') ? $a -&gt; numify() : 0 + "$a" if ref($a);
            croak "accuracy must be a number, not '$a'"
              if $a !~ /^\s*[+-]?(?:\d+(?:\.\d*)?|\.\d+)(?:[Ee][+-]?\d+)?\s*\z/;
            croak "accuracy must be an integer, not '$a'"
              if $a != int $a;
        }

        if (ref($x)) {
            $x = $x -&gt; bround($a) if defined $a;
            $x -&gt; {precision} = undef;          # clear instance P
            $x -&gt; {accuracy}  = $a;             # set instance A
        } else {
            no strict 'refs';
            ${"${class}::precision"} = undef;   # clear class P
            ${"${class}::accuracy"}  = $a;      # set class A
        }
    }

    # getter/accessor

    else {
        if (ref($x)) {
            return $x -&gt; {accuracy};
        } else {
            no strict 'refs';
            return ${"${class}::accuracy"};
        }
    }
}

sub precision {
    my $x = shift;
    my $class = ref($x) || $x || __PACKAGE__;

    # setter/mutator

    if (@_) {
        my $p = shift;

        if (defined $p) {
            $p = $p -&gt; can('numify') ? $p -&gt; numify() : 0 + "$p" if ref($p);
            croak "precision must be a number, not '$p'"
              if $p !~ /^\s*[+-]?(?:\d+(?:\.\d*)?|\.\d+)(?:[Ee][+-]?\d+)?\s*\z/;
            croak "precision must be an integer, not '$p'"
              if $p != int $p;
        }

        if (ref($x)) {
            $x = $x -&gt; bfround($p) if defined $p;
            $x -&gt; {accuracy}  = undef;          # clear instance A
            $x -&gt; {precision} = $p;             # set instance P
        } else {
            no strict 'refs';
            ${"${class}::accuracy"}  = undef;   # clear class A
            ${"${class}::precision"} = $p;      # set class P
        }
    }

    # getter/accessor

    else {
        if (ref($x)) {
            return $x -&gt; {precision};
        } else {
            no strict 'refs';
            return ${"${class}::precision"};
        }
    }
}

sub trap_inf {
    my $self = shift;
    my $class = ref($self) || $self || __PACKAGE__;

    # setter/mutator

    if (@_) {
        my $b = shift() ? 1 : 0;
        if (ref($self) &amp;&amp; exists $self -&gt; {trap_inf}) {
            $self -&gt; {trap_inf} = $b;
        } else {
            no strict 'refs';
            ${"${class}::_trap_inf"} = $b;
        }
    }

    # getter/accessor

    else {
        if (ref($self) &amp;&amp; exists $self -&gt; {trap_inf}) {
            return $self -&gt; {trap_inf};
        } else {
            no strict 'refs';
            return ${"${class}::_trap_inf"};
        }
    }
}

sub trap_nan {
    my $self = shift;
    my $class = ref($self) || $self || __PACKAGE__;

    # setter/mutator

    if (@_) {
        my $b = shift() ? 1 : 0;
        if (ref($self) &amp;&amp; exists $self -&gt; {trap_nan}) {
            $self -&gt; {trap_nan} = $b;
        } else {
            no strict 'refs';
            ${"${class}::_trap_nan"} = $b;
        }
    }

    # getter/accessor

    else {
        if (ref($self) &amp;&amp; exists $self -&gt; {trap_nan}) {
            return $self -&gt; {trap_nan};
        } else {
            no strict 'refs';
            return ${"${class}::_trap_nan"};
        }
    }
}

sub config {
    # return (or set) configuration data.
    my $class = shift || __PACKAGE__;

    # setter/mutator
    #
    # $class -&gt; config(var =&gt; value, ...)
    # $class -&gt; config({ var =&gt; value, ... })

    if (@_ &gt; 1 || (@_ == 1 &amp;&amp; (ref($_[0]) eq 'HASH'))) {
        # try to set given options as arguments from hash

        # If the argument is a hash ref, make a copy of it, since keys will be
        # deleted below and we don't want to modify the input hash.

        my $args = ref($_[0]) eq 'HASH' ? { %{ $_[0] } }: { @_ };

        # We use this special handling of accuracy and precision because
        # accuracy() always sets precision to undef and precision() always sets
        # accuracy to undef. With out this special treatment, the following
        # would result in both accuracy and precision being undef.
        #
        #   $x -&gt; config(accuracy =&gt; 3, precision =&gt; undef)

        croak "config(): both accuracy and precision are defined"
          if defined($args -&gt; {accuracy}) &amp;&amp; defined ($args -&gt; {precision});

        if (defined $args -&gt; {accuracy}) {
            $class -&gt; accuracy($args -&gt; {accuracy});
        } elsif (defined $args -&gt; {precision}) {
            $class -&gt; precision($args -&gt; {precision});
        } else {
            $class -&gt; accuracy(undef);  # also sets precision to undef
        }

        delete $args-&gt;{accuracy};
        delete $args-&gt;{precision};

        # Set any remaining keys.

        foreach my $key (qw/
                               round_mode div_scale
                               upgrade downgrade
                               trap_inf trap_nan
                           /)
        {
            # use a method call to check argument
            $class-&gt;$key($args-&gt;{$key}) if exists $args-&gt;{$key};
            delete $args-&gt;{$key};
        }

        # If there are any keys left, they are invalid.

        if (keys %$args) {
            croak("Illegal key(s) '", join("', '", keys %$args),
                        "' passed to $class\-&gt;config()");
        }
    }

    # Now build the full configuration.

    my $cfg = {
               lib         =&gt; $LIB,
               lib_version =&gt; $LIB -&gt; VERSION(),
               class       =&gt; $class,
               version     =&gt; $class -&gt; VERSION(),
              };

    foreach my $key (qw/
                           accuracy precision
                           round_mode div_scale
                           upgrade downgrade
                           trap_inf trap_nan
                       /)
    {
        $cfg-&gt;{$key} = $class -&gt; $key();
    }

    # getter/accessor
    #
    # $class -&gt; config("var")

    if (@_ == 1 &amp;&amp; (ref($_[0]) ne 'HASH')) {
        return $cfg-&gt;{$_[0]};
    }

    $cfg;
}

sub _scale_a {
    # select accuracy parameter based on precedence,
    # used by bround() and bfround(), may return undef for scale (means no op)
    my ($x, $scale, $mode) = @_;

    $scale = $x-&gt;{accuracy} unless defined $scale;

    my $class = ref($x);

    $scale = $class -&gt; accuracy() unless defined $scale;
    $mode = $class -&gt; round_mode() unless defined $mode;

    if (defined $scale) {
        $scale = $scale-&gt;can('numify') ? $scale-&gt;numify()
                                       : "$scale" if ref($scale);
        $scale = int($scale);
    }

    ($scale, $mode);
}

sub _scale_p {
    # select precision parameter based on precedence,
    # used by bround() and bfround(), may return undef for scale (means no op)
    my ($x, $scale, $mode) = @_;

    $scale = $x-&gt;{precision} unless defined $scale;

    my $class = ref($x);

    $scale = $class -&gt; precision() unless defined $scale;
    $mode = $class -&gt; round_mode() unless defined $mode;

    if (defined $scale) {
        $scale = $scale-&gt;can('numify') ? $scale-&gt;numify()
                                       : "$scale" if ref($scale);
        $scale = int($scale);
    }

    ($scale, $mode);
}

###############################################################################
# Constructor methods
###############################################################################

sub new {
    # Create a new Math::BigInt object from a string or another Math::BigInt
    # object. See hash keys documented at top.

    # The argument could be an object, so avoid ||, &amp;&amp; etc. on it. This would
    # cause costly overloaded code to be called. The only allowed ops are ref()
    # and defined.

    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Calling new() with no input arguments has been discouraged for more than
    # 10 years, but people apparently still use it, so we still support it.

    return $class -&gt; bzero() unless @_;

    my ($wanted, @r) = @_;

    if (!defined($wanted)) {
        #carp("Use of uninitialized value in new()")
        #  if warnings::enabled("uninitialized");
        return $class -&gt; bzero(@r);
    }

    if (!ref($wanted) &amp;&amp; $wanted eq "") {
        #carp(q|Argument "" isn't numeric in new()|)
        #  if warnings::enabled("numeric");
        #return $class -&gt; bzero(@r);
        return $class -&gt; bnan(@r);
    }

    # Initialize a new object.

    $self = bless {}, $class;

    # Math::BigInt or subclass

    if (defined(blessed($wanted)) &amp;&amp; $wanted -&gt; isa(__PACKAGE__)) {

        # Don't copy the accuracy and precision, because a new object should get
        # them from the global configuration.

        $self -&gt; {sign}  = $wanted -&gt; {sign};
        $self -&gt; {value} = $LIB -&gt; _copy($wanted -&gt; {value});
        $self = $self-&gt;round(@r)
          unless @r &gt;= 2 &amp;&amp; !defined($r[0]) &amp;&amp; !defined($r[1]);
        return $self;
    }

    # Shortcut for non-zero scalar integers with no non-zero exponent.

    if ($wanted =~
        / ^
          ( [+-]? )             # optional sign
          ( [1-9] [0-9]* )      # non-zero significand
          ( \.0* )?             # ... with optional zero fraction
          ( [Ee] [+-]? 0+ )?    # optional zero exponent
          \z
        /x)
    {
        my $sgn = $1;
        my $abs = $2;
        $self-&gt;{sign} = $sgn || '+';
        $self-&gt;{value} = $LIB-&gt;_new($abs);
        $self = $self-&gt;round(@r);
        return $self;
    }

    # Handle Infs.

    if ($wanted =~ / ^
                     \s*
                     ( [+-]? )
                     inf (?: inity )?
                     \s*
                     \z
                   /ix)
    {
        my $sgn = $1 || '+';
        return $class -&gt; binf($sgn, @r);
    }

    # Handle explicit NaNs (not the ones returned due to invalid input).

    if ($wanted =~ / ^
                     \s*
                     ( [+-]? )
                     nan
                     \s*
                     \z
                   /ix)
    {
        return $class -&gt; bnan(@r);
    }

    my @parts;

    if (
        # Handle hexadecimal numbers. We auto-detect hexadecimal numbers if they
        # have a "0x", "0X", "x", or "X" prefix, cf. CORE::oct().

        $wanted =~ /^\s*[+-]?0?[Xx]/ and
        @parts = $class -&gt; _hex_str_to_flt_lib_parts($wanted)

          or

        # Handle octal numbers. We auto-detect octal numbers if they have a
        # "0o", "0O", "o", "O" prefix, cf. CORE::oct().

        $wanted =~ /^\s*[+-]?0?[Oo]/ and
        @parts = $class -&gt; _oct_str_to_flt_lib_parts($wanted)

          or

        # Handle binary numbers. We auto-detect binary numbers if they have a
        # "0b", "0B", "b", or "B" prefix, cf. CORE::oct().

        $wanted =~ /^\s*[+-]?0?[Bb]/ and
        @parts = $class -&gt; _bin_str_to_flt_lib_parts($wanted)

          or

        # At this point, what is left are decimal numbers that aren't handled
        # above and octal floating point numbers that don't have any of the
        # "0o", "0O", "o", or "O" prefixes. First see if it is a decimal number.

        @parts = $class -&gt; _dec_str_to_flt_lib_parts($wanted)
          or

        # See if it is an octal floating point number. The extra check is
        # included because _oct_str_to_flt_lib_parts() accepts octal numbers
        # that don't have a prefix (this is needed to make it work with, e.g.,
        # from_oct() that don't require a prefix). However, Perl requires a
        # prefix for octal floating point literals. For example, "1p+0" is not
        # valid, but "01p+0" and "0__1p+0" are.

        $wanted =~ /^\s*[+-]?0_*\d/ and
        @parts = $class -&gt; _oct_str_to_flt_lib_parts($wanted))
    {
        # The value is an integer iff the exponent is non-negative.

        if ($parts[2] eq '+') {
            $self -&gt; {sign}  = $parts[0];
            $self -&gt; {value} = $LIB -&gt; _lsft($parts[1], $parts[3], 10);
            $self = $self-&gt;round(@r)
              unless @r &gt;= 2 &amp;&amp; !defined($r[0]) &amp;&amp; !defined($r[1]);
            return $self;
        }

        # The value is not an integer, so upgrade if upgrading is enabled.

        return $upgrade -&gt; new($wanted, @r) if defined $upgrade;
    }

    # If we get here, the value is neither a valid decimal, binary, octal, or
    # hexadecimal number. It is not explicit an Inf or a NaN either.

    return $class -&gt; bnan(@r);
}

# Create a Math::BigInt from a decimal string. This is an equivalent to
# from_hex(), from_oct(), and from_bin(). It is like new() except that it does
# not accept anything but a string representing a finite decimal number.

sub from_dec {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('from_dec');

    my $str = shift;
    my @r   = @_;

    # If called as a class method, initialize a new object.

    $self = $class -&gt; bzero(@r) unless $selfref;

    if (my @parts = $class -&gt; _dec_str_to_flt_lib_parts($str)) {

        # The value is an integer iff the exponent is non-negative.

        if ($parts[2] eq '+') {
            $self -&gt; {sign}  = $parts[0];
            $self -&gt; {value} = $LIB -&gt; _lsft($parts[1], $parts[3], 10);
            return $self -&gt; round(@r);
        }

        # The value is not an integer, so upgrade if upgrading is enabled.

        return $upgrade -&gt; new($str, @r) if defined $upgrade;
    }

    return $self -&gt; bnan(@r);
}

# Create a Math::BigInt from a hexadecimal string.

sub from_hex {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('from_hex');

    my $str = shift;
    my @r   = @_;

    # If called as a class method, initialize a new object.

    $self = $class -&gt; bzero(@r) unless $selfref;

    if (my @parts = $class -&gt; _hex_str_to_flt_lib_parts($str)) {

        # The value is an integer iff the exponent is non-negative.

        if ($parts[2] eq '+') {
            $self -&gt; {sign}  = $parts[0];
            $self -&gt; {value} = $LIB -&gt; _lsft($parts[1], $parts[3], 10);
            return $self -&gt; round(@r);
        }

        # The value is not an integer, so upgrade if upgrading is enabled.

        return $upgrade -&gt; new($str, @r) if defined $upgrade;
    }

    return $self -&gt; bnan(@r);
}

# Create a Math::BigInt from an octal string.

sub from_oct {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('from_oct');

    my $str = shift;
    my @r   = @_;

    # If called as a class method, initialize a new object.

    $self = $class -&gt; bzero(@r) unless $selfref;

    if (my @parts = $class -&gt; _oct_str_to_flt_lib_parts($str)) {

        # The value is an integer iff the exponent is non-negative.

        if ($parts[2] eq '+') {
            $self -&gt; {sign}  = $parts[0];
            $self -&gt; {value} = $LIB -&gt; _lsft($parts[1], $parts[3], 10);
            return $self -&gt; round(@r);
        }

        # The value is not an integer, so upgrade if upgrading is enabled.

        return $upgrade -&gt; new($str, @r) if defined $upgrade;
    }

    return $self -&gt; bnan(@r);
}

# Create a Math::BigInt from a binary string.

sub from_bin {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('from_bin');

    my $str = shift;
    my @r   = @_;

    # If called as a class method, initialize a new object.

    $self = $class -&gt; bzero(@r) unless $selfref;

    if (my @parts = $class -&gt; _bin_str_to_flt_lib_parts($str)) {

        # The value is an integer iff the exponent is non-negative.

        if ($parts[2] eq '+') {
            $self -&gt; {sign}  = $parts[0];
            $self -&gt; {value} = $LIB -&gt; _lsft($parts[1], $parts[3], 10);
            return $self -&gt; round(@r);
        }

        # The value is not an integer, so upgrade if upgrading is enabled.

        return $upgrade -&gt; new($str, @r) if defined $upgrade;
    }

    return $self -&gt; bnan(@r);
}

# Create a Math::BigInt from a byte string.

sub from_bytes {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('from_bytes');

    croak("from_bytes() requires a newer version of the $LIB library.")
        unless $LIB-&gt;can('_from_bytes');

    my $str = shift;
    my @r = @_;

    # If called as a class method, initialize a new object.

    $self = $class -&gt; bzero(@r) unless $selfref;
    $self -&gt; {sign}  = '+';
    $self -&gt; {value} = $LIB -&gt; _from_bytes($str);
    return $self -&gt; round(@r);
}

sub from_base {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('from_base');

    my ($str, $base, $cs, @r) = @_;     # $cs is the collation sequence

    $base = $class-&gt;new($base) unless ref($base);

    croak("the base must be a finite integer &gt;= 2")
      if $base &lt; 2 || ! $base -&gt; is_int();

    # If called as a class method, initialize a new object.

    $self = $class -&gt; bzero() unless $selfref;

    # If no collating sequence is given, pass some of the conversions to
    # methods optimized for those cases.

    unless (defined $cs) {
        return $self -&gt; from_bin($str, @r) if $base == 2;
        return $self -&gt; from_oct($str, @r) if $base == 8;
        return $self -&gt; from_hex($str, @r) if $base == 16;
        if ($base == 10) {
            my $tmp = $class -&gt; from_dec($str, @r);
            $self -&gt; {value} = $tmp -&gt; {value};
            $self -&gt; {sign}  = '+';
            return $self -&gt; bround(@r);
        }
    }

    croak("from_base() requires a newer version of the $LIB library.")
      unless $LIB-&gt;can('_from_base');

    $self -&gt; {sign}  = '+';
    $self -&gt; {value}
      = $LIB-&gt;_from_base($str, $base -&gt; {value}, defined($cs) ? $cs : ());
    return $self -&gt; bround(@r);
}

sub from_base_num {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('from_base_num');

    # Make sure we have an array of non-negative, finite, numerical objects.

    my $nums = shift;
    $nums = [ @$nums ];         # create new reference

    for my $i (0 .. $#$nums) {
        # Make sure we have an object.
        $nums -&gt; [$i] = $class -&gt; new($nums -&gt; [$i])
          unless defined(blessed($nums -&gt; [$i]))
                   &amp;&amp; $nums -&gt; [$i] -&gt; isa(__PACKAGE__);
        # Make sure we have a finite, non-negative integer.
        croak "the elements must be finite non-negative integers"
          if $nums -&gt; [$i] -&gt; is_neg() || ! $nums -&gt; [$i] -&gt; is_int();
    }

    my $base = shift;
    $base = $class -&gt; new($base)
      unless defined(blessed($base)) &amp;&amp; $base -&gt; isa(__PACKAGE__);

    my @r = @_;

    # If called as a class method, initialize a new object.

    $self = $class -&gt; bzero(@r) unless $selfref;

    croak("from_base_num() requires a newer version of the $LIB library.")
      unless $LIB-&gt;can('_from_base_num');

    $self -&gt; {sign}  = '+';
    $self -&gt; {value} = $LIB -&gt; _from_base_num([ map { $_ -&gt; {value} } @$nums ],
                                           $base -&gt; {value});

    return $self -&gt; round(@r);
}

sub bzero {
    # create/assign '+0'

    # Class::method(...) -&gt; Class-&gt;method(...)
    unless (@_ &amp;&amp; (defined(blessed($_[0])) &amp;&amp; $_[0] -&gt; isa(__PACKAGE__) ||
                   $_[0] =~ /^[a-z]\w*(?:::[a-z]\w*)*$/i))
    {
        #carp "Using ", (caller(0))[3], "() as a function is deprecated;",
        #  " use is as a method instead";
        unshift @_, __PACKAGE__;
    }

    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('bzero');

    # Get the rounding parameters, if any.

    my @r = @_;

    # If called as a class method, initialize a new object.

    $self = bless {}, $class unless $selfref;

    $self-&gt;{sign} = '+';
    $self-&gt;{value} = $LIB-&gt;_zero();

    # If rounding parameters are given as arguments, use them. If no rounding
    # parameters are given, and if called as a class method, initialize the new
    # instance with the class variables.

    if (@r) {
        if (@r &gt;= 2 &amp;&amp; defined($r[0]) &amp;&amp; defined($r[1])) {
            carp "can't specify both accuracy and precision";
            return $self -&gt; bnan();
        }
        $self-&gt;{accuracy} = $_[0];
        $self-&gt;{precision} = $_[1];
    } elsif (!$selfref) {
        $self-&gt;{accuracy} = $class -&gt; accuracy();
        $self-&gt;{precision} = $class -&gt; precision();
    }

    return $self;
}

sub bone {
    # Create or assign '+1' (or -1 if given sign '-').

    # Class::method(...) -&gt; Class-&gt;method(...)
    unless (@_ &amp;&amp; (defined(blessed($_[0])) &amp;&amp; $_[0] -&gt; isa(__PACKAGE__) ||
                   $_[0] =~ /^[a-z]\w*(?:::[a-z]\w*)*$/i))
    {
        #carp "Using ", (caller(0))[3], "() as a function is deprecated;",
        #  " use is as a method instead";
        unshift @_, __PACKAGE__;
    }

    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('bone');

    my ($sign, @r) = @_;

    # Get the sign.

    if (defined($_[0]) &amp;&amp; $_[0] =~ /^\s*([+-])\s*$/) {
        $sign = $1;
        shift;
    } else {
        $sign = '+';
    }

    # If called as a class method, initialize a new object.

    $self = bless {}, $class unless $selfref;

    $self-&gt;{sign}  = $sign;
    $self-&gt;{value} = $LIB-&gt;_one();

    # If rounding parameters are given as arguments, use them. If no rounding
    # parameters are given, and if called as a class method, initialize the new
    # instance with the class variables.

    if (@r) {
        if (@r &gt;= 2 &amp;&amp; defined($r[0]) &amp;&amp; defined($r[1])) {
            carp "can't specify both accuracy and precision";
            return $self -&gt; bnan();
        }
        $self-&gt;{accuracy} = $_[0];
        $self-&gt;{precision} = $_[1];
    } elsif (!$selfref) {
        $self-&gt;{accuracy} = $class -&gt; accuracy();
        $self-&gt;{precision} = $class -&gt; precision();
    }

    return $self;
}

sub binf {
    # create/assign a '+inf' or '-inf'

    # Class::method(...) -&gt; Class-&gt;method(...)
    unless (@_ &amp;&amp; (defined(blessed($_[0])) &amp;&amp; $_[0] -&gt; isa(__PACKAGE__) ||
                   $_[0] =~ /^[a-z]\w*(?:::[a-z]\w*)*$/i))
    {
        #carp "Using ", (caller(0))[3], "() as a function is deprecated;",
        #  " use is as a method instead";
        unshift @_, __PACKAGE__;
    }

    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    {
        no strict 'refs';
        if (${"${class}::_trap_inf"}) {
            croak("Tried to create +-inf in $class-&gt;binf()");
        }
    }

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('binf');

    # Get the sign.

    my $sign = '+';     # default is to return positive infinity
    if (defined($_[0]) &amp;&amp; $_[0] =~ /^\s*([+-])(inf|$)/i) {
        $sign = $1;
        shift;
    }

    # Get the rounding parameters, if any.

    my @r = @_;

    # If called as a class method, initialize a new object.

    $self = bless {}, $class unless $selfref;

    $self -&gt; {sign}  = $sign . 'inf';
    $self -&gt; {value} = $LIB -&gt; _zero();

    # If rounding parameters are given as arguments, use them. If no rounding
    # parameters are given, and if called as a class method, initialize the new
    # instance with the class variables.

    if (@r) {
        if (@r &gt;= 2 &amp;&amp; defined($r[0]) &amp;&amp; defined($r[1])) {
            carp "can't specify both accuracy and precision";
            return $self -&gt; bnan();
        }
        $self-&gt;{accuracy} = $_[0];
        $self-&gt;{precision} = $_[1];
    } elsif (!$selfref) {
        $self-&gt;{accuracy} = $class -&gt; accuracy();
        $self-&gt;{precision} = $class -&gt; precision();
    }

    return $self;
}

sub bnan {
    # create/assign a 'NaN'

    # Class::method(...) -&gt; Class-&gt;method(...)
    unless (@_ &amp;&amp; (defined(blessed($_[0])) &amp;&amp; $_[0] -&gt; isa(__PACKAGE__) ||
                   $_[0] =~ /^[a-z]\w*(?:::[a-z]\w*)*$/i))
    {
        #carp "Using ", (caller(0))[3], "() as a function is deprecated;",
        #  " use is as a method instead";
        unshift @_, __PACKAGE__;
    }

    my $self    = shift;
    my $selfref = ref($self);
    my $class   = $selfref || $self;

    {
        no strict 'refs';
        if (${"${class}::_trap_nan"}) {
            croak("Tried to create NaN in $class-&gt;bnan()");
        }
    }

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    # Don't modify constant (read-only) objects.

    return $self if $selfref &amp;&amp; $self-&gt;modify('bnan');

    # Get the rounding parameters, if any.

    my @r = @_;

    $self = bless {}, $class unless $selfref;

    $self -&gt; {sign}  = $nan;
    $self -&gt; {value} = $LIB -&gt; _zero();

    # If rounding parameters are given as arguments, use them. If no rounding
    # parameters are given, and if called as a class method, initialize the new
    # instance with the class variables.

    if (@r) {
        if (@r &gt;= 2 &amp;&amp; defined($r[0]) &amp;&amp; defined($r[1])) {
            carp "can't specify both accuracy and precision";
            return $self -&gt; bnan();
        }
        $self-&gt;{accuracy} = $_[0];
        $self-&gt;{precision} = $_[1];
    } elsif (!$selfref) {
        $self-&gt;{accuracy} = $class -&gt; accuracy();
        $self-&gt;{precision} = $class -&gt; precision();
    }

    return $self;
}

sub bpi {

    # Class::method(...) -&gt; Class-&gt;method(...)
    unless (@_ &amp;&amp; (defined(blessed($_[0])) &amp;&amp; $_[0] -&gt; isa(__PACKAGE__) ||
                   $_[0] =~ /^[a-z]\w*(?:::[a-z]\w*)*$/i))
    {
        #carp "Using ", (caller(0))[3], "() as a function is deprecated;",
        #  " use is as a method instead";
        unshift @_, __PACKAGE__;
    }

    # Called as                 Argument list
    # ---------                 -------------
    # Math::BigFloat-&gt;bpi()     ("Math::BigFloat")
    # Math::BigFloat-&gt;bpi(10)   ("Math::BigFloat", 10)
    # $x-&gt;bpi()                 ($x)
    # $x-&gt;bpi(10)               ($x, 10)
    # Math::BigFloat::bpi()     ()
    # Math::BigFloat::bpi(10)   (10)
    #
    # In ambiguous cases, we favour the OO-style, so the following case
    #
    #   $n = Math::BigFloat-&gt;new("10");
    #   $x = Math::BigFloat-&gt;bpi($n);
    #
    # which gives an argument list with the single element $n, is resolved as
    #
    #   $n-&gt;bpi();

    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;
    my @r       = @_;                   # rounding paramters

    # Make "require" work.

    $class -&gt; import() if $IMPORT == 0;

    if ($selfref) {                     # bpi() called as an instance method
        return $self if $self -&gt; modify('bpi');
    } else {                            # bpi() called as a class method
        $self = bless {}, $class;       # initialize new instance
    }

    return $upgrade -&gt; bpi(@r) if defined $upgrade;

    # hard-wired to "3"
    $self -&gt; {sign}  = '+';
    $self -&gt; {value} = $LIB -&gt; _new("3");
    $self = $self -&gt; round(@r);
    return $self;
}

sub copy {
    my ($x, $class);
    if (ref($_[0])) {           # $y = $x -&gt; copy()
        $x = shift;
        $class = ref($x);
    } else {                    # $y = Math::BigInt -&gt; copy($y)
        $class = shift;
        $x = shift;
    }

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @_;

    my $copy = bless {}, $class;

    $copy-&gt;{sign}  = $x-&gt;{sign};
    $copy-&gt;{value} = $LIB-&gt;_copy($x-&gt;{value});
    $copy-&gt;{accuracy}    = $x-&gt;{accuracy} if exists $x-&gt;{accuracy};
    $copy-&gt;{precision}    = $x-&gt;{precision} if exists $x-&gt;{precision};

    return $copy;
}

sub as_int {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);
    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $x -&gt; copy() if $x -&gt; isa("Math::BigInt");

    # Disable upgrading and downgrading.

    my $upg = Math::BigInt -&gt; upgrade();
    my $dng = Math::BigInt -&gt; downgrade();
    Math::BigInt -&gt; upgrade(undef);
    Math::BigInt -&gt; downgrade(undef);

    # Copy the value.

    my $y = Math::BigInt -&gt; new($x);

    # Copy the remaining instance variables.

    ($y-&gt;{accuracy}, $y-&gt;{precision}) = ($x-&gt;{accuracy}, $x-&gt;{precision});

    # Restore upgrading and downgrading

    Math::BigInt -&gt; upgrade($upg);
    Math::BigInt -&gt; downgrade($dng);

    return $y;
}

sub as_float {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);
    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Disable upgrading and downgrading.

    require Math::BigFloat;
    my $upg = Math::BigFloat -&gt; upgrade();
    my $dng = Math::BigFloat -&gt; downgrade();
    Math::BigFloat -&gt; upgrade(undef);
    Math::BigFloat -&gt; downgrade(undef);

    # Copy the value.

    my $y = Math::BigFloat -&gt; new($x);

    # Copy the remaining instance variables.

    ($y-&gt;{accuracy}, $y-&gt;{precision}) = ($x-&gt;{accuracy}, $x-&gt;{precision});

    # Restore upgrading and downgrading..

    Math::BigFloat -&gt; upgrade($upg);
    Math::BigFloat -&gt; downgrade($dng);

    return $y;
}

sub as_rat {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);
    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Disable upgrading and downgrading.

    require Math::BigRat;
    my $upg = Math::BigRat -&gt; upgrade();
    my $dng = Math::BigRat -&gt; downgrade();
    Math::BigRat -&gt; upgrade(undef);
    Math::BigRat -&gt; downgrade(undef);

    my $y = Math::BigRat -&gt; new($x);

    # Copy the remaining instance variables.

    ($y-&gt;{accuracy}, $y-&gt;{precision}) = ($x-&gt;{accuracy}, $x-&gt;{precision});

    # Restore upgrading and downgrading.

    Math::BigRat -&gt; upgrade($upg);
    Math::BigRat -&gt; downgrade($dng);

    return $y;
}

###############################################################################
# Boolean methods
###############################################################################

sub is_zero {
    # return true if arg (BINT or num_str) is zero (array '+', '0')
    my (undef, $x) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    return 0 if $x-&gt;{sign} !~ /^\+$/; # -, NaN &amp; +-inf aren't
    $LIB-&gt;_is_zero($x-&gt;{value});
}

sub is_one {
    # return true if arg (BINT or num_str) is +1, or -1 if sign is given
    my (undef, $x, $sign) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    $sign = '+' if !defined($sign) || $sign ne '-';

    return 0 if $x-&gt;{sign} ne $sign; # -1 != +1, NaN, +-inf aren't either
    $LIB-&gt;_is_one($x-&gt;{value});
}

sub is_finite {
    my (undef, $x) = ref($_[0]) ? (undef, @_) : objectify(1, @_);
    return $x-&gt;{sign} eq '+' || $x-&gt;{sign} eq '-';
}

sub is_inf {
    # return true if arg (BINT or num_str) is +-inf
    my (undef, $x, $sign) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    if (defined $sign) {
        $sign = '[+-]inf' if $sign eq ''; # +- doesn't matter, only that's inf
        $sign = "[$1]inf" if $sign =~ /^([+-])(inf)?$/; # extract '+' or '-'
        return $x-&gt;{sign} =~ /^$sign$/ ? 1 : 0;
    }
    $x-&gt;{sign} =~ /^[+-]inf$/ ? 1 : 0; # only +-inf is infinity
}

sub is_nan {
    # return true if arg (BINT or num_str) is NaN
    my (undef, $x) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    $x-&gt;{sign} eq $nan ? 1 : 0;
}

sub is_positive {
    # return true when arg (BINT or num_str) is positive (&gt; 0)
    my (undef, $x) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    return 1 if $x-&gt;{sign} eq '+inf'; # +inf is positive

    # 0+ is neither positive nor negative
    ($x-&gt;{sign} eq '+' &amp;&amp; !$x-&gt;is_zero()) ? 1 : 0;
}

sub is_negative {
    # return true when arg (BINT or num_str) is negative (&lt; 0)
    my (undef, $x) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    $x-&gt;{sign} =~ /^-/ ? 1 : 0; # -inf is negative, but NaN is not
}

sub is_non_negative {
    # Return true if argument is non-negative (&gt;= 0).
    my (undef, $x) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    return 1 if $x-&gt;{sign} =~ /^\+/;
    return 1 if $x -&gt; is_zero();
    return 0;
}

sub is_non_positive {
    # Return true if argument is non-positive (&lt;= 0).
    my (undef, $x) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    return 1 if $x-&gt;{sign} =~ /^\-/;
    return 1 if $x -&gt; is_zero();
    return 0;
}

sub is_odd {
    # return true when arg (BINT or num_str) is odd, false for even
    my (undef, $x) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    return 0 if $x-&gt;{sign} !~ /^[+-]$/; # NaN &amp; +-inf aren't
    $LIB-&gt;_is_odd($x-&gt;{value});
}

sub is_even {
    # return true when arg (BINT or num_str) is even, false for odd
    my (undef, $x) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    return 0 if $x-&gt;{sign} !~ /^[+-]$/; # NaN &amp; +-inf aren't
    $LIB-&gt;_is_even($x-&gt;{value});
}

sub is_int {
    # return true when arg (BINT or num_str) is an integer
    my (undef, $x) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    $x-&gt;{sign} =~ /^[+-]$/ ? 1 : 0; # inf/-inf/NaN aren't
}

###############################################################################
# Comparison methods
###############################################################################

sub bcmp {
    # Compares 2 values.  Returns one of undef, &lt;0, =0, &gt;0. (suitable for sort)
    # (BINT or num_str, BINT or num_str) return cond_code

    # set up parameters
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $upgrade-&gt;bcmp($x, $y)
      if defined($upgrade) &amp;&amp; (!$x-&gt;isa(__PACKAGE__) || !$y-&gt;isa(__PACKAGE__));

    if (($x-&gt;{sign} !~ /^[+-]$/) || ($y-&gt;{sign} !~ /^[+-]$/)) {
        # handle +-inf and NaN
        return    if (($x-&gt;{sign} eq $nan) || ($y-&gt;{sign} eq $nan));
        return  0 if $x-&gt;{sign} eq $y-&gt;{sign} &amp;&amp; $x-&gt;{sign} =~ /^[+-]inf$/;
        return +1 if $x-&gt;{sign} eq '+inf';
        return -1 if $x-&gt;{sign} eq '-inf';
        return -1 if $y-&gt;{sign} eq '+inf';
        return +1;
    }

    # check sign for speed first
    return 1 if $x-&gt;{sign} eq '+' &amp;&amp; $y-&gt;{sign} eq '-'; # does also 0 &lt;=&gt; -y
    return -1 if $x-&gt;{sign} eq '-' &amp;&amp; $y-&gt;{sign} eq '+'; # does also -x &lt;=&gt; 0

    # have same sign, so compare absolute values.  Don't make tests for zero
    # here because it's actually slower than testing in Calc (especially w/ Pari
    # et al)

    # post-normalized compare for internal use (honors signs)
    if ($x-&gt;{sign} eq '+') {
        # $x and $y both &gt; 0
        return $LIB-&gt;_acmp($x-&gt;{value}, $y-&gt;{value});
    }

    # $x &amp;&amp; $y both &lt; 0
    $LIB-&gt;_acmp($y-&gt;{value}, $x-&gt;{value}); # swapped acmp (lib returns 0, 1, -1)
}

sub bacmp {
    # Compares 2 values, ignoring their signs.
    # Returns one of undef, &lt;0, =0, &gt;0. (suitable for sort)
    # (BINT, BINT) return cond_code

    # set up parameters
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $upgrade-&gt;bacmp($x, $y)
      if defined($upgrade) &amp;&amp; (!$x-&gt;isa(__PACKAGE__) || !$y-&gt;isa(__PACKAGE__));

    if (($x-&gt;{sign} !~ /^[+-]$/) || ($y-&gt;{sign} !~ /^[+-]$/)) {
        # handle +-inf and NaN
        return   if (($x-&gt;{sign} eq $nan) || ($y-&gt;{sign} eq $nan));
        return 0 if $x-&gt;{sign} =~ /^[+-]inf$/ &amp;&amp; $y-&gt;{sign} =~ /^[+-]inf$/;
        return 1 if $x-&gt;{sign} =~ /^[+-]inf$/ &amp;&amp; $y-&gt;{sign} !~ /^[+-]inf$/;
        return -1;
    }
    $LIB-&gt;_acmp($x-&gt;{value}, $y-&gt;{value}); # lib does only 0, 1, -1
}

sub beq {
    my (undef, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                           ? (undef, @_)
                           : objectify(2, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    my $cmp = $x -&gt; bcmp($y);           # bcmp() upgrades if necessary
    return defined($cmp) &amp;&amp; !$cmp;
}

sub bne {
    my (undef, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                           ? (undef, @_)
                           : objectify(2, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    my $cmp = $x -&gt; bcmp($y);           # bcmp() upgrades if necessary
    return defined($cmp) &amp;&amp; !$cmp ? '' : 1;
}

sub blt {
    my (undef, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                           ? (undef, @_)
                           : objectify(2, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    my $cmp = $x -&gt; bcmp($y);           # bcmp() upgrades if necessary
    return defined($cmp) &amp;&amp; $cmp &lt; 0;
}

sub ble {
    my (undef, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                           ? (undef, @_)
                           : objectify(2, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    my $cmp = $x -&gt; bcmp($y);           # bcmp() upgrades if necessary
    return defined($cmp) &amp;&amp; $cmp &lt;= 0;
}

sub bgt {
    my (undef, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                           ? (undef, @_)
                           : objectify(2, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    my $cmp = $x -&gt; bcmp($y);           # bcmp() upgrades if necessary
    return defined($cmp) &amp;&amp; $cmp &gt; 0;
}

sub bge {
    my (undef, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                           ? (undef, @_)
                           : objectify(2, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    my $cmp = $x -&gt; bcmp($y);           # bcmp() upgrades if necessary
    return defined($cmp) &amp;&amp; $cmp &gt;= 0;
}

###############################################################################
# Arithmetic methods
###############################################################################

sub bneg {
    # (BINT or num_str) return BINT
    # negate number or make a negated number from string
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('bneg');

    return $upgrade -&gt; bneg($x, @r)
      if defined($upgrade) &amp;&amp; !$x-&gt;isa(__PACKAGE__);

    # Don't negate +0 so we always have the normalized form +0. Does nothing for
    # 'NaN'.
    $x-&gt;{sign} =~ tr/+-/-+/
      unless $x-&gt;{sign} eq '+' &amp;&amp; $LIB-&gt;_is_zero($x-&gt;{value});

    $x -&gt; round(@r);
}

sub babs {
    # (BINT or num_str) return BINT
    # make number absolute, or return absolute BINT from string
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('babs');

    # This call to the upgrade class must either be commented out or the method
    # must be implemented in the upgrade class(es) to avoid infinite recursion.
    # It doesn't help to check whether $x isa $upgrade, because there might be
    # several levels of upgrading. Also see the test file t/upgrade2.t
    #return $upgrade -&gt; babs($x, @r)
    #  if defined($upgrade) &amp;&amp; !$x-&gt;isa(__PACKAGE__);

    $x-&gt;{sign} =~ s/^-/+/;

    $x -&gt; round(@r);
}

sub bsgn {
    # Signum function.
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('bsgn');

    # This call to the upgrade class must either be commented out or the method
    # must be implemented in the upgrade class(es) to avoid infinite recursion.
    # It doesn't help to check whether $x isa $upgrade, because there might be
    # several levels of upgrading. Also see the test file t/upgrade2.t
    #return $upgrade -&gt; bsgn($x, @r)
    #  if defined($upgrade) &amp;&amp; !$x-&gt;isa(__PACKAGE__);

    return $x -&gt; bone("+", @r) if $x -&gt; is_pos();
    return $x -&gt; bone("-", @r) if $x -&gt; is_neg();

    $x -&gt; round(@r);
}

sub bnorm {
    # (numstr or BINT) return BINT
    # Normalize number -- no-op here
    my ($class, $x, @r) = ref($_[0]) ? (undef, $_[0]) : objectify(1, @_);

    # This method is called from the rounding methods, so if this method
    # supports rounding by calling the rounding methods, we get an infinite
    # recursion.

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    $x;
}

sub binc {
    # increment arg by one
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('binc');

    return $x-&gt;round(@r) if $x -&gt; is_inf() || $x -&gt; is_nan();

    return $upgrade -&gt; binc($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    if ($x-&gt;{sign} eq '+') {
        $x-&gt;{value} = $LIB-&gt;_inc($x-&gt;{value});
    } elsif ($x-&gt;{sign} eq '-') {
        $x-&gt;{value} = $LIB-&gt;_dec($x-&gt;{value});
        $x-&gt;{sign} = '+' if $LIB-&gt;_is_zero($x-&gt;{value}); # -1 +1 =&gt; -0 =&gt; +0
    }

    return $x-&gt;round(@r);
}

sub bdec {
    # decrement arg by one
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('bdec');

    return $x-&gt;round(@r) if $x -&gt; is_inf() || $x -&gt; is_nan();

    return $upgrade -&gt; bdec($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);;

    if ($x-&gt;{sign} eq '-') {
        $x-&gt;{value} = $LIB-&gt;_inc($x-&gt;{value});
    } elsif ($x-&gt;{sign} eq '+') {
        if ($LIB-&gt;_is_zero($x-&gt;{value})) {      # +1 - 1 =&gt; +0
            $x-&gt;{value} = $LIB-&gt;_one();
            $x-&gt;{sign} = '-';
        } else {
            $x-&gt;{value} = $LIB-&gt;_dec($x-&gt;{value});
        }
    }

    return $x-&gt;round(@r);
}

#sub bstrcmp {
#    my $self    = shift;
#    my $selfref = ref $self;
#    my $class   = $selfref || $self;
#
#    croak 'bstrcmp() is an instance method, not a class method'
#        unless $selfref;
#    croak 'Wrong number of arguments for bstrcmp()' unless @_ == 1;
#
#    return $self -&gt; bstr() CORE::cmp shift;
#}
#
#sub bstreq {
#    my $self    = shift;
#    my $selfref = ref $self;
#    my $class   = $selfref || $self;
#
#    croak 'bstreq() is an instance method, not a class method'
#        unless $selfref;
#    croak 'Wrong number of arguments for bstreq()' unless @_ == 1;
#
#    my $cmp = $self -&gt; bstrcmp(shift);
#    return defined($cmp) &amp;&amp; ! $cmp;
#}
#
#sub bstrne {
#    my $self    = shift;
#    my $selfref = ref $self;
#    my $class   = $selfref || $self;
#
#    croak 'bstrne() is an instance method, not a class method'
#        unless $selfref;
#    croak 'Wrong number of arguments for bstrne()' unless @_ == 1;
#
#    my $cmp = $self -&gt; bstrcmp(shift);
#    return defined($cmp) &amp;&amp; ! $cmp ? '' : 1;
#}
#
#sub bstrlt {
#    my $self    = shift;
#    my $selfref = ref $self;
#    my $class   = $selfref || $self;
#
#    croak 'bstrlt() is an instance method, not a class method'
#        unless $selfref;
#    croak 'Wrong number of arguments for bstrlt()' unless @_ == 1;
#
#    my $cmp = $self -&gt; bstrcmp(shift);
#    return defined($cmp) &amp;&amp; $cmp &lt; 0;
#}
#
#sub bstrle {
#    my $self    = shift;
#    my $selfref = ref $self;
#    my $class   = $selfref || $self;
#
#    croak 'bstrle() is an instance method, not a class method'
#        unless $selfref;
#    croak 'Wrong number of arguments for bstrle()' unless @_ == 1;
#
#    my $cmp = $self -&gt; bstrcmp(shift);
#    return defined($cmp) &amp;&amp; $cmp &lt;= 0;
#}
#
#sub bstrgt {
#    my $self    = shift;
#    my $selfref = ref $self;
#    my $class   = $selfref || $self;
#
#    croak 'bstrgt() is an instance method, not a class method'
#        unless $selfref;
#    croak 'Wrong number of arguments for bstrgt()' unless @_ == 1;
#
#    my $cmp = $self -&gt; bstrcmp(shift);
#    return defined($cmp) &amp;&amp; $cmp &gt; 0;
#}
#
#sub bstrge {
#    my $self    = shift;
#    my $selfref = ref $self;
#    my $class   = $selfref || $self;
#
#    croak 'bstrge() is an instance method, not a class method'
#        unless $selfref;
#    croak 'Wrong number of arguments for bstrge()' unless @_ == 1;
#
#    my $cmp = $self -&gt; bstrcmp(shift);
#    return defined($cmp) &amp;&amp; $cmp &gt;= 0;
#}

sub badd {
    # add second arg (BINT or string) to first (BINT) (modifies first)
    # return result as BINT

    # set up parameters
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    return $x if $x-&gt;modify('badd');

    $r[3] = $y;                 # no push!

    return $upgrade-&gt;badd($x, $y, @r)
      if defined($upgrade) &amp;&amp; (!$x-&gt;isa(__PACKAGE__) || !$y-&gt;isa(__PACKAGE__));

    # Inf and NaN handling
    if ($x-&gt;{sign} !~ /^[+-]$/ || $y-&gt;{sign} !~ /^[+-]$/) {
        # NaN first
        return $x-&gt;bnan(@r) if (($x-&gt;{sign} eq $nan) || ($y-&gt;{sign} eq $nan));
        # Inf handling
        if (($x-&gt;{sign} =~ /^[+-]inf$/) &amp;&amp; ($y-&gt;{sign} =~ /^[+-]inf$/)) {
            # +Inf + +Inf or -Inf + -Inf =&gt; same, rest is NaN
            return $x-&gt;round(@r) if $x-&gt;{sign} eq $y-&gt;{sign};
            return $x-&gt;bnan(@r);
        }
        # Â±Inf + something =&gt; Â±Inf
        # something + Â±Inf =&gt; Â±Inf
        if ($y-&gt;{sign} =~ /^[+-]inf$/) {
            $x-&gt;{sign} = $y-&gt;{sign};
        }
        return $x -&gt; round(@r);
    }

    ($x-&gt;{value}, $x-&gt;{sign})
      = $LIB -&gt; _sadd($x-&gt;{value}, $x-&gt;{sign}, $y-&gt;{value}, $y-&gt;{sign});
    $x-&gt;round(@r);
}

sub bsub {
    # (BINT or num_str, BINT or num_str) return BINT
    # subtract second arg from first, modify first

    # set up parameters
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    return $x if $x -&gt; modify('bsub');

    return $upgrade -&gt; bsub($x, $y, @r)
      if defined($upgrade) &amp;&amp; (!$x-&gt;isa(__PACKAGE__) || !$y-&gt;isa(__PACKAGE__));

    return $x -&gt; round(@r) if $y -&gt; is_zero();

    # To correctly handle the lone special case $x -&gt; bsub($x), we note the
    # sign of $x, then flip the sign from $y, and if the sign of $x did change,
    # too, then we caught the special case:

    my $xsign = $x -&gt; {sign};
    $y -&gt; {sign} =~ tr/+-/-+/;  # does nothing for NaN
    if ($xsign ne $x -&gt; {sign}) {
        # special case of $x -&gt; bsub($x) results in 0
        return $x -&gt; bzero(@r) if $xsign =~ /^[+-]$/;
        return $x -&gt; bnan(@r);    # NaN, -inf, +inf
    }

    $x = $x -&gt; badd($y, @r);    # badd() does not leave internal zeros
    $y -&gt; {sign} =~ tr/+-/-+/;  # refix $y (does nothing for NaN)
    $x;                         # already rounded by badd() or no rounding
}

sub bmul {
    # multiply the first number by the second number
    # (BINT or num_str, BINT or num_str) return BINT

    # set up parameters
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    return $x if $x-&gt;modify('bmul');

    return $x-&gt;bnan(@r) if (($x-&gt;{sign} eq $nan) || ($y-&gt;{sign} eq $nan));

    # inf handling
    if (($x-&gt;{sign} =~ /^[+-]inf$/) || ($y-&gt;{sign} =~ /^[+-]inf$/)) {
        return $x-&gt;bnan(@r) if $x-&gt;is_zero() || $y-&gt;is_zero();
        # result will always be +-inf:
        # +inf * +/+inf =&gt; +inf, -inf * -/-inf =&gt; +inf
        # +inf * -/-inf =&gt; -inf, -inf * +/+inf =&gt; -inf
        return $x-&gt;binf(@r) if ($x-&gt;{sign} =~ /^\+/ &amp;&amp; $y-&gt;{sign} =~ /^\+/);
        return $x-&gt;binf(@r) if ($x-&gt;{sign} =~ /^-/ &amp;&amp; $y-&gt;{sign} =~ /^-/);
        return $x-&gt;binf('-', @r);
    }

    return $upgrade-&gt;bmul($x, $y, @r)
      if defined($upgrade) &amp;&amp; (!$x-&gt;isa(__PACKAGE__) || !$y-&gt;isa(__PACKAGE__));

    $r[3] = $y;                 # no push here

    $x-&gt;{sign} = $x-&gt;{sign} eq $y-&gt;{sign} ? '+' : '-'; # +1 * +1 or -1 * -1 =&gt; +

    $x-&gt;{value} = $LIB-&gt;_mul($x-&gt;{value}, $y-&gt;{value}); # do actual math
    $x-&gt;{sign} = '+' if $LIB-&gt;_is_zero($x-&gt;{value});   # no -0

    $x-&gt;round(@r);
}

sub bmuladd {
    # multiply two numbers and then add the third to the result
    # (BINT or num_str, BINT or num_str, BINT or num_str) return BINT

    # set up parameters
    my ($class, $x, $y, $z, @r)
      = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1]) &amp;&amp; ref($_[1]) eq ref($_[2])
      ? (ref($_[0]), @_)
      : objectify(3, @_);

    return $x if $x-&gt;modify('bmuladd');

    # x, y, and z are finite numbers

    if ($x-&gt;{sign} =~ /^[+-]$/ &amp;&amp;
        $y-&gt;{sign} =~ /^[+-]$/ &amp;&amp;
        $z-&gt;{sign} =~ /^[+-]$/)
    {
        return $upgrade-&gt;bmuladd($x, $y, $z, @r)
          if defined($upgrade) &amp;&amp; (!$x-&gt;isa(__PACKAGE__) ||
                                   !$y-&gt;isa(__PACKAGE__) ||
                                   !$z-&gt;isa(__PACKAGE__));

        # TODO: what if $y and $z have A or P set?
        $r[3] = $z;             # no push here

        my $zs = $z-&gt;{sign};
        my $zv = $z-&gt;{value};
        $zv = $LIB -&gt; _copy($zv) if refaddr($x) eq refaddr($z);

        $x-&gt;{sign} = $x-&gt;{sign} eq $y-&gt;{sign} ? '+' : '-'; # +1 * +1 or -1 * -1 =&gt; +
        $x-&gt;{value} = $LIB-&gt;_mul($x-&gt;{value}, $y-&gt;{value}); # do actual math
        $x-&gt;{sign} = '+' if $LIB-&gt;_is_zero($x-&gt;{value});    # no -0

        ($x-&gt;{value}, $x-&gt;{sign})
          = $LIB -&gt; _sadd($x-&gt;{value}, $x-&gt;{sign}, $zv, $zs);
        return $x-&gt;round(@r);
    }

    # At least one of x, y, and z is a NaN

    return $x-&gt;bnan(@r) if (($x-&gt;{sign} eq $nan) ||
                            ($y-&gt;{sign} eq $nan) ||
                            ($z-&gt;{sign} eq $nan));

    # At least one of x, y, and z is an Inf

    if ($x-&gt;{sign} eq "-inf") {

        if ($y -&gt; is_neg()) {               # x = -inf, y &lt; 0
            if ($z-&gt;{sign} eq "-inf") {
                return $x-&gt;bnan(@r);
            } else {
                return $x-&gt;binf("+", @r);
            }
        } elsif ($y -&gt; is_zero()) {         # x = -inf, y = 0
            return $x-&gt;bnan(@r);
        } else {                            # x = -inf, y &gt; 0
            if ($z-&gt;{sign} eq "+inf") {
                return $x-&gt;bnan(@r);
            } else {
                return $x-&gt;binf("-", @r);
            }
        }

    } elsif ($x-&gt;{sign} eq "+inf") {

        if ($y -&gt; is_neg()) {               # x = +inf, y &lt; 0
            if ($z-&gt;{sign} eq "+inf") {
                return $x-&gt;bnan(@r);
            } else {
                return $x-&gt;binf("-", @r);
            }
        } elsif ($y -&gt; is_zero()) {         # x = +inf, y = 0
            return $x-&gt;bnan(@r);
        } else {                            # x = +inf, y &gt; 0
            if ($z-&gt;{sign} eq "-inf") {
                return $x-&gt;bnan(@r);
            } else {
                return $x-&gt;binf("+", @r);
            }
        }

    } elsif ($x -&gt; is_neg()) {

        if ($y-&gt;{sign} eq "-inf") {         # -inf &lt; x &lt; 0, y = -inf
            if ($z-&gt;{sign} eq "-inf") {
                return $x-&gt;bnan(@r);
            } else {
                return $x-&gt;binf("+", @r);
            }
        } elsif ($y-&gt;{sign} eq "+inf") {    # -inf &lt; x &lt; 0, y = +inf
            if ($z-&gt;{sign} eq "+inf") {
                return $x-&gt;bnan(@r);
            } else {
                return $x-&gt;binf("-", @r);
            }
        } else {                            # -inf &lt; x &lt; 0, -inf &lt; y &lt; +inf
            if ($z-&gt;{sign} eq "-inf") {
                return $x-&gt;binf("-", @r);
            } elsif ($z-&gt;{sign} eq "+inf") {
                return $x-&gt;binf("+", @r);
            }
        }

    } elsif ($x -&gt; is_zero()) {

        if ($y-&gt;{sign} eq "-inf") {         # x = 0, y = -inf
            return $x-&gt;bnan(@r);
        } elsif ($y-&gt;{sign} eq "+inf") {    # x = 0, y = +inf
            return $x-&gt;bnan(@r);
        } else {                            # x = 0, -inf &lt; y &lt; +inf
            if ($z-&gt;{sign} eq "-inf") {
                return $x-&gt;binf("-", @r);
            } elsif ($z-&gt;{sign} eq "+inf") {
                return $x-&gt;binf("+", @r);
            }
        }

    } elsif ($x -&gt; is_pos()) {

        if ($y-&gt;{sign} eq "-inf") {         # 0 &lt; x &lt; +inf, y = -inf
            if ($z-&gt;{sign} eq "+inf") {
                return $x-&gt;bnan(@r);
            } else {
                return $x-&gt;binf("-", @r);
            }
        } elsif ($y-&gt;{sign} eq "+inf") {    # 0 &lt; x &lt; +inf, y = +inf
            if ($z-&gt;{sign} eq "-inf") {
                return $x-&gt;bnan(@r);
            } else {
                return $x-&gt;binf("+", @r);
            }
        } else {                            # 0 &lt; x &lt; +inf, -inf &lt; y &lt; +inf
            if ($z-&gt;{sign} eq "-inf") {
                return $x-&gt;binf("-", @r);
            } elsif ($z-&gt;{sign} eq "+inf") {
                return $x-&gt;binf("+", @r);
            }
        }
    }

    die;
}

sub bdiv {
    # This does floored division, where the quotient is floored, i.e., rounded
    # towards negative infinity. As a consequence, the remainder has the same
    # sign as the divisor.

    # Set up parameters.
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    return $x if $x -&gt; modify('bdiv');

    my $wantarray = wantarray;          # call only once

    # At least one argument is NaN. Return NaN for both quotient and the
    # modulo/remainder.

    if ($x -&gt; is_nan() || $y -&gt; is_nan()) {
        return $wantarray ? ($x -&gt; bnan(@r), $class -&gt; bnan(@r))
                          : $x -&gt; bnan(@r);
    }

    # Divide by zero and modulo zero.
    #
    # Division: Use the common convention that x / 0 is inf with the same sign
    # as x, except when x = 0, where we return NaN. This is also what earlier
    # versions did.
    #
    # Modulo: In modular arithmetic, the congruence relation z = x (mod y)
    # means that there is some integer k such that z - x = k y. If y = 0, we
    # get z - x = 0 or z = x. This is also what earlier versions did, except
    # that 0 % 0 returned NaN.
    #
    #     inf /    0 =  inf                  inf %    0 =  inf
    #       5 /    0 =  inf                    5 %    0 =    5
    #       0 /    0 =  NaN                    0 %    0 =    0
    #      -5 /    0 = -inf                   -5 %    0 =   -5
    #    -inf /    0 = -inf                 -inf %    0 = -inf

    if ($y -&gt; is_zero()) {
        my $rem;
        if ($wantarray) {
            $rem = $x -&gt; copy() -&gt; round(@r);
        }
        if ($x -&gt; is_zero()) {
            $x = $x -&gt; bnan(@r);
        } else {
            $x = $x -&gt; binf($x -&gt; {sign}, @r);
        }
        return $wantarray ? ($x, $rem) : $x;
    }

    # Numerator (dividend) is +/-inf, and denominator is finite and non-zero.
    # The divide by zero cases are covered above. In all of the cases listed
    # below we return the same as core Perl.
    #
    #     inf / -inf =  NaN                  inf % -inf =  NaN
    #     inf /   -5 = -inf                  inf %   -5 =  NaN
    #     inf /    5 =  inf                  inf %    5 =  NaN
    #     inf /  inf =  NaN                  inf %  inf =  NaN
    #
    #    -inf / -inf =  NaN                 -inf % -inf =  NaN
    #    -inf /   -5 =  inf                 -inf %   -5 =  NaN
    #    -inf /    5 = -inf                 -inf %    5 =  NaN
    #    -inf /  inf =  NaN                 -inf %  inf =  NaN

    if ($x -&gt; is_inf()) {
        my $rem;
        $rem = $class -&gt; bnan(@r) if $wantarray;
        if ($y -&gt; is_inf()) {
            $x = $x -&gt; bnan(@r);
        } else {
            my $sign = $x -&gt; bcmp(0) == $y -&gt; bcmp(0) ? '+' : '-';
            $x = $x -&gt; binf($sign, @r);
        }
        return $wantarray ? ($x, $rem) : $x;
    }

    # Denominator (divisor) is +/-inf. The cases when the numerator is +/-inf
    # are covered above. In the modulo cases (in the right column) we return
    # the same as core Perl, which does floored division, so for consistency we
    # also do floored division in the division cases (in the left column).
    #
    #      -5 /  inf =   -1                   -5 %  inf =  inf
    #       0 /  inf =    0                    0 %  inf =    0
    #       5 /  inf =    0                    5 %  inf =    5
    #
    #      -5 / -inf =    0                   -5 % -inf =   -5
    #       0 / -inf =    0                    0 % -inf =    0
    #       5 / -inf =   -1                    5 % -inf = -inf

    if ($y -&gt; is_inf()) {
        my $rem;
        if ($x -&gt; is_zero() || $x -&gt; bcmp(0) == $y -&gt; bcmp(0)) {
            $rem = $x -&gt; copy() -&gt; round(@r) if $wantarray;
            $x = $x -&gt; bzero(@r);
        } else {
            $rem = $class -&gt; binf($y -&gt; {sign}, @r) if $wantarray;
            $x = $x -&gt; bone('-', @r);
        }
        return $wantarray ? ($x, $rem) : $x;
    }

    # At this point, both the numerator and denominator are finite numbers, and
    # the denominator (divisor) is non-zero.

    # Division might return a non-integer result, so upgrade unconditionally, if
    # upgrading is enabled.

    return $upgrade -&gt; bdiv($x, $y, @r) if defined $upgrade;

    $r[3] = $y;                                   # no push!

    # Inialize remainder.

    my $rem = $class -&gt; bzero();

    # Are both operands the same object, i.e., like $x -&gt; bdiv($x)? If so,
    # flipping the sign of $y also flips the sign of $x.

    my $xsign = $x -&gt; {sign};
    my $ysign = $y -&gt; {sign};

    $y -&gt; {sign} =~ tr/+-/-+/;            # Flip the sign of $y, and see ...
    my $same = $xsign ne $x -&gt; {sign};    # ... if that changed the sign of $x.
    $y -&gt; {sign} = $ysign;                # Re-insert the original sign.

    if ($same) {
        $x = $x -&gt; bone();
    } else {
        ($x -&gt; {value}, $rem -&gt; {value}) =
          $LIB -&gt; _div($x -&gt; {value}, $y -&gt; {value});

        if ($LIB -&gt; _is_zero($rem -&gt; {value})) {
            if ($xsign eq $ysign || $LIB -&gt; _is_zero($x -&gt; {value})) {
                $x -&gt; {sign} = '+';
            } else {
                $x -&gt; {sign} = '-';
            }
        } else {
            if ($xsign eq $ysign) {
                $x -&gt; {sign} = '+';
            } else {
                if ($xsign eq '+') {
                    $x = $x -&gt; badd(1);
                } else {
                    $x = $x -&gt; bsub(1);
                }
                $x -&gt; {sign} = '-';
            }
        }
    }

    $x = $x -&gt; round(@r);

    if ($wantarray) {
        unless ($LIB -&gt; _is_zero($rem -&gt; {value})) {
            if ($xsign ne $ysign) {
                $rem = $y -&gt; copy() -&gt; babs() -&gt; bsub($rem);
            }
            $rem -&gt; {sign} = $ysign;
        }
        $rem -&gt; {accuracy} = $x -&gt; {accuracy};
        $rem -&gt; {precision} = $x -&gt; {precision};
        $rem = $rem -&gt; round(@r);
        return ($x, $rem);
    }

    return $x;
}

sub btdiv {
    # This does truncated division, where the quotient is truncted, i.e.,
    # rounded towards zero.
    #
    # ($q, $r) = $x -&gt; btdiv($y) returns $q and $r so that $q is int($x / $y)
    # and $q * $y + $r = $x.

    # Set up parameters
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    return $x if $x -&gt; modify('btdiv');

    my $wantarray = wantarray;          # call only once

    # At least one argument is NaN. Return NaN for both quotient and the
    # modulo/remainder.

    if ($x -&gt; is_nan() || $y -&gt; is_nan()) {
        return $wantarray ? ($x -&gt; bnan(@r), $class -&gt; bnan(@r))
                          : $x -&gt; bnan(@r);
    }

    # Divide by zero and modulo zero.
    #
    # Division: Use the common convention that x / 0 is inf with the same sign
    # as x, except when x = 0, where we return NaN. This is also what earlier
    # versions did.
    #
    # Modulo: In modular arithmetic, the congruence relation z = x (mod y)
    # means that there is some integer k such that z - x = k y. If y = 0, we
    # get z - x = 0 or z = x. This is also what earlier versions did, except
    # that 0 % 0 returned NaN.
    #
    #     inf / 0 =  inf                     inf % 0 =  inf
    #       5 / 0 =  inf                       5 % 0 =    5
    #       0 / 0 =  NaN                       0 % 0 =    0
    #      -5 / 0 = -inf                      -5 % 0 =   -5
    #    -inf / 0 = -inf                    -inf % 0 = -inf

    if ($y -&gt; is_zero()) {
        my $rem;
        if ($wantarray) {
            $rem = $x -&gt; copy(@r);
        }
        if ($x -&gt; is_zero()) {
            $x = $x -&gt; bnan(@r);
        } else {
            $x = $x -&gt; binf($x -&gt; {sign}, @r);
        }
        return $wantarray ? ($x, $rem) : $x;
    }

    # Numerator (dividend) is +/-inf, and denominator is finite and non-zero.
    # The divide by zero cases are covered above. In all of the cases listed
    # below we return the same as core Perl.
    #
    #     inf / -inf =  NaN                  inf % -inf =  NaN
    #     inf /   -5 = -inf                  inf %   -5 =  NaN
    #     inf /    5 =  inf                  inf %    5 =  NaN
    #     inf /  inf =  NaN                  inf %  inf =  NaN
    #
    #    -inf / -inf =  NaN                 -inf % -inf =  NaN
    #    -inf /   -5 =  inf                 -inf %   -5 =  NaN
    #    -inf /    5 = -inf                 -inf %    5 =  NaN
    #    -inf /  inf =  NaN                 -inf %  inf =  NaN

    if ($x -&gt; is_inf()) {
        my $rem;
        $rem = $class -&gt; bnan(@r) if $wantarray;
        if ($y -&gt; is_inf()) {
            $x = $x -&gt; bnan(@r);
        } else {
            my $sign = $x -&gt; bcmp(0) == $y -&gt; bcmp(0) ? '+' : '-';
            $x = $x -&gt; binf($sign,@r );
        }
        return $wantarray ? ($x, $rem) : $x;
    }

    # Denominator (divisor) is +/-inf. The cases when the numerator is +/-inf
    # are covered above. In the modulo cases (in the right column) we return
    # the same as core Perl, which does floored division, so for consistency we
    # also do floored division in the division cases (in the left column).
    #
    #      -5 /  inf =    0                   -5 %  inf =  -5
    #       0 /  inf =    0                    0 %  inf =   0
    #       5 /  inf =    0                    5 %  inf =   5
    #
    #      -5 / -inf =    0                   -5 % -inf =  -5
    #       0 / -inf =    0                    0 % -inf =   0
    #       5 / -inf =    0                    5 % -inf =   5

    if ($y -&gt; is_inf()) {
        my $rem;
        $rem = $x -&gt; copy() -&gt; round(@r) if $wantarray;
        $x = $x -&gt; bzero(@r);
        return $wantarray ? ($x, $rem) : $x;
    }

    # Division might return a non-integer result, so upgrade unconditionally, if
    # upgrading is enabled.

    return $upgrade -&gt; btdiv($x, $y, @r) if defined $upgrade;

    $r[3] = $y;                 # no push!

    # Inialize remainder.

    my $rem = $class -&gt; bzero();

    # Are both operands the same object, i.e., like $x -&gt; bdiv($x)? If so,
    # flipping the sign of $y also flips the sign of $x.

    my $xsign = $x -&gt; {sign};
    my $ysign = $y -&gt; {sign};

    $y -&gt; {sign} =~ tr/+-/-+/;            # Flip the sign of $y, and see ...
    my $same = $xsign ne $x -&gt; {sign};    # ... if that changed the sign of $x.
    $y -&gt; {sign} = $ysign;                # Re-insert the original sign.

    if ($same) {
        $x = $x -&gt; bone(@r);
    } else {
        ($x -&gt; {value}, $rem -&gt; {value}) =
          $LIB -&gt; _div($x -&gt; {value}, $y -&gt; {value});

        $x -&gt; {sign} = $xsign eq $ysign ? '+' : '-';
        $x -&gt; {sign} = '+' if $LIB -&gt; _is_zero($x -&gt; {value});
        $x = $x -&gt; round(@r);
    }

    if (wantarray) {
        $rem -&gt; {sign} = $xsign;
        $rem -&gt; {sign} = '+' if $LIB -&gt; _is_zero($rem -&gt; {value});
        $rem -&gt; {accuracy} = $x -&gt; {accuracy};
        $rem -&gt; {precision} = $x -&gt; {precision};
        $rem = $rem -&gt; round(@r);
        return ($x, $rem);
    }

    return $x;
}

sub bmod {
    # This is the remainder after floored division.

    # Set up parameters.
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    return $x if $x -&gt; modify('bmod');

    $r[3] = $y;                 # no push!

    # At least one argument is NaN.

    if ($x -&gt; is_nan() || $y -&gt; is_nan()) {
        return $x -&gt; bnan(@r);
    }

    # Modulo zero. See documentation for bdiv().

    if ($y -&gt; is_zero()) {
        return $x -&gt; round(@r);
    }

    # Numerator (dividend) is +/-inf.

    if ($x -&gt; is_inf()) {
        return $x -&gt; bnan(@r);
    }

    # Denominator (divisor) is +/-inf.

    if ($y -&gt; is_inf()) {
        if ($x -&gt; is_zero() || $x -&gt; bcmp(0) == $y -&gt; bcmp(0)) {
            return $x -&gt; round(@r);
        } else {
            return $x -&gt; binf($y -&gt; sign(), @r);
        }
    }

    return $upgrade -&gt; bmod($x, $y, @r)
      if defined($upgrade) &amp;&amp; (!$x -&gt; isa(__PACKAGE__) ||
                               !$y -&gt; isa(__PACKAGE__));

    # Calc new sign and in case $y == +/- 1, return $x.

    $x -&gt; {value} = $LIB -&gt; _mod($x -&gt; {value}, $y -&gt; {value});
    if ($LIB -&gt; _is_zero($x -&gt; {value})) {
        $x -&gt; {sign} = '+';     # do not leave -0
    } else {
        $x -&gt; {value} = $LIB -&gt; _sub($y -&gt; {value}, $x -&gt; {value}, 1) # $y-$x
          if ($x -&gt; {sign} ne $y -&gt; {sign});
        $x -&gt; {sign} = $y -&gt; {sign};
    }

    $x -&gt; round(@r);
}

sub btmod {
    # Remainder after truncated division.

    # set up parameters
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    return $x if $x -&gt; modify('btmod');

    # At least one argument is NaN.

    if ($x -&gt; is_nan() || $y -&gt; is_nan()) {
        return $x -&gt; bnan(@r);
    }

    # Modulo zero. See documentation for btdiv().

    if ($y -&gt; is_zero()) {
        return $x -&gt; round(@r);
    }

    # Numerator (dividend) is +/-inf.

    if ($x -&gt; is_inf()) {
        return $x -&gt; bnan(@r);
    }

    # Denominator (divisor) is +/-inf.

    if ($y -&gt; is_inf()) {
        return $x -&gt; round(@r);
    }

    return $upgrade -&gt; btmod($x, $y, @r)
      if defined($upgrade) &amp;&amp; (!$x -&gt; isa(__PACKAGE__) ||
                               !$y -&gt; isa(__PACKAGE__));

    $r[3] = $y;                 # no push!

    my $xsign = $x -&gt; {sign};

    $x -&gt; {value} = $LIB -&gt; _mod($x -&gt; {value}, $y -&gt; {value});

    $x -&gt; {sign} = $xsign;
    $x -&gt; {sign} = '+' if $LIB -&gt; _is_zero($x -&gt; {value});
    $x -&gt; round(@r);
}

sub bmodinv {
    # Return modular multiplicative inverse:
    #
    #   z is the modular inverse of x (mod y) if and only if
    #
    #       x*z â‰¡ 1  (mod y)
    #
    # If the modulus y is larger than one, x and z are relative primes (i.e.,
    # their greatest common divisor is one).
    #
    # If no modular multiplicative inverse exists, NaN is returned.

    # set up parameters
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    return $x if $x-&gt;modify('bmodinv');

    # Return NaN if one or both arguments is +inf, -inf, or nan.

    return $x-&gt;bnan(@r) if ($y-&gt;{sign} !~ /^[+-]$/ ||
                            $x-&gt;{sign} !~ /^[+-]$/);

    # Return NaN if $y is zero; 1 % 0 makes no sense.

    return $x-&gt;bnan(@r) if $y-&gt;is_zero();

    # Return 0 in the trivial case. $x % 1 or $x % -1 is zero for all finite
    # integers $x.

    return $x-&gt;bzero(@r) if ($y-&gt;is_one('+') ||
                             $y-&gt;is_one('-'));

    return $upgrade -&gt; bmodinv($x, $y, @r)
      if defined($upgrade) &amp;&amp; (!$x -&gt; isa(__PACKAGE__) ||
                               !$y -&gt; isa(__PACKAGE__));

    # Return NaN if $x = 0, or $x modulo $y is zero. The only valid case when
    # $x = 0 is when $y = 1 or $y = -1, but that was covered above.
    #
    # Note that computing $x modulo $y here affects the value we'll feed to
    # $LIB-&gt;_modinv() below when $x and $y have opposite signs. E.g., if $x =
    # 5 and $y = 7, those two values are fed to _modinv(), but if $x = -5 and
    # $y = 7, the values fed to _modinv() are $x = 2 (= -5 % 7) and $y = 7.
    # The value if $x is affected only when $x and $y have opposite signs.

    $x = $x-&gt;bmod($y);
    return $x-&gt;bnan(@r) if $x-&gt;is_zero();

    # Compute the modular multiplicative inverse of the absolute values. We'll
    # correct for the signs of $x and $y later. Return NaN if no GCD is found.

    ($x-&gt;{value}, $x-&gt;{sign}) = $LIB-&gt;_modinv($x-&gt;{value}, $y-&gt;{value});
    return $x-&gt;bnan(@r) if !defined($x-&gt;{value});

    # Library inconsistency workaround: _modinv() in Math::BigInt::GMP versions
    # &lt;= 1.32 return undef rather than a "+" for the sign.

    $x-&gt;{sign} = '+' unless defined $x-&gt;{sign};

    # When one or both arguments are negative, we have the following
    # relations.  If x and y are positive:
    #
    #   modinv(-x, -y) = -modinv(x, y)
    #   modinv(-x, y) = y - modinv(x, y)  = -modinv(x, y) (mod y)
    #   modinv( x, -y) = modinv(x, y) - y  =  modinv(x, y) (mod -y)

    # We must swap the sign of the result if the original $x is negative.
    # However, we must compensate for ignoring the signs when computing the
    # inverse modulo. The net effect is that we must swap the sign of the
    # result if $y is negative.

    $x = $x -&gt; bneg() if $y-&gt;{sign} eq '-';

    # Compute $x modulo $y again after correcting the sign.

    $x = $x -&gt; bmod($y) if $x-&gt;{sign} ne $y-&gt;{sign};

    $x -&gt; round(@r);
}

sub bmodpow {
    # Modular exponentiation. Raises a very large number to a very large
    # exponent in a given very large modulus quickly, thanks to binary
    # exponentiation.  Supports negative exponents.
    my ($class, $num, $exp, $mod, @r)
      = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1]) &amp;&amp; ref($_[1]) eq ref($_[2])
      ? (ref($_[0]), @_)
      : objectify(3, @_);

    return $num if $num-&gt;modify('bmodpow');

    # When the exponent 'e' is negative, use the following relation, which is
    # based on finding the multiplicative inverse 'd' of 'b' modulo 'm':
    #
    #    b^(-e) (mod m) = d^e (mod m) where b*d = 1 (mod m)

    $num = $num -&gt; bmodinv($mod) if ($exp-&gt;{sign} eq '-');

    # Check for valid input. All operands must be finite, and the modulus must
    # be non-zero.

    return $num-&gt;bnan(@r) if ($num-&gt;{sign} =~ /NaN|inf/ ||  # NaN, -inf, +inf
                              $exp-&gt;{sign} =~ /NaN|inf/ ||  # NaN, -inf, +inf
                              $mod-&gt;{sign} =~ /NaN|inf/);   # NaN, -inf, +inf

    # Modulo zero. See documentation for Math::BigInt's bmod() method.

    if ($mod -&gt; is_zero()) {
        if ($num -&gt; is_zero()) {
            return $class -&gt; bnan(@r);
        } else {
            return $num -&gt; copy(@r);
        }
    }

    return $upgrade -&gt; bmodinv($num, $exp, $mod, @r)
      if defined($upgrade) &amp;&amp; (!$num -&gt; isa(__PACKAGE__) ||
                               !$exp -&gt; isa(__PACKAGE__) ||
                               !$mod -&gt; ($class));

    # Compute 'a (mod m)', ignoring the signs on 'a' and 'm'. If the resulting
    # value is zero, the output is also zero, regardless of the signs on 'a' and
    # 'm'.

    my $value = $LIB-&gt;_modpow($num-&gt;{value}, $exp-&gt;{value}, $mod-&gt;{value});
    my $sign  = '+';

    # If the resulting value is non-zero, we have four special cases, depending
    # on the signs on 'a' and 'm'.

    unless ($LIB-&gt;_is_zero($value)) {

        # There is a negative sign on 'a' (= $num**$exp) only if the number we
        # are exponentiating ($num) is negative and the exponent ($exp) is odd.

        if ($num-&gt;{sign} eq '-' &amp;&amp; $exp-&gt;is_odd()) {

            # When both the number 'a' and the modulus 'm' have a negative sign,
            # use this relation:
            #
            #    -a (mod -m) = -(a (mod m))

            if ($mod-&gt;{sign} eq '-') {
                $sign = '-';
            }

            # When only the number 'a' has a negative sign, use this relation:
            #
            #    -a (mod m) = m - (a (mod m))

            else {
                # Use copy of $mod since _sub() modifies the first argument.
                my $mod = $LIB-&gt;_copy($mod-&gt;{value});
                $value = $LIB-&gt;_sub($mod, $value);
                $sign  = '+';
            }

        } else {

            # When only the modulus 'm' has a negative sign, use this relation:
            #
            #    a (mod -m) = (a (mod m)) - m
            #               = -(m - (a (mod m)))

            if ($mod-&gt;{sign} eq '-') {
                # Use copy of $mod since _sub() modifies the first argument.
                my $mod = $LIB-&gt;_copy($mod-&gt;{value});
                $value = $LIB-&gt;_sub($mod, $value);
                $sign  = '-';
            }

            # When neither the number 'a' nor the modulus 'm' have a negative
            # sign, directly return the already computed value.
            #
            #    (a (mod m))

        }

    }

    $num-&gt;{value} = $value;
    $num-&gt;{sign}  = $sign;

    return $num -&gt; round(@r);
}

sub bpow {
    # (BINT or num_str, BINT or num_str) return BINT
    # compute power of two numbers -- stolen from Knuth Vol 2 pg 233
    # modifies first argument

    # set up parameters
    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    return $x if $x -&gt; modify('bpow');

    # $x and/or $y is a NaN
    return $x -&gt; bnan(@r) if $x -&gt; is_nan() || $y -&gt; is_nan();

    # $x and/or $y is a +/-Inf
    if ($x -&gt; is_inf("-")) {
        return $x -&gt; bzero(@r)      if $y -&gt; is_negative();
        return $x -&gt; bnan(@r)       if $y -&gt; is_zero();
        return $x -&gt; round(@r)      if $y -&gt; is_odd();
        return $x -&gt; bneg(@r);
    } elsif ($x -&gt; is_inf("+")) {
        return $x -&gt; bzero(@r)      if $y -&gt; is_negative();
        return $x -&gt; bnan(@r)       if $y -&gt; is_zero();
        return $x -&gt; round(@r);
    } elsif ($y -&gt; is_inf("-")) {
        return $x -&gt; bnan(@r)       if $x -&gt; is_one("-");
        return $x -&gt; binf("+", @r)  if $x -&gt; is_zero();
        return $x -&gt; bone(@r)       if $x -&gt; is_one("+");
        return $x -&gt; bzero(@r);
    } elsif ($y -&gt; is_inf("+")) {
        return $x -&gt; bnan(@r)       if $x -&gt; is_one("-");
        return $x -&gt; bzero(@r)      if $x -&gt; is_zero();
        return $x -&gt; bone(@r)       if $x -&gt; is_one("+");
        return $x -&gt; binf("+", @r);
    }

    if ($x -&gt; is_zero()) {
        return $x -&gt; bone(@r) if $y -&gt; is_zero();
        return $x -&gt; binf(@r) if $y -&gt; is_negative();
        return $x -&gt; round(@r);
    }

    if ($x -&gt; is_one("+")) {
        return $x -&gt; round(@r);
    }

    if ($x -&gt; is_one("-")) {
        return $x -&gt; round(@r) if $y -&gt; is_odd();
        return $x -&gt; bneg(@r);
    }

    return $upgrade -&gt; bpow($x, $y, @r) if defined $upgrade;

    # We don't support finite non-integers, so return zero. The reason for
    # returning zero, not NaN, is that all output is in the open interval (0,1),
    # and truncating that to integer gives zero.

    if ($y-&gt;{sign} eq '-' || !$y -&gt; isa(__PACKAGE__)) {
        return $x -&gt; bzero(@r);
    }

    $r[3] = $y;                 # no push!

    $x-&gt;{value} = $LIB -&gt; _pow($x-&gt;{value}, $y-&gt;{value});
    $x-&gt;{sign}  = $x -&gt; is_negative() &amp;&amp; $y -&gt; is_odd() ? '-' : '+';
    $x -&gt; round(@r);
}

sub binv {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), $_[0]) : objectify(1, @_);

    return $x if $x -&gt; modify('binv');

    return $x -&gt; binf("+", @r)  if $x -&gt; is_zero();
    return $x -&gt; bzero(@r)      if $x -&gt; is_inf();
    return $x -&gt; bnan(@r)       if $x -&gt; is_nan();
    return $x -&gt; round(@r)      if $x -&gt; is_one("+") || $x -&gt; is_one("-");

    return $upgrade -&gt; binv($x, @r) if defined $upgrade;
    $x -&gt; bzero(@r);
}

sub blog {
    # Return the logarithm of the operand. If a second operand is defined, that
    # value is used as the base, otherwise the base is assumed to be Euler's
    # constant.

    my ($class, $x, $base, @r);

    # Only objectify the base if it is defined, since an undefined base, as in
    # $x-&gt;blog() or $x-&gt;blog(undef) signals that the base is Euler's number =
    # 2.718281828...

    if (!ref($_[0]) &amp;&amp; $_[0] =~ /^[a-z]\w*(?:::\w+)*$/i) {
        # E.g., Math::BigInt-&gt;blog(256, 2)
        ($class, $x, $base, @r) =
          defined $_[2] ? objectify(2, @_) : objectify(1, @_);
    } else {
        # E.g., $x-&gt;blog(2) or the deprecated Math::BigInt::blog(256, 2)
        ($class, $x, $base, @r) =
          defined $_[1] ? objectify(2, @_) : objectify(1, @_);
    }

    return $x if $x-&gt;modify('blog');

    # Handle all exception cases and all trivial cases. I have used Wolfram
    # Alpha (http://www.wolframalpha.com) as the reference for these cases.

    return $x -&gt; bnan(@r) if $x -&gt; is_nan();

    if (defined $base) {
        $base = $class -&gt; new($base)
          unless defined(blessed($base)) &amp;&amp; $base -&gt; isa(__PACKAGE__);
        if ($base -&gt; is_nan() || $base -&gt; is_one()) {
            return $x -&gt; bnan(@r);
        } elsif ($base -&gt; is_inf() || $base -&gt; is_zero()) {
            return $x -&gt; bnan(@r) if $x -&gt; is_inf() || $x -&gt; is_zero();
            return $x -&gt; bzero(@r);
        } elsif ($base -&gt; is_negative()) {              # -inf &lt; base &lt; 0
            return $x -&gt; bzero(@r) if $x -&gt; is_one();   #     x = 1
            return $x -&gt; bone('+', @r)  if $x == $base; #     x = base
            # we can't handle these cases, so upgrade, if we can
            return $upgrade -&gt; blog($x, $base, @r) if defined $upgrade;
            return $x -&gt; bnan(@r);
        }
        return $x -&gt; bone(@r) if $x == $base;   # 0 &lt; base &amp;&amp; 0 &lt; x &lt; inf
    }

    # We now know that the base is either undefined or &gt;= 2 and finite.

    if ($x -&gt; is_inf()) {                       # x = +/-inf
        return $x -&gt; binf('+', @r);
    } elsif ($x -&gt; is_neg()) {                  # -inf &lt; x &lt; 0
        return $upgrade -&gt; blog($x, $base, @r) if defined $upgrade;
        return $x -&gt; bnan(@r);
    } elsif ($x -&gt; is_one()) {                  # x = 1
        return $x -&gt; bzero(@r);
    } elsif ($x -&gt; is_zero()) {                 # x = 0
        return $x -&gt; binf('-', @r);
    }

    # At this point we are done handling all exception cases and trivial cases.

    return $upgrade -&gt; blog($x, $base, @r) if defined $upgrade;

    # fix for bug #24969:
    # the default base is e (Euler's number) which is not an integer
    if (!defined $base) {
        require Math::BigFloat;

        # disable upgrading and downgrading

        my $upg = Math::BigFloat -&gt; upgrade();
        my $dng = Math::BigFloat -&gt; downgrade();
        Math::BigFloat -&gt; upgrade(undef);
        Math::BigFloat -&gt; downgrade(undef);

        my $u = Math::BigFloat -&gt; blog($x) -&gt; as_int();

        # reset upgrading and downgrading

        Math::BigFloat -&gt; upgrade($upg);
        Math::BigFloat -&gt; downgrade($dng);

        # modify $x in place

        $x-&gt;{value} = $u-&gt;{value};
        $x-&gt;{sign}  = $u-&gt;{sign};

        return $x -&gt; round(@r);
    }

    my ($rc) = $LIB -&gt; _log_int($x-&gt;{value}, $base-&gt;{value});
    return $x -&gt; bnan(@r) unless defined $rc;   # not possible to take log?
    $x-&gt;{value} = $rc;
    $x = $x -&gt; round(@r);
}

sub bexp {
    # Calculate e ** $x (Euler's number to the power of X), truncated to
    # an integer value.
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('bexp');

    # inf, -inf, NaN, &lt;0 =&gt; NaN
    return $x -&gt; bnan(@r)  if $x-&gt;{sign} eq 'NaN';
    return $x -&gt; bone(@r)  if $x-&gt;is_zero();
    return $x -&gt; round(@r) if $x-&gt;{sign} eq '+inf';
    return $x -&gt; bzero(@r) if $x-&gt;{sign} eq '-inf';

    return $upgrade -&gt; bexp($x, @r) if defined $upgrade;

    require Math::BigFloat;
    my $tmp = Math::BigFloat -&gt; bexp($x, @r) -&gt; as_int();
    $x-&gt;{value} = $tmp-&gt;{value};
    return $x -&gt; round(@r);
}

sub bilog2 {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x -&gt; modify('bilog2');

    return $upgrade -&gt; new($x, @r) unless $x -&gt; isa(__PACKAGE__);

    return $x -&gt; bnan(@r)        if $x -&gt; is_nan();
    return $x -&gt; binf("+", @r)   if $x -&gt; is_inf("+");
    return $x -&gt; binf("-", @r)   if $x -&gt; is_zero();
    if ($x -&gt; is_neg()) {
        return $upgrade -&gt; bilog2($x, @r) if $upgrade;
        return $x -&gt; bnan(@r);
    }

    $x -&gt; {value} = $LIB -&gt; _ilog2($x -&gt; {value});
    return $x -&gt; round(@r);
}

sub bilog10 {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x -&gt; modify('bilog10');

    return $upgrade -&gt; new($x, @r) unless $x -&gt; isa(__PACKAGE__);

    return $x -&gt; bnan(@r)        if $x -&gt; is_nan();
    return $x -&gt; binf("+", @r)   if $x -&gt; is_inf("+");
    return $x -&gt; binf("-", @r)   if $x -&gt; is_zero();
    if ($x -&gt; is_neg()) {
        return $upgrade -&gt; bilog2($x, @r) if $upgrade;
        return $x -&gt; bnan(@r);
    }

    $x -&gt; {value} = $LIB -&gt; _ilog10($x -&gt; {value});
    return $x -&gt; round(@r);
}

sub bclog2 {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x -&gt; modify('bclog2');

    return $upgrade -&gt; new($x, @r) unless $x -&gt; isa(__PACKAGE__);

    return $x -&gt; bnan(@r)        if $x -&gt; is_nan();
    return $x -&gt; binf("+", @r)   if $x -&gt; is_inf("+");
    return $x -&gt; binf("-", @r)   if $x -&gt; is_zero();
    if ($x -&gt; is_neg()) {
        return $upgrade -&gt; bilog2($x, @r) if $upgrade;
        return $x -&gt; bnan(@r);
    }

    $x -&gt; {value} = $LIB -&gt; _clog2($x -&gt; {value});
    return $x -&gt; round(@r);
}

sub bclog10 {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x -&gt; modify('bclog10');

    return $upgrade -&gt; new($x, @r) unless $x -&gt; isa(__PACKAGE__);

    return $x -&gt; bnan(@r)        if $x -&gt; is_nan();
    return $x -&gt; binf("+", @r)   if $x -&gt; is_inf("+");
    return $x -&gt; binf("-", @r)   if $x -&gt; is_zero();
    if ($x -&gt; is_neg()) {
        return $upgrade -&gt; bilog2($x, @r) if $upgrade;
        return $x -&gt; bnan(@r);
    }

    $x -&gt; {value} = $LIB -&gt; _clog10($x -&gt; {value});
    return $x -&gt; round(@r);
}

sub bnok {
    # Calculate n over k (binomial coefficient or "choose" function) as
    # integer.

    # Set up parameters.
    my ($class, $n, $k, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_)
                            : objectify(2, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $n if $n-&gt;modify('bnok');

    # All cases where at least one argument is NaN.

    return $n-&gt;bnan(@r) if $n-&gt;{sign} eq 'NaN' || $k-&gt;{sign} eq 'NaN';

    # All cases where at least one argument is +/-inf.

    if ($n -&gt; is_inf()) {
        if ($k -&gt; is_inf()) {                   # bnok(+/-inf,+/-inf)
            return $n -&gt; bnan(@r);
        } elsif ($k -&gt; is_neg()) {              # bnok(+/-inf,k), k &lt; 0
            return $n -&gt; bzero(@r);
        } elsif ($k -&gt; is_zero()) {             # bnok(+/-inf,k), k = 0
            return $n -&gt; bone(@r);
        } else {
            if ($n -&gt; is_inf("+", @r)) {        # bnok(+inf,k), 0 &lt; k &lt; +inf
                return $n -&gt; binf("+");
            } else {                            # bnok(-inf,k), k &gt; 0
                my $sign = $k -&gt; is_even() ? "+" : "-";
                return $n -&gt; binf($sign, @r);
            }
        }
    }

    elsif ($k -&gt; is_inf()) {            # bnok(n,+/-inf), -inf &lt;= n &lt;= inf
        return $n -&gt; bnan(@r);
    }

    # At this point, both n and k are real numbers.

    return $upgrade -&gt; bnok($n, $k, @r)
      if defined($upgrade) &amp;&amp; (!$n -&gt; isa(__PACKAGE__) ||
                               !$k -&gt; isa(__PACKAGE__));

    my $sign = 1;

    if ($n &gt;= 0) {
        if ($k &lt; 0 || $k &gt; $n) {
            return $n -&gt; bzero(@r);
        }
    } else {

        if ($k &gt;= 0) {

            # n &lt; 0 and k &gt;= 0: bnok(n,k) = (-1)^k * bnok(-n+k-1,k)

            $sign = (-1) ** $k;
            $n = $n -&gt; bneg() -&gt; badd($k) -&gt; bdec();

        } elsif ($k &lt;= $n) {

            # n &lt; 0 and k &lt;= n: bnok(n,k) = (-1)^(n-k) * bnok(-k-1,n-k)

            $sign = (-1) ** ($n - $k);
            my $x0 = $n -&gt; copy();
            $n = $n -&gt; bone() -&gt; badd($k) -&gt; bneg();
            $k = $k -&gt; copy();
            $k = $k -&gt; bneg() -&gt; badd($x0);

        } else {

            # n &lt; 0 and n &lt; k &lt; 0:

            return $n -&gt; bzero(@r);
        }
    }

    # Some backends, e.g., Math::BigInt::GMP do not allow values of n and k
    # that are larger than the largest unsigned integer, so check for this, and
    # use the simpler and slower generic method in the superclass if n and/or k
    # are larger than the largest unsigned integer.

    my $uintmax = $LIB -&gt; _new(~0);
    if ($LIB -&gt; _acmp($n-&gt;{value}, $uintmax) &gt; 0 ||
        $LIB -&gt; _acmp($k-&gt;{value}, $uintmax) &gt; 0)
    {
        $n-&gt;{value} = $LIB -&gt; SUPER::_nok($n-&gt;{value}, $k-&gt;{value});
    } else {
        $n-&gt;{value} = $LIB -&gt; _nok($n-&gt;{value}, $k-&gt;{value});
    }
    $n = $n -&gt; bneg() if $sign == -1;

    $n -&gt; round(@r);
}

sub buparrow {
    my $a = shift;
    my $y = $a -&gt; uparrow(@_);
    $a -&gt; {value} = $y -&gt; {value};
    return $a;
}

sub uparrow {
    # Knuth's up-arrow notation buparrow(a, n, b)
    #
    # The following is a simple, recursive implementation of the up-arrow
    # notation, just to show the idea. Such implementations cause "Deep
    # recursion on subroutine ..." warnings, so we use a faster, non-recursive
    # algorithm below with @_ as a stack.
    #
    #   sub buparrow {
    #       my ($a, $n, $b) = @_;
    #       return $a ** $b if $n == 1;
    #       return $a * $b  if $n == 0;
    #       return 1        if $b == 0;
    #       return buparrow($a, $n - 1, buparrow($a, $n, $b - 1));
    #   }

    my ($a, $b, $n) = @_;
    my $class = ref $a;
    croak("a must be non-negative") if $a &lt; 0;
    croak("n must be non-negative") if $n &lt; 0;
    croak("b must be non-negative") if $b &lt; 0;

    while (@_ &gt;= 3) {

        # return $a ** $b if $n == 1;

        if ($_[-2] == 1) {
            my ($a, $n, $b) = splice @_, -3;
            push @_, $a ** $b;
            next;
        }

        # return $a * $b if $n == 0;

        if ($_[-2] == 0) {
            my ($a, $n, $b) = splice @_, -3;
            push @_, $a * $b;
            next;
        }

        # return 1 if $b == 0;

        if ($_[-1] == 0) {
            splice @_, -3;
            push @_, $class -&gt; bone();
            next;
        }

        # return buparrow($a, $n - 1, buparrow($a, $n, $b - 1));

        my ($a, $n, $b) = splice @_, -3;
        push @_, ($a, $n - 1,
                      $a, $n, $b - 1);

    }

    pop @_;
}

sub backermann {
    my $m = shift;
    my $y = $m -&gt; ackermann(@_);
    $m -&gt; {value} = $y -&gt; {value};
    return $m;
}

sub ackermann {
    # Ackermann's function ackermann(m, n)
    #
    # The following is a simple, recursive implementation of the ackermann
    # function, just to show the idea. Such implementations cause "Deep
    # recursion on subroutine ..." warnings, so we use a faster, non-recursive
    # algorithm below with @_ as a stack.
    #
    # sub ackermann {
    #     my ($m, $n) = @_;
    #     return $n + 1                                  if $m == 0;
    #     return ackermann($m - 1, 1)                    if $m &gt; 0 &amp;&amp; $n == 0;
    #     return ackermann($m - 1, ackermann($m, $n - 1) if $m &gt; 0 &amp;&amp; $n &gt; 0;
    # }

    my ($m, $n) = @_;
    my $class = ref $m;
    croak("m must be non-negative") if $m &lt; 0;
    croak("n must be non-negative") if $n &lt; 0;

    my $two      = $class -&gt; new("2");
    my $three    = $class -&gt; new("3");
    my $thirteen = $class -&gt; new("13");

    $n = pop;
    $n = $class -&gt; new($n) unless ref($n);
    while (@_) {
        my $m = pop;
        if ($m &gt; $three) {
            push @_, (--$m) x $n;
            while (--$m &gt;= $three) {
                push @_, $m;
            }
            $n = $thirteen;
        } elsif ($m == $three) {
            $n = $class -&gt; bone() -&gt; blsft($n + $three) -&gt; bsub($three);
        } elsif ($m == $two) {
            $n = $n -&gt; bmul($two) -&gt; badd($three);
        } elsif ($m &gt;= 0) {
            $n = $n -&gt; badd($m) -&gt; binc();
        } else {
            die "negative m!";
        }
    }
    $n;
}

sub bsin {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x -&gt; modify('bsin');

    # Trivial cases.

    return $x -&gt; bzero(@r) if $x -&gt; is_zero();
    return $x -&gt; bnan(@r)  if $x -&gt; is_inf() || $x -&gt; is_nan();

    if ($upgrade) {
        my $xtmp = $upgrade -&gt; bsin($x, @r);
        if ($xtmp -&gt; is_int()) {
            $xtmp = $xtmp -&gt; as_int();
            %$x = %$xtmp;
        } else {
            %$x = %$xtmp;
            bless $x, $upgrade;
        }
        return $x;
    }

    # When x is an integer, sin(x) truncated to an integer is always zero.

    $x -&gt; bzero(@r);
}

sub bcos {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x -&gt; modify('bcos');

    # Trivial cases.

    return $x -&gt; bone(@r) if $x -&gt; is_zero();
    return $x -&gt; bnan(@r) if $x -&gt; is_inf() || $x -&gt; is_nan();

    if ($upgrade) {
        my $xtmp = $upgrade -&gt; bcos($x, @r);
        if ($xtmp -&gt; is_int()) {
            $xtmp = $xtmp -&gt; as_int();
            %$x = %$xtmp;
        } else {
            %$x = %$xtmp;
            bless $x, $upgrade;
        }
        return $x;
    }

    # When x is a non-zero integer, cos(x) truncated to an integer is always
    # zero.

    $x -&gt; bzero(@r);
}

sub batan {
    # Calculate arctan(x) to N digits. Unless upgrading is in effect, returns
    # the result truncated to an integer.
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('batan');

    return $x -&gt; bnan(@r)  if $x -&gt; is_nan();
    return $x -&gt; bzero(@r) if $x -&gt; is_zero();

    return $upgrade -&gt; batan($x, @r) if defined $upgrade;

    return $x -&gt; bone("+", @r) if $x -&gt; bgt("1");
    return $x -&gt; bone("-", @r) if $x -&gt; blt("-1");

    $x -&gt; bzero(@r);
}

sub batan2 {
    # calculate arcus tangens of ($y/$x)

    my ($class, $y, $x, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_) : objectify(2, @_);

    return $y if $y-&gt;modify('batan2');

    return $y-&gt;bnan() if ($y-&gt;{sign} eq $nan) || ($x-&gt;{sign} eq $nan);

    return $upgrade-&gt;batan2($y, $x, @r) if defined $upgrade;

    # Y    X
    # != 0 -inf result is +- pi
    if ($x-&gt;is_inf() || $y-&gt;is_inf()) {
        if ($y-&gt;is_inf()) {
            if ($x-&gt;{sign} eq '-inf') {
                # calculate 3 pi/4 =&gt; 2.3.. =&gt; 2
                $y = $y-&gt;bone(substr($y-&gt;{sign}, 0, 1));
                $y = $y-&gt;bmul($class-&gt;new(2));
            } elsif ($x-&gt;{sign} eq '+inf') {
                # calculate pi/4 =&gt; 0.7 =&gt; 0
                $y = $y-&gt;bzero();
            } else {
                # calculate pi/2 =&gt; 1.5 =&gt; 1
                $y = $y-&gt;bone(substr($y-&gt;{sign}, 0, 1));
            }
        } else {
            if ($x-&gt;{sign} eq '+inf') {
                # calculate pi/4 =&gt; 0.7 =&gt; 0
                $y = $y-&gt;bzero();
            } else {
                # PI =&gt; 3.1415.. =&gt; 3
                $y = $y-&gt;bone(substr($y-&gt;{sign}, 0, 1));
                $y = $y-&gt;bmul($class-&gt;new(3));
            }
        }
        return $y;
    }

    require Math::BigFloat;
    my $r = Math::BigFloat-&gt;new($y)
      -&gt;batan2(Math::BigFloat-&gt;new($x), @r)
        -&gt;as_int();

    $x-&gt;{value} = $r-&gt;{value};
    $x-&gt;{sign} = $r-&gt;{sign};

    $x-&gt;round(@r);
}

sub bsqrt {
    # calculate square root of $x
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x -&gt; modify('bsqrt');

    return $x -&gt; bnan(@r)  if $x -&gt; is_nan();
    return $x -&gt; round(@r) if $x -&gt; is_zero() || $x -&gt; is_inf("+");

    if ($upgrade) {
        $x = $upgrade -&gt; bsqrt($x, @r);
        $x = $x -&gt; as_int() if $x -&gt; is_int();
        return $x;
    }

    return $x -&gt; bnan(@r) if $x -&gt; is_neg();

    $x-&gt;{value} = $LIB -&gt; _sqrt($x-&gt;{value});
    return $x -&gt; round(@r);
}

sub broot {
    # calculate $y'th root of $x

    # set up parameters

    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_) : objectify(2, @_);

    $y = $class-&gt;new(2) unless defined $y;

    return $x if $x-&gt;modify('broot');

    # NaN handling: $x ** 1/0, x or y NaN, or y inf/-inf or y == 0
    return $x-&gt;bnan(@r) if $x-&gt;{sign} !~ /^\+/ || $y-&gt;is_zero() ||
                           $y-&gt;{sign} !~ /^\+$/;

    return $x-&gt;round(@r)
      if $x-&gt;is_zero() || $x-&gt;is_one() || $x-&gt;is_inf() || $y-&gt;is_one();

    return $upgrade-&gt;broot($x, $y, @r) if defined $upgrade;

    $x-&gt;{value} = $LIB-&gt;_root($x-&gt;{value}, $y-&gt;{value});
    $x-&gt;round(@r);
}

sub bfac {
    # (BINT or num_str, BINT or num_str) return BINT
    # compute factorial number from $x, modify $x in place
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('bfac') || $x-&gt;{sign} eq '+inf'; # inf =&gt; inf

    return $x-&gt;bnan(@r) if $x-&gt;{sign} ne '+'; # NaN, &lt;0 =&gt; NaN

    return $upgrade -&gt; bfac($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    $x-&gt;{value} = $LIB-&gt;_fac($x-&gt;{value});
    $x-&gt;round(@r);
}

sub bdfac {
    # compute double factorial, modify $x in place
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('bdfac') || $x-&gt;{sign} eq '+inf'; # inf =&gt; inf

    return $x-&gt;bnan(@r) if $x-&gt;is_nan() || $x &lt;= -2;
    return $x-&gt;bone(@r) if $x &lt;= 1;

    return $upgrade -&gt; bdfac($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    croak("bdfac() requires a newer version of the $LIB library.")
        unless $LIB-&gt;can('_dfac');

    $x-&gt;{value} = $LIB-&gt;_dfac($x-&gt;{value});
    $x-&gt;round(@r);
}

sub btfac {
    # compute triple factorial, modify $x in place
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('btfac') || $x-&gt;{sign} eq '+inf'; # inf =&gt; inf

    return $x-&gt;bnan(@r) if $x-&gt;is_nan();

    return $upgrade -&gt; btfac($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    my $k = $class -&gt; new("3");
    return $x-&gt;bnan(@r) if $x &lt;= -$k;

    my $one = $class -&gt; bone();
    return $x-&gt;bone(@r) if $x &lt;= $one;

    my $f = $x -&gt; copy();
    while ($f -&gt; bsub($k) &gt; $one) {
        $x = $x -&gt; bmul($f);
    }
    $x-&gt;round(@r);
}

sub bmfac {
    # compute multi-factorial

    my ($class, $x, $k, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_) : objectify(2, @_);

    return $x if $x-&gt;modify('bmfac') || $x-&gt;{sign} eq '+inf';
    return $x-&gt;bnan(@r) if $x-&gt;is_nan() || $k-&gt;is_nan() || $k &lt; 1 || $x &lt;= -$k;

    return $upgrade -&gt; bmfac($x, $k, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    my $one = $class -&gt; bone();
    return $x-&gt;bone(@r) if $x &lt;= $one;

    my $f = $x -&gt; copy();
    while ($f -&gt; bsub($k) &gt; $one) {
        $x = $x -&gt; bmul($f);
    }
    $x-&gt;round(@r);
}

sub bfib {
    # compute Fibonacci number(s)
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    croak("bfib() requires a newer version of the $LIB library.")
        unless $LIB-&gt;can('_fib');

    return $x if $x-&gt;modify('bfib');

    return $upgrade -&gt; bfib($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # List context.

    if (wantarray) {
        return () if $x -&gt; is_nan();
        croak("bfib() can't return an infinitely long list of numbers")
          if $x -&gt; is_inf();

        my $n = $x -&gt; numify();

        my @y;

        $y[0] = $x -&gt; copy() -&gt; babs();
        $y[0]{value} = $LIB -&gt; _zero();
        return @y if $n == 0;

        $y[1] = $y[0] -&gt; copy();
        $y[1]{value} = $LIB -&gt; _one();
        return @y if $n == 1;

        for (my $i = 2 ; $i &lt;= abs($n) ; $i++) {
            $y[$i] = $y[$i - 1] -&gt; copy();
            $y[$i]{value} = $LIB -&gt; _add($LIB -&gt; _copy($y[$i - 1]{value}),
                                           $y[$i - 2]{value});
        }

        # The last element in the array is the invocand.

        $x-&gt;{value} = $y[-1]{value};
        $y[-1] = $x;

        # If negative, insert sign as appropriate.

        if ($x -&gt; is_neg()) {
            for (my $i = 2 ; $i &lt;= $#y ; $i += 2) {
                $y[$i]{sign} = '-';
            }
        }

        @y = map { $_ -&gt; round(@r) } @y;
        return @y;
    }

    # Scalar context.

    else {
        return $x if $x -&gt; is_inf('+');
        return $x -&gt; bnan() if $x -&gt; is_nan() || $x -&gt; is_inf('-');

        $x-&gt;{sign}  = $x -&gt; is_neg() &amp;&amp; $x -&gt; is_even() ? '-' : '+';
        $x-&gt;{value} = $LIB -&gt; _fib($x-&gt;{value});
        return $x -&gt; round(@r);
    }
}

sub blucas {
    # compute Lucas number(s)
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    croak("blucas() requires a newer version of the $LIB library.")
        unless $LIB-&gt;can('_lucas');

    return $x if $x-&gt;modify('blucas');

    return $upgrade -&gt; blucas($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # List context.

    if (wantarray) {
        return () if $x -&gt; is_nan();
        croak("bfib() can't return an infinitely long list of numbers")
          if $x -&gt; is_inf();

        my $n = $x -&gt; numify();

        my @y;

        $y[0] = $x -&gt; copy() -&gt; babs();
        $y[0]{value} = $LIB -&gt; _two();
        return @y if $n == 0;

        $y[1] = $y[0] -&gt; copy();
        $y[1]{value} = $LIB -&gt; _one();
        return @y if $n == 1;

        for (my $i = 2 ; $i &lt;= abs($n) ; $i++) {
            $y[$i] = $y[$i - 1] -&gt; copy();
            $y[$i]{value} = $LIB -&gt; _add($LIB -&gt; _copy($y[$i - 1]{value}),
                                           $y[$i - 2]{value});
        }

        # The last element in the array is the invocand.

        $x-&gt;{value} = $y[-1]{value};
        $y[-1] = $x;

        # If negative, insert sign as appropriate.

        if ($x -&gt; is_neg()) {
            for (my $i = 2 ; $i &lt;= $#y ; $i += 2) {
                $y[$i]{sign} = '-';
            }
        }

        @y = map { $_ -&gt; round(@r) } @y;
        return @y;
    }

    # Scalar context.

    else {
        return $x if $x -&gt; is_inf('+');
        return $x -&gt; bnan() if $x -&gt; is_nan() || $x -&gt; is_inf('-');

        $x-&gt;{sign}  = $x -&gt; is_neg() &amp;&amp; $x -&gt; is_even() ? '-' : '+';
        $x-&gt;{value} = $LIB -&gt; _lucas($x-&gt;{value});
        return $x -&gt; round(@r);
    }
}

sub blsft {
    # (BINT or num_str, BINT or num_str) return BINT
    # compute $x &lt;&lt; $y, base $n

    my ($class, $x, $y, $b, @r);

    # Objectify the base only when it is defined, since an undefined base, as
    # in $x-&gt;blsft(3) or $x-&gt;blog(3, undef) means use the default base 2.

    if (!ref($_[0]) &amp;&amp; $_[0] =~ /^[A-Za-z]|::/) {
        # E.g., Math::BigInt-&gt;blog(256, 5, 2)
        ($class, $x, $y, $b, @r) =
          defined $_[3] ? objectify(3, @_) : objectify(2, @_);
    } else {
        # E.g., Math::BigInt::blog(256, 5, 2) or $x-&gt;blog(5, 2)
        ($class, $x, $y, $b, @r) =
          defined $_[2] ? objectify(3, @_) : objectify(2, @_);
    }

    return $x if $x -&gt; modify('blsft');

    # The default base is 2.

    $b = 2 unless defined $b;
    $b = $class -&gt; new($b) unless defined(blessed($b));

    # Handle "foreign" objects.

    return $upgrade -&gt; blsft($x, $y, $b, @r)
      if defined($upgrade) &amp;&amp; (!$x -&gt; isa(__PACKAGE__) ||
                               !$y -&gt; isa(__PACKAGE__) ||
                               !$b -&gt; isa(__PACKAGE__));

    # Handle NaN cases.

    return $x -&gt; bnan(@r)
      if $x -&gt; is_nan() || $y -&gt; is_nan() || $b -&gt; is_nan();

    # blsft($x, -$y, $b) = brsft($x, $y, $b)

    return $x -&gt; brsft($y -&gt; copy() -&gt; bneg(), $b, @r) if $y -&gt; is_neg();

    # Now handle all cases where at least one operand is Â±Inf or the result
    # will be Â±Inf or NaN.

    if ($y -&gt; is_inf("+")) {
       if ($b -&gt; is_one("-")) {
            return $x -&gt; bnan(@r);
        } elsif ($b -&gt; is_one("+")) {
            return $x -&gt; round(@r);
        } elsif ($b -&gt; is_zero()) {
            return $x -&gt; bnan(@r) if $x -&gt; is_inf();
            return $x -&gt; bzero(@r);
        } else {
            return $x -&gt; binf("-", @r) if $x -&gt; is_negative();
            return $x -&gt; binf("+", @r) if $x -&gt; is_positive();
            return $x -&gt; bnan(@r);
        }
    }

    if ($b -&gt; is_inf()) {
        return $x -&gt; bnan(@r) if $x -&gt; is_zero() || $y -&gt; is_zero();
        if ($b -&gt; is_inf("-")) {
            return $x -&gt; binf("+", @r)
              if ($x -&gt; is_negative() &amp;&amp; $y -&gt; is_odd() ||
                  $x -&gt; is_positive() &amp;&amp; $y -&gt; is_even());
            return $x -&gt; binf("-", @r);
       } else {
           return $x -&gt; binf("-", @r) if $x -&gt; is_negative();
           return $x -&gt; binf("+", @r);
        }
    }

    if ($b -&gt; is_zero()) {
        return $x -&gt; round(@r) if $y -&gt; is_zero();
        return $x -&gt; bnan(@r)  if $x -&gt; is_inf();
        return $x -&gt; bzero(@r);
    }

    if ($x -&gt; is_inf()) {
        if ($b -&gt; is_negative()) {
            if ($x -&gt; is_inf("-")) {
                if ($y -&gt; is_even()) {
                    return $x -&gt; round(@r);
                } else {
                    return $x -&gt; binf("+", @r);
                }
            } else {
                if ($y -&gt; is_even()) {
                    return $x -&gt; round(@r);
                } else {
                    return $x -&gt; binf("-", @r);
                }
            }
        } else {
            return $x -&gt; round(@r);
        }
    }

    # At this point, we know that both the input and the output is finite.
    # Handle some trivial cases.

    return $x -&gt; round(@r) if $x -&gt; is_zero() || $y -&gt; is_zero()
                              || $b -&gt; is_one("+")
                              || $b -&gt; is_one("-") &amp;&amp; $y -&gt; is_even();

    return $x -&gt; bneg(@r) if $b -&gt; is_one("-") &amp;&amp; $y -&gt; is_odd();

    # While some of the libraries support an arbitrarily large base, not all of
    # them do, so rather than returning an incorrect result in those cases,
    # disallow bases that don't work with all libraries.

    my $uintmax = ~0;
    if ($x -&gt; bcmp($uintmax) &gt; 0) {
        $x = $x -&gt; bmul($b -&gt; bpow($y));
    } else {
        my $neg = 0;
        if ($b -&gt; is_negative()) {
            $neg = 1 if $y -&gt; is_odd();
            $b = $b -&gt; babs();
        }
        $b = $b -&gt; numify();
        $x -&gt; {value} = $LIB -&gt; _lsft($x -&gt; {value}, $y -&gt; {value}, $b);
        $x -&gt; {sign} =~ tr/+-/-+/ if $neg;
    }
    $x -&gt; round(@r);
}

sub brsft {
    # (BINT or num_str, BINT or num_str) return BINT
    # compute $x &gt;&gt; $y, base $n

    my ($class, $x, $y, $b, @r);

    # Objectify the base only when it is defined, since an undefined base, as
    # in $x-&gt;blsft(3) or $x-&gt;blog(3, undef) means use the default base 2.

    if (!ref($_[0]) &amp;&amp; $_[0] =~ /^[A-Za-z]|::/) {
        # E.g., Math::BigInt-&gt;blog(256, 5, 2)
        ($class, $x, $y, $b, @r) =
          defined $_[3] ? objectify(3, @_) : objectify(2, @_);
    } else {
        # E.g., Math::BigInt::blog(256, 5, 2) or $x-&gt;blog(5, 2)
        ($class, $x, $y, $b, @r) =
          defined $_[2] ? objectify(3, @_) : objectify(2, @_);
    }

    return $x if $x -&gt; modify('brsft');

    # The default base is 2.

    $b = 2 unless defined $b;
    $b = $class -&gt; new($b) unless defined(blessed($b));

    # Handle "foreign" objects.

    return $upgrade -&gt; brsft($x, $y, $b, @r)
      if defined($upgrade) &amp;&amp; (!$x -&gt; isa(__PACKAGE__) ||
                               !$y -&gt; isa(__PACKAGE__) ||
                               !$b -&gt; isa(__PACKAGE__));

    # Handle NaN cases.

    return $x -&gt; bnan(@r)
      if $x -&gt; is_nan() || $y -&gt; is_nan() || $b -&gt; is_nan();

    # brsft($x, -$y, $b) = blsft($x, $y, $b)

    return $x -&gt; blsft($y -&gt; copy() -&gt; bneg(), $b, @r) if $y -&gt; is_neg();

    # Now handle all cases where at least one operand is Â±Inf or the result
    # will be Â±Inf or NaN.

    if ($b -&gt; is_inf()) {
        return $x -&gt; bnan(@r) if $x -&gt; is_inf() || $y -&gt; is_zero();
        if ($b -&gt; is_inf("+")) {
            if ($x -&gt; is_negative()) {
                return $x -&gt; bone("-", @r);
            } else {
                return $x -&gt; bzero(@r);
            }
        } else {
            if ($x -&gt; is_negative()) {
                return $y -&gt; is_odd() ? $x -&gt; bzero(@r)
                                      : $x -&gt; bone("-", @r);
            } elsif ($x -&gt; is_positive()) {
                return $y -&gt; is_odd() ? $x -&gt; bone("-", @r)
                                      : $x -&gt; bzero(@r);
            } else {
                return $x -&gt; bzero(@r);
            }
        }
    }

    if ($b -&gt; is_zero()) {
        return $x -&gt; round(@r) if $y -&gt; is_zero();
        return $x -&gt; bnan(@r)  if $x -&gt; is_zero();
        return $x -&gt; is_negative() ? $x -&gt; binf("-", @r)
                                   : $x -&gt; binf("+", @r);
    }

    if ($y -&gt; is_inf("+")) {
        if ($b -&gt; is_one("-")) {
            return $x -&gt; bnan(@r);
        } elsif ($b -&gt; is_one("+")) {
            return $x -&gt; round(@r);
        } else {
            return $x -&gt; bnan(@r) if $x -&gt; is_inf();
            return $x -&gt; is_negative() ? $x -&gt; bone("-", @r)
                                       : $x -&gt; bzero(@r);
        }
    }

    if ($x -&gt; is_inf()) {
        if ($b -&gt; is_negative()) {
            if ($x -&gt; is_inf("-")) {
                if ($y -&gt; is_even()) {
                    return $x -&gt; round(@r);
                } else {
                    return $x -&gt; binf("+", @r);
                }
            } else {
                if ($y -&gt; is_even()) {
                    return $x -&gt; round(@r);
                } else {
                    return $x -&gt; binf("-", @r);
                }
            }
        } else {
            return $x -&gt; round(@r);
        }
    }

    # At this point, we know that both the input and the output is finite.
    # Handle some trivial cases.

    return $x -&gt; round(@r) if $x -&gt; is_zero() || $y -&gt; is_zero()
                              || $b -&gt; is_one("+")
                              || $b -&gt; is_one("-") &amp;&amp; $y -&gt; is_even();

    return $x -&gt; bneg(@r) if $b -&gt; is_one("-") &amp;&amp; $y -&gt; is_odd();

    # We know that $y is positive. Shifting right by a positive amount might
    # lead to a non-integer result.

    return $upgrade -&gt; brsft($x, $y, $b, @r) if defined($upgrade);

    # This only works for negative numbers when shifting in base 2.
    if ($x -&gt; is_neg() &amp;&amp; $b -&gt; bcmp("2") == 0) {
        return $x -&gt; round(@r) if $x -&gt; is_one('-'); # -1 =&gt; -1
        # Although this is O(N*N) in Math::BigInt::Calc-&gt;_as_bin(), it is O(N)
        # in Pari et al., but perhaps there is a better emulation for two's
        # complement shift ... if $y != 1, we must simulate it by doing:
        # convert to bin, flip all bits, shift, and be done
        $x = $x -&gt; binc();                      # -3 =&gt; -2
        my $bin = $x -&gt; to_bin();               # convert to string
        $bin =~ s/^-//;                         # strip leading minus
        $bin =~ tr/10/01/;                      # flip bits
        my $nbits = CORE::length($bin);
        return $x -&gt; bone("-", @r) if $y &gt;= $nbits;
        $bin = substr $bin, 0, $nbits - $y;     # keep most significant bits
        $bin = '1' . $bin;                      # prepend one dummy '1'
        $bin =~ tr/10/01/;                      # flip bits back
        my $res = $class -&gt; from_bin($bin);     # convert back from string
        $res = $res -&gt; binc();                  # remember to increment
        $x -&gt; {value} = $res -&gt; {value};        # take over value
        return $x -&gt; round(@r);
    }

    # While some of the libraries support an arbitrarily large base, not all of
    # them do, so rather than returning an incorrect result in those cases, use
    # division.

    my $uintmax = ~0;
    if ($x -&gt; bcmp($uintmax) &gt; 0 || $x -&gt; is_neg() || $b -&gt; is_negative()) {
        $x = $x -&gt; bdiv($b -&gt; bpow($y));
    } else {
        $b = $b -&gt; numify();
        $x -&gt; {value} = $LIB -&gt; _rsft($x -&gt; {value}, $y -&gt; {value}, $b);
    }

    return $x -&gt; round(@r);
}

###############################################################################
# Bitwise methods
###############################################################################

# Bitwise left shift.

sub bblsft {
    # We don't call objectify(), because the bitwise methods should not
    # upgrade/downgrade, even when upgrading/downgrading is enabled.

    my ($class, $x, $y, @r);

    # $x -&gt; bblsft($y)

    if (ref($_[0])) {
        ($class, $x, $y, @r) = (ref($_[0]), @_);
        $y = $y -&gt; as_int()
          if ref($y) &amp;&amp; !$y -&gt; isa(__PACKAGE__) &amp;&amp; $y -&gt; can('as_int');
        $y = $class -&gt; new(int($y)) unless ref($y);
    }

    # $class -&gt; bblsft($x, $y)

    else {
        ($class, $x, $y, @r) = @_;
        for ($x, $y) {
            $_ = $_ -&gt; as_int()
              if ref($_) &amp;&amp; !$_ -&gt; isa(__PACKAGE__) &amp;&amp; $_ -&gt; can('as_int');
            $_ = $class -&gt; new(int($_)) unless ref($_);
        }
    }

    return $x if $x -&gt; modify('bblsft');

    return $x -&gt; bnan(@r) if $x -&gt; is_nan() || $y -&gt; is_nan();

    # bblsft($x, -$y) = bbrsft($x, $y)

    return $x -&gt; bbrsft($y -&gt; copy() -&gt; bneg()) if $y -&gt; is_neg();

    # Shifting infinitely far to the left.

    if ($y -&gt; is_inf("+")) {
        return $x -&gt; binf("+", @r) if $x -&gt; is_pos();
        return $x -&gt; binf("-", @r) if $x -&gt; is_neg();
        return $x -&gt; bnan(@r);
    }

    # These cases change nothing.

    return $x -&gt; round(@r) if $x -&gt; is_zero() || $x -&gt; is_inf() ||
                              $y -&gt; is_zero();

    $x -&gt; {value} = $LIB -&gt; _lsft($x -&gt; {value}, $y -&gt; {value}, 2);
    $x -&gt; round(@r);
}

# Bitwise right shift.

sub bbrsft {
    # We don't call objectify(), because the bitwise methods should not
    # upgrade/downgrade, even when upgrading/downgrading is enabled.

    my ($class, $x, $y, @r);

    # $x -&gt; bblsft($y)

    if (ref($_[0])) {
        ($class, $x, $y, @r) = (ref($_[0]), @_);
        $y = $y -&gt; as_int()
          if ref($y) &amp;&amp; !$y -&gt; isa(__PACKAGE__) &amp;&amp; $y -&gt; can('as_int');
        $y = $class -&gt; new(int($y)) unless ref($y);
    }

    # $class -&gt; bblsft($x, $y)

    else {
        ($class, $x, $y, @r) = @_;
        for ($x, $y) {
            $_ = $_ -&gt; as_int()
              if ref($_) &amp;&amp; !$_ -&gt; isa(__PACKAGE__) &amp;&amp; $_ -&gt; can('as_int');
            $_ = $class -&gt; new(int($_)) unless ref($_);
        }
    }

    return $x if $x -&gt; modify('bbrsft');

    return $x -&gt; bnan(@r) if $x -&gt; is_nan() || $y -&gt; is_nan();

    # bbrsft($x, -$y) = bblsft($x, $y)

    return $x -&gt; bblsft($y -&gt; copy() -&gt; bneg()) if $y -&gt; is_neg();

    # Shifting infinitely far to the right.

    if ($y -&gt; is_inf("+")) {
        return $x -&gt; bnan(@r)      if $x -&gt; is_inf();
        return $x -&gt; bone("-", @r) if $x -&gt; is_neg();
        return $x -&gt; bzero(@r);
    }

    # These cases change nothing.

    return $x -&gt; round(@r) if $x -&gt; is_zero() || $x -&gt; is_inf() ||
                              $y -&gt; is_zero();

    # At this point, $x is either positive or negative, not zero.

    if ($x -&gt; is_pos()) {
        $x -&gt; {value} = $LIB -&gt; _rsft($x -&gt; {value}, $y -&gt; {value}, 2);
    } else {
        my $n = $x -&gt; {value};
        my $d = $LIB -&gt; _pow($LIB -&gt; _new("2"), $y -&gt; {value});
        my ($p, $q) = $LIB -&gt; _div($n, $d);
        $p = $LIB -&gt; _inc($p) unless $LIB -&gt; _is_zero($q);
        $x -&gt; {value} = $p;
    }

    $x -&gt; round(@r);
}

sub band {
    #(BINT or num_str, BINT or num_str) return BINT
    # compute x &amp; y

    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_) : objectify(2, @_);

    return $x if $x-&gt;modify('band');

    return $upgrade -&gt; band($x, $y, @r)
      if defined($upgrade) &amp;&amp; (!$x -&gt; isa(__PACKAGE__) ||
                               !$y -&gt; isa(__PACKAGE__));

    $r[3] = $y;                 # no push!

    return $x-&gt;bnan(@r) if $x-&gt;{sign} !~ /^[+-]$/ || $y-&gt;{sign} !~ /^[+-]$/;

    if ($x-&gt;{sign} eq '+' &amp;&amp; $y-&gt;{sign} eq '+') {
        $x-&gt;{value} = $LIB-&gt;_and($x-&gt;{value}, $y-&gt;{value});
    } else {
        ($x-&gt;{value}, $x-&gt;{sign}) = $LIB-&gt;_sand($x-&gt;{value}, $x-&gt;{sign},
                                                $y-&gt;{value}, $y-&gt;{sign});
    }
    return $x-&gt;round(@r);
}

sub bior {
    #(BINT or num_str, BINT or num_str) return BINT
    # compute x | y

    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_) : objectify(2, @_);

    return $x if $x-&gt;modify('bior');

    return $upgrade -&gt; bior($x, $y, @r)
      if defined($upgrade) &amp;&amp; (!$x -&gt; isa(__PACKAGE__) ||
                               !$y -&gt; isa(__PACKAGE__));

    $r[3] = $y;                 # no push!

    return $x-&gt;bnan() if ($x-&gt;{sign} !~ /^[+-]$/ || $y-&gt;{sign} !~ /^[+-]$/);

    if ($x-&gt;{sign} eq '+' &amp;&amp; $y-&gt;{sign} eq '+') {
        $x-&gt;{value} = $LIB-&gt;_or($x-&gt;{value}, $y-&gt;{value});
    } else {
        ($x-&gt;{value}, $x-&gt;{sign}) = $LIB-&gt;_sor($x-&gt;{value}, $x-&gt;{sign},
                                               $y-&gt;{value}, $y-&gt;{sign});
    }
    return $x-&gt;round(@r);
}

sub bxor {
    #(BINT or num_str, BINT or num_str) return BINT
    # compute x ^ y

    my ($class, $x, $y, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                            ? (ref($_[0]), @_) : objectify(2, @_);

    return $x if $x-&gt;modify('bxor');

    return $upgrade -&gt; bxor($x, $y, @r)
      if defined($upgrade) &amp;&amp; (!$x -&gt; isa(__PACKAGE__) ||
                               !$y -&gt; isa(__PACKAGE__));

    $r[3] = $y;                 # no push!

    return $x-&gt;bnan(@r) if $x-&gt;{sign} !~ /^[+-]$/ || $y-&gt;{sign} !~ /^[+-]$/;

    if ($x-&gt;{sign} eq '+' &amp;&amp; $y-&gt;{sign} eq '+') {
        $x-&gt;{value} = $LIB-&gt;_xor($x-&gt;{value}, $y-&gt;{value});
    } else {
        ($x-&gt;{value}, $x-&gt;{sign}) = $LIB-&gt;_sxor($x-&gt;{value}, $x-&gt;{sign},
                                               $y-&gt;{value}, $y-&gt;{sign});
    }
    return $x-&gt;round(@r);
}

sub bnot {
    # (num_str or BINT) return BINT
    # represent ~x as twos-complement number
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;modify('bnot');

    return $upgrade -&gt; bnot($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    $x -&gt; binc() -&gt; bneg(@r);
}

###############################################################################
# Rounding methods
###############################################################################

sub round {
    # Round $self according to given parameters, or given second argument's
    # parameters or global defaults

    my ($class, $self, @args) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    # These signal no rounding:
    #
    #   $x-&gt;round(undef)
    #   $x-&gt;round(undef, undef, ...)
    #
    # The "@args &lt;= 3" is necessary because the final set of parameters that
    # will be used for rounding depend on the "extra arguments", if any.

    if (@args == 1 &amp;&amp; !defined($args[0]) ||
        @args &gt;= 2 &amp;&amp; @args &lt;= 3 &amp;&amp; !defined($args[0]) &amp;&amp; !defined($args[1]))
    {
        $self-&gt;{accuracy} = undef;
        $self-&gt;{precision} = undef;
        return $self;
    }

    my ($a, $p, $r) = splice @args, 0, 3;

    # $a accuracy, if given by caller
    # $p precision, if given by caller
    # $r round_mode, if given by caller
    # @args all 'other' arguments (0 for unary, 1 for binary ops)

    if (defined $a) {
        croak "accuracy must be a number, not '$a'"
          unless $a =~/^[+-]?(?:\d+(?:\.\d*)?|\.\d+)(?:[Ee][+-]?\d+)?\z/;
    }

    if (defined $p) {
        croak "precision must be a number, not '$p'"
          unless $p =~/^[+-]?(?:\d+(?:\.\d*)?|\.\d+)(?:[Ee][+-]?\d+)?\z/;
    }

    # now pick $a or $p, but only if we have got "arguments"
    if (!defined $a) {
        foreach ($self, @args) {
            # take the defined one, or if both defined, the one that is smaller
            $a = $_-&gt;{accuracy}
              if (defined $_-&gt;{accuracy}) &amp;&amp; (!defined $a || $_-&gt;{accuracy} &lt; $a);
        }
    }
    if (!defined $p) {
        # even if $a is defined, take $p, to signal error for both defined
        foreach ($self, @args) {
            # take the defined one, or if both defined, the one that is bigger
            # -2 &gt; -3, and 3 &gt; 2
            $p = $_-&gt;{precision}
              if (defined $_-&gt;{precision}) &amp;&amp; (!defined $p || $_-&gt;{precision} &gt; $p);
        }
    }

    # if still none defined, use globals
    unless (defined $a || defined $p) {
        $a = $class -&gt; accuracy();
        $p = $class -&gt; precision();
    }

    # A == 0 is useless, so undef it to signal no rounding
    $a = undef if defined $a &amp;&amp; $a == 0;

    # no rounding today?
    return $self unless defined $a || defined $p; # early out

    # set A and set P is an fatal error
    return $self-&gt;bnan() if defined $a &amp;&amp; defined $p;

    $r = $class -&gt; round_mode() unless defined $r;
    if ($r !~ /^(even|odd|[+-]inf|zero|trunc|common)$/) {
        croak("Unknown round mode '$r'");
    }

    # now round, by calling either bround or bfround:
    if (defined $a) {
        $self = $self-&gt;bround(int($a), $r)
          if !defined $self-&gt;{accuracy} || $self-&gt;{accuracy} &gt;= $a;
    } else {                  # both can't be undefined due to early out
        $self = $self-&gt;bfround(int($p), $r)
          if !defined $self-&gt;{precision} || $self-&gt;{precision} &lt;= $p;
    }

    # bround() or bfround() already called bnorm() if nec.
    $self;
}

sub bround {
    # accuracy: +$n preserve $n digits from left,
    #           -$n preserve $n digits from right (f.i. for 0.1234 style in MBF)
    # no-op for $n == 0
    # and overwrite the rest with 0's, return normalized number
    # do not return $x-&gt;bnorm(), but $x

    my ($class, $x, @a) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    my ($scale, $mode) = $x-&gt;_scale_a(@a);
    return $x if !defined $scale || $x-&gt;modify('bround'); # no-op

    if ($x-&gt;is_zero() || $scale == 0) {
        $x-&gt;{accuracy} = $scale if !defined $x-&gt;{accuracy} || $x-&gt;{accuracy} &gt; $scale; # 3 &gt; 2
        return $x;
    }
    return $x if $x-&gt;{sign} !~ /^[+-]$/; # inf, NaN

    # we have fewer digits than we want to scale to
    my $len = $x-&gt;length();
    # convert $scale to a scalar in case it is an object (put's a limit on the
    # number length, but this would already limited by memory constraints),
    # makes it faster
    $scale = $scale-&gt;numify() if ref ($scale);

    # scale &lt; 0, but &gt; -len (not &gt;=!)
    if (($scale &lt; 0 &amp;&amp; $scale &lt; -$len-1) || ($scale &gt;= $len)) {
        $x-&gt;{accuracy} = $scale if !defined $x-&gt;{accuracy} || $x-&gt;{accuracy} &gt; $scale; # 3 &gt; 2
        return $x;
    }

    # count of 0's to pad, from left (+) or right (-): 9 - +6 =&gt; 3, or |-6| =&gt; 6
    my ($pad, $digit_round, $digit_after);
    $pad = $len - $scale;
    $pad = abs($scale-1) if $scale &lt; 0;

    # do not use digit(), it is very costly for binary =&gt; decimal
    # getting the entire string is also costly, but we need to do it only once
    my $xs = $LIB-&gt;_str($x-&gt;{value});
    my $pl = -$pad-1;

    # pad:   123: 0 =&gt; -1, at 1 =&gt; -2, at 2 =&gt; -3, at 3 =&gt; -4
    # pad+1: 123: 0 =&gt; 0, at 1 =&gt; -1, at 2 =&gt; -2, at 3 =&gt; -3
    $digit_round = '0';
    $digit_round = substr($xs, $pl, 1) if $pad &lt;= $len;
    $pl++;
    $pl ++ if $pad &gt;= $len;
    $digit_after = '0';
    $digit_after = substr($xs, $pl, 1) if $pad &gt; 0;

    # in case of 01234 we round down, for 6789 up, and only in case 5 we look
    # closer at the remaining digits of the original $x, remember decision
    my $round_up = 1;           # default round up
    $round_up -- if
      ($mode eq 'trunc')                      ||   # trunc by round down
        ($digit_after =~ /[01234]/)           ||   # round down anyway,
          # 6789 =&gt; round up
          ($digit_after eq '5')               &amp;&amp;   # not 5000...0000
            ($x-&gt;_scan_for_nonzero($pad, $xs, $len) == 0)   &amp;&amp;
              (
               ($mode eq 'even') &amp;&amp; ($digit_round =~ /[24680]/) ||
               ($mode eq 'odd')  &amp;&amp; ($digit_round =~ /[13579]/) ||
               ($mode eq '+inf') &amp;&amp; ($x-&gt;{sign} eq '-')         ||
               ($mode eq '-inf') &amp;&amp; ($x-&gt;{sign} eq '+')         ||
               ($mode eq 'zero') # round down if zero, sign adjusted below
              );
    my $put_back = 0;           # not yet modified

    if (($pad &gt; 0) &amp;&amp; ($pad &lt;= $len)) {
        substr($xs, -$pad, $pad) = '0' x $pad; # replace with '00...'
        $xs =~ s/^0+(\d)/$1/;                  # "00000" -&gt; "0"
        $put_back = 1;                         # need to put back
    } elsif ($pad &gt; $len) {
        $x = $x-&gt;bzero();            # round to '0'
    }

    if ($round_up) {            # what gave test above?
        $put_back = 1;                               # need to put back
        $pad = $len, $xs = '0' x $pad if $scale &lt; 0; # tlr: whack 0.51=&gt;1.0

        # we modify directly the string variant instead of creating a number and
        # adding it, since that is faster (we already have the string)
        my $c = 0;
        $pad ++;                # for $pad == $len case
        while ($pad &lt;= $len) {
            $c = substr($xs, -$pad, 1) + 1;
            $c = '0' if $c eq '10';
            substr($xs, -$pad, 1) = $c;
            $pad++;
            last if $c != 0;    # no overflow =&gt; early out
        }
        $xs = '1'.$xs if $c == 0;
    }
    $x-&gt;{value} = $LIB-&gt;_new($xs) if $put_back == 1; # put back, if needed

    $x-&gt;{accuracy} = $scale if $scale &gt;= 0;
    if ($scale &lt; 0) {
        $x-&gt;{accuracy} = $len+$scale;
        $x-&gt;{accuracy} = 0 if $scale &lt; -$len;
    }
    $x;
}

sub bfround {
    # precision: round to the $Nth digit left (+$n) or right (-$n) from the '.'
    # $n == 0 || $n == 1 =&gt; round to integer

    my ($class, $x, @p) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    my ($scale, $mode) = $x-&gt;_scale_p(@p);

    return $x if !defined $scale || $x-&gt;modify('bfround'); # no-op

    # no-op for Math::BigInt objects if $n &lt;= 0
    $x = $x-&gt;bround($x-&gt;length()-$scale, $mode) if $scale &gt; 0;

    $x-&gt;{accuracy} = undef;
    $x-&gt;{precision} = $scale;          # store new precision
    $x;
}

sub fround {
    # Exists to make life easier for switch between MBF and MBI (should we
    # autoload fxxx() like MBF does for bxxx()?)
    my $x = shift;
    $x = __PACKAGE__-&gt;new($x) unless ref $x;
    $x-&gt;bround(@_);
}

sub bfloor {
    # round towards minus infinity; no-op since it's already integer
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $upgrade -&gt; bfloor($x)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    $x-&gt;round(@r);
}

sub bceil {
    # round towards plus infinity; no-op since it's already int
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $upgrade -&gt; bceil($x)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    $x-&gt;round(@r);
}

sub bint {
    # round towards zero; no-op since it's already integer
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $upgrade -&gt; bint($x)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    $x-&gt;round(@r);
}

###############################################################################
# Other mathematical methods
###############################################################################

sub bgcd {
    # (BINT or num_str, BINT or num_str) return BINT
    # does not modify arguments, but returns new object
    # GCD -- Euclid's algorithm, variant C (Knuth Vol 3, pg 341 ff)

    # Class::method(...) -&gt; Class-&gt;method(...)
    unless (@_ &amp;&amp; (defined(blessed($_[0])) &amp;&amp; $_[0] -&gt; isa(__PACKAGE__) ||
                   $_[0] =~ /^[a-z]\w*(?:::[a-z]\w*)*$/i))
    {
        #carp "Using ", (caller(0))[3], "() as a function is deprecated;",
        #  " use is as a method instead";
        unshift @_, __PACKAGE__;
    }

    my ($class, @args) = objectify(0, @_);

    # Upgrade?

    if (defined $upgrade) {
        my $do_upgrade = 0;
        for my $arg (@args) {
            unless ($arg -&gt; isa(__PACKAGE__)) {
                $do_upgrade = 1;
                last;
            }
        }
        return $upgrade -&gt; bgcd(@args) if $do_upgrade;
    }

    my $x = shift @args;
    $x = defined(blessed($x)) &amp;&amp; $x -&gt; isa(__PACKAGE__) ? $x -&gt; copy()
                                                        : $class -&gt; new($x);

    return $class-&gt;bnan() if $x-&gt;{sign} !~ /^[+-]$/;    # x NaN?

    while (@args) {
        my $y = shift @args;
        $y = $class-&gt;new($y)
          unless defined(blessed($y)) &amp;&amp; $y -&gt; isa(__PACKAGE__);
        return $class-&gt;bnan() if $y-&gt;{sign} !~ /^[+-]$/;    # y NaN?
        $x-&gt;{value} = $LIB-&gt;_gcd($x-&gt;{value}, $y-&gt;{value});
        last if $LIB-&gt;_is_one($x-&gt;{value});
    }

    return $x -&gt; babs();
}

sub blcm {
    # (BINT or num_str, BINT or num_str) return BINT
    # does not modify arguments, but returns new object
    # Least Common Multiple

    # Class::method(...) -&gt; Class-&gt;method(...)
    unless (@_ &amp;&amp; (defined(blessed($_[0])) &amp;&amp; $_[0] -&gt; isa(__PACKAGE__) ||
                   $_[0] =~ /^[a-z]\w*(?:::[a-z]\w*)*$/i))
    {
        #carp "Using ", (caller(0))[3], "() as a function is deprecated;",
        #  " use is as a method instead";
        unshift @_, __PACKAGE__;
    }

    my ($class, @args) = objectify(0, @_);

    # Upgrade?

    if (defined $upgrade) {
        my $do_upgrade = 0;
        for my $arg (@args) {
            unless ($arg -&gt; isa(__PACKAGE__)) {
                $do_upgrade = 1;
                last;
            }
        }
        return $upgrade -&gt; blcm(@args) if $do_upgrade;
    }

    my $x = shift @args;
    $x = defined(blessed($x)) &amp;&amp; $x -&gt; isa(__PACKAGE__) ? $x -&gt; copy()
                                                        : $class -&gt; new($x);
    return $class-&gt;bnan() if $x-&gt;{sign} !~ /^[+-]$/;    # x NaN?

    while (@args) {
        my $y = shift @args;
        $y = $class -&gt; new($y)
          unless defined(blessed($y)) &amp;&amp; $y -&gt; isa(__PACKAGE__);
        return $x-&gt;bnan() if $y-&gt;{sign} !~ /^[+-]$/;     # y not integer
        $x -&gt; {value} = $LIB-&gt;_lcm($x -&gt; {value}, $y -&gt; {value});
    }

    return $x -&gt; babs();
}

###############################################################################
# Object property methods
###############################################################################

sub sign {
    # return the sign of the number: +/-/-inf/+inf/NaN
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    $x-&gt;{sign};
}

sub digit {
    # return the nth decimal digit, negative values count backward, 0 is right
    my (undef, $x, $n, @r) = ref($_[0]) ? (undef, @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    $n = $n-&gt;numify() if ref($n);
    $LIB-&gt;_digit($x-&gt;{value}, $n || 0);
}

sub bdigitsum {
    # like digitsum(), but assigns the result to the invocand
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $x           if $x -&gt; is_nan();
    return $x -&gt; bnan() if $x -&gt; is_inf();

    $x -&gt; {value} = $LIB -&gt; _digitsum($x -&gt; {value});
    $x -&gt; {sign}  = '+';
    return $x;
}

sub digitsum {
    # compute sum of decimal digits and return it
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $class -&gt; bnan() if $x -&gt; is_nan();
    return $class -&gt; bnan() if $x -&gt; is_inf();

    my $y = $class -&gt; bzero();
    $y -&gt; {value} = $LIB -&gt; _digitsum($x -&gt; {value});
    $y -&gt; round(@r);
}

sub length {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    my $e = $LIB-&gt;_len($x-&gt;{value});
    wantarray ? ($e, 0) : $e;
}

sub exponent {
    # return a copy of the exponent (here always 0, NaN or 1 for $m == 0)
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Upgrade?

    return $upgrade -&gt; exponent($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    if ($x-&gt;{sign} !~ /^[+-]$/) {
        my $s = $x-&gt;{sign};
        $s =~ s/^[+-]//; # NaN, -inf, +inf =&gt; NaN or inf
        return $class-&gt;new($s, @r);
    }
    return $class-&gt;bzero(@r) if $x-&gt;is_zero();

    # 12300 =&gt; 2 trailing zeros =&gt; exponent is 2
    $class-&gt;new($LIB-&gt;_zeros($x-&gt;{value}), @r);
}

sub mantissa {
    # return the mantissa (compatible to Math::BigFloat, e.g. reduced)
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Upgrade?

    return $upgrade -&gt; mantissa($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    if ($x-&gt;{sign} !~ /^[+-]$/) {
        # for NaN, +inf, -inf: keep the sign
        return $class-&gt;new($x-&gt;{sign}, @r);
    }
    my $m = $x-&gt;copy();
    $m -&gt; precision(undef);
    $m -&gt; accuracy(undef);

    # that's a bit inefficient:
    my $zeros = $LIB-&gt;_zeros($m-&gt;{value});
    $m = $m-&gt;brsft($zeros, 10) if $zeros != 0;
    $m -&gt; round(@r);
}

sub parts {
    # return a copy of both the exponent and the mantissa
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Upgrade?

    return $upgrade -&gt; parts($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    ($x-&gt;mantissa(@r), $x-&gt;exponent(@r));
}

# Parts used for scientific notation with significand/mantissa and exponent as
# integers. E.g., "12345.6789" is returned as "123456789" (mantissa) and "-4"
# (exponent).

sub sparts {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Not-a-number.

    if ($x -&gt; is_nan()) {
        my $mant = $class -&gt; bnan(@r);          # mantissa
        return $mant unless wantarray;          # scalar context
        my $expo = $class -&gt; bnan(@r);          # exponent
        return ($mant, $expo);                  # list context
    }

    # Infinity.

    if ($x -&gt; is_inf()) {
        my $mant = $class -&gt; binf($x-&gt;{sign}, @r);  # mantissa
        return $mant unless wantarray;              # scalar context
        my $expo = $class -&gt; binf('+', @r);         # exponent
        return ($mant, $expo);                      # list context
    }

    # Upgrade?

    return $upgrade -&gt; sparts($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number.

    my $mant   = $x -&gt; copy();
    my $nzeros = $LIB -&gt; _zeros($mant -&gt; {value});

    $mant -&gt; {value}
      = $LIB -&gt; _rsft($mant -&gt; {value}, $LIB -&gt; _new($nzeros), 10)
        if $nzeros != 0;
    return $mant unless wantarray;

    my $expo = $class -&gt; new($nzeros, @r);
    return ($mant, $expo);
}

# Parts used for normalized notation with significand/mantissa as either 0 or a
# number in the semi-open interval [1,10). E.g., "12345.6789" is returned as
# "1.23456789" and "4".

sub nparts {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Not-a-Number and Infinity.

    return $x -&gt; sparts(@r) if $x -&gt; is_nan() || $x -&gt; is_inf();

    # Upgrade?

    return $upgrade -&gt; nparts($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number.

    my ($mant, $expo) = $x -&gt; sparts(@r);
    if ($mant -&gt; bcmp(0)) {
        my ($ndigtot, $ndigfrac) = $mant -&gt; length();
        my $expo10adj = $ndigtot - $ndigfrac - 1;

        if ($expo10adj &gt; 0) {          # if mantissa is not an integer
            return $upgrade -&gt; nparts($x, @r) if defined $upgrade;
            $mant = $mant -&gt; bnan(@r);
            return $mant unless wantarray;
            $expo = $expo -&gt; badd($expo10adj, @r);
            return ($mant, $expo);
        }
    }

    return $mant unless wantarray;
    return ($mant, $expo);
}

# Parts used for engineering notation with significand/mantissa as either 0 or a
# number in the semi-open interval [1,1000) and the exponent is a multiple of 3.
# E.g., "12345.6789" is returned as "12.3456789" and "3".

sub eparts {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Not-a-number and Infinity.

    return $x -&gt; sparts(@r) if $x -&gt; is_nan() || $x -&gt; is_inf();

    # Upgrade?

    return $upgrade -&gt; eparts($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number.

    my ($mant, $expo) = $x -&gt; sparts(@r);

    if ($mant -&gt; bcmp(0)) {
        my $ndigmant  = $mant -&gt; length();
        $expo = $expo -&gt; badd($ndigmant, @r);

        # $c is the number of digits that will be in the integer part of the
        # final mantissa.

        my $c = $expo -&gt; copy() -&gt; bdec() -&gt; bmod(3) -&gt; binc();
        $expo = $expo -&gt; bsub($c);

        if ($ndigmant &gt; $c) {
            return $upgrade -&gt; eparts($x, @r) if defined $upgrade;
            $mant = $mant -&gt; bnan(@r);
            return $mant unless wantarray;
            return ($mant, $expo);
        }

        $mant = $mant -&gt; blsft($c - $ndigmant, 10, @r);
    }

    return $mant unless wantarray;
    return ($mant, $expo);
}

# Parts used for decimal notation, e.g., "12345.6789" is returned as "12345"
# (integer part) and "0.6789" (fraction part).

sub dparts {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Not-a-number.

    if ($x -&gt; is_nan()) {
        my $int = $class -&gt; bnan(@r);
        return $int unless wantarray;
        my $frc = $class -&gt; bzero(@r);    # or NaN?
        return ($int, $frc);
    }

    # Infinity.

    if ($x -&gt; is_inf()) {
        my $int = $class -&gt; binf($x-&gt;{sign}, @r);
        return $int unless wantarray;
        my $frc = $class -&gt; bzero(@r);
        return ($int, $frc);
    }

    # Upgrade?

    return $upgrade -&gt; dparts($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number.

    my $int = $x -&gt; copy() -&gt; round(@r);
    return $int unless wantarray;

    my $frc = $class -&gt; bzero(@r);
    return ($int, $frc);
}

# Fractional parts with the numerator and denominator as integers. E.g.,
# "123.4375" is returned as "1975" and "16".

sub fparts {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # NaN =&gt; NaN/NaN

    if ($x -&gt; is_nan()) {
        return $class -&gt; bnan(@r) unless wantarray;
        return $class -&gt; bnan(@r), $class -&gt; bnan(@r);
    }

    # Â±Inf =&gt; Â±Inf/1

    if ($x -&gt; is_inf()) {
        my $numer = $class -&gt; binf($x-&gt;{sign}, @r);
        return $numer unless wantarray;
        my $denom = $class -&gt; bone(@r);
        return $numer, $denom;
    }

    # Upgrade?

    return $upgrade -&gt; fparts($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # N =&gt; N/1

    my $numer = $x -&gt; copy() -&gt; round(@r);
    return $numer unless wantarray;
    my $denom = $class -&gt; bone(@r);
    return $numer, $denom;
}

sub numerator {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $upgrade -&gt; numerator($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    return $x -&gt; copy() -&gt; round(@r);
}

sub denominator {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $upgrade -&gt; denominator($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    return $x -&gt; is_nan() ? $class -&gt; bnan(@r) : $class -&gt; bone(@r);
}

###############################################################################
# String conversion methods
###############################################################################

sub bstr {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Inf and NaN

    if ($x-&gt;{sign} ne '+' &amp;&amp; $x-&gt;{sign} ne '-') {
        return $x-&gt;{sign} unless $x-&gt;{sign} eq '+inf'; # -inf, NaN
        return 'inf';                                  # +inf
    }

    # Upgrade?

    return $upgrade -&gt; bstr($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number

    my $str = $LIB-&gt;_str($x-&gt;{value});
    return $x-&gt;{sign} eq '-' ? "-$str" : $str;
}

# Scientific notation with significand/mantissa as an integer, e.g., "12345" is
# written as "1.2345e+4".

sub bsstr {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Inf and NaN

    if ($x-&gt;{sign} ne '+' &amp;&amp; $x-&gt;{sign} ne '-') {
        return $x-&gt;{sign} unless $x-&gt;{sign} eq '+inf';  # -inf, NaN
        return 'inf';                                   # +inf
    }

    # Upgrade?

    return $upgrade -&gt; bsstr($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number

    my $expo = $LIB -&gt; _zeros($x-&gt;{value});
    my $mant = $LIB -&gt; _str($x-&gt;{value});
    $mant = substr($mant, 0, -$expo) if $expo;  # strip trailing zeros

    ($x-&gt;{sign} eq '-' ? '-' : '') . $mant . 'e+' . $expo;
}

# Normalized notation, e.g., "12345" is written as "1.2345e+4".

sub bnstr {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Inf and NaN

    if ($x-&gt;{sign} ne '+' &amp;&amp; $x-&gt;{sign} ne '-') {
        return $x-&gt;{sign} unless $x-&gt;{sign} eq '+inf';  # -inf, NaN
        return 'inf';                                   # +inf
    }

    # Upgrade?

    return $upgrade -&gt; bnstr($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number

    my $expo = $LIB -&gt; _zeros($x-&gt;{value});
    my $mant = $LIB -&gt; _str($x-&gt;{value});
    $mant = substr($mant, 0, -$expo) if $expo;  # strip trailing zeros

    my $mantlen = CORE::length($mant);
    if ($mantlen &gt; 1) {
        $expo += $mantlen - 1;                  # adjust exponent
        substr $mant, 1, 0, ".";                # insert decimal point
    }

    ($x-&gt;{sign} eq '-' ? '-' : '') . $mant . 'e+' . $expo;
}

# Engineering notation, e.g., "12345" is written as "12.345e+3".

sub bestr {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Inf and NaN

    if ($x-&gt;{sign} ne '+' &amp;&amp; $x-&gt;{sign} ne '-') {
        return $x-&gt;{sign} unless $x-&gt;{sign} eq '+inf';  # -inf, NaN
        return 'inf';                                   # +inf
    }

    # Upgrade?

    return $upgrade -&gt; bestr($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number

    my $expo = $LIB -&gt; _zeros($x-&gt;{value});     # number of trailing zeros
    my $mant = $LIB -&gt; _str($x-&gt;{value});       # mantissa as a string
    $mant = substr($mant, 0, -$expo) if $expo;  # strip trailing zeros
    my $mantlen = CORE::length($mant);          # length of mantissa
    $expo += $mantlen;

    my $dotpos = ($expo - 1) % 3 + 1;           # offset of decimal point
    $expo -= $dotpos;

    if ($dotpos &lt; $mantlen) {
        substr $mant, $dotpos, 0, ".";          # insert decimal point
    } elsif ($dotpos &gt; $mantlen) {
        $mant .= "0" x ($dotpos - $mantlen);    # append zeros
    }

    ($x-&gt;{sign} eq '-' ? '-' : '') . $mant . 'e+' . $expo;
}

# Decimal notation, e.g., "12345" (no exponent).

sub bdstr {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Inf and NaN

    if ($x-&gt;{sign} ne '+' &amp;&amp; $x-&gt;{sign} ne '-') {
        return $x-&gt;{sign} unless $x-&gt;{sign} eq '+inf';  # -inf, NaN
        return 'inf';                                   # +inf
    }

    # Upgrade?

    return $upgrade -&gt; bdstr($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number

    ($x-&gt;{sign} eq '-' ? '-' : '') . $LIB-&gt;_str($x-&gt;{value});
}

# Fraction notation, e.g., "123.4375" is written as "1975/16", but "123" is
# written as "123", not "123/1".

sub bfstr {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Inf and NaN

    if ($x-&gt;{sign} ne '+' &amp;&amp; $x-&gt;{sign} ne '-') {
        return $x-&gt;{sign} unless $x-&gt;{sign} eq '+inf';  # -inf, NaN
        return 'inf';                                   # +inf
    }

    # Upgrade?

    return $upgrade -&gt; bfstr($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number

    ($x-&gt;{sign} eq '-' ? '-' : '') . $LIB-&gt;_str($x-&gt;{value});
}

sub to_hex {
    # return as hex string with no prefix

    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Inf and NaN

    if ($x-&gt;{sign} ne '+' &amp;&amp; $x-&gt;{sign} ne '-') {
        return $x-&gt;{sign} unless $x-&gt;{sign} eq '+inf';  # -inf, NaN
        return 'inf';                                   # +inf
    }

    # Upgrade?

    return $upgrade -&gt; to_hex($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number

    my $hex = $LIB-&gt;_to_hex($x-&gt;{value});
    return $x-&gt;{sign} eq '-' ? "-$hex" : $hex;
}

sub to_oct {
    # return as octal string with no prefix

    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Inf and NaN

    if ($x-&gt;{sign} ne '+' &amp;&amp; $x-&gt;{sign} ne '-') {
        return $x-&gt;{sign} unless $x-&gt;{sign} eq '+inf';  # -inf, NaN
        return 'inf';                                   # +inf
    }

    # Upgrade?

    return $upgrade -&gt; to_oct($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number

    my $oct = $LIB-&gt;_to_oct($x-&gt;{value});
    return $x-&gt;{sign} eq '-' ? "-$oct" : $oct;
}

sub to_bin {
    # return as binary string with no prefix

    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    # Inf and NaN

    if ($x-&gt;{sign} ne '+' &amp;&amp; $x-&gt;{sign} ne '-') {
        return $x-&gt;{sign} unless $x-&gt;{sign} eq '+inf';  # -inf, NaN
        return 'inf';                                   # +inf
    }

    # Upgrade?

    return $upgrade -&gt; to_bin($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    # Finite number

    my $bin = $LIB-&gt;_to_bin($x-&gt;{value});
    return $x-&gt;{sign} eq '-' ? "-$bin" : $bin;
}

sub to_bytes {
    # return a byte string

    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    croak("to_bytes() requires a finite, non-negative integer")
        if $x -&gt; is_neg() || ! $x -&gt; is_int();

    return $upgrade -&gt; to_bytes($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    croak("to_bytes() requires a newer version of the $LIB library.")
        unless $LIB-&gt;can('_to_bytes');

    return $LIB-&gt;_to_bytes($x-&gt;{value});
}

sub to_base {
    # return a base anything string

    # $cs is the collation sequence
    my ($class, $x, $base, $cs, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                                    ? (ref($_[0]), @_) : objectify(2, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    croak("the value to convert must be a finite, non-negative integer")
      if $x -&gt; is_neg() || !$x -&gt; is_int();

    croak("the base must be a finite integer &gt;= 2")
      if $base &lt; 2 || ! $base -&gt; is_int();

    # If no collating sequence is given, pass some of the conversions to
    # methods optimized for those cases.

    unless (defined $cs) {
        return    $x -&gt; to_bin() if $base == 2;
        return    $x -&gt; to_oct() if $base == 8;
        return uc $x -&gt; to_hex() if $base == 16;
        return    $x -&gt; bstr()   if $base == 10;
    }

    croak("to_base() requires a newer version of the $LIB library.")
      unless $LIB-&gt;can('_to_base');

    return $upgrade -&gt; to_base($x, $base, $cs, @r)
      if defined($upgrade) &amp;&amp; (!$x -&gt; isa(__PACKAGE__) ||
                               !$base -&gt; isa(__PACKAGE__));

    return $LIB-&gt;_to_base($x-&gt;{value}, $base -&gt; {value},
                          defined($cs) ? $cs : ());
}

sub to_base_num {
    # return a base anything array ref, e.g.,
    # Math::BigInt -&gt; new(255) -&gt; to_base_num(10) returns [2, 5, 5];

    # $cs is the collation sequence
    my ($class, $x, $base, @r) = ref($_[0]) &amp;&amp; ref($_[0]) eq ref($_[1])
                               ? (ref($_[0]), @_) : objectify(2, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    croak("the value to convert must be a finite non-negative integer")
      if $x -&gt; is_neg() || !$x -&gt; is_int();

    croak("the base must be a finite integer &gt;= 2")
      if $base &lt; 2 || ! $base -&gt; is_int();

    croak("to_base() requires a newer version of the $LIB library.")
      unless $LIB-&gt;can('_to_base');

    return $upgrade -&gt; to_base_num($x, $base, @r)
      if defined($upgrade) &amp;&amp; (!$x -&gt; isa(__PACKAGE__) ||
                               !$base -&gt; isa(__PACKAGE__));

    # Get a reference to an array of library thingies, and replace each element
    # with a Math::BigInt object using that thingy.

    my $vals = $LIB -&gt; _to_base_num($x-&gt;{value}, $base -&gt; {value});

    for my $i (0 .. $#$vals) {
        my $x = $class -&gt; bzero();
        $x -&gt; {value} = $vals -&gt; [$i];
        $vals -&gt; [$i] = $x;
    }

    return $vals;
}

sub as_hex {
    # return as hex string, with prefixed 0x

    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $x-&gt;bstr() if $x-&gt;{sign} !~ /^[+-]$/; # inf, nan etc

    return $upgrade -&gt; as_hex($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    my $hex = $LIB-&gt;_as_hex($x-&gt;{value});
    return $x-&gt;{sign} eq '-' ? "-$hex" : $hex;
}

sub as_oct {
    # return as octal string, with prefixed 0

    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $x-&gt;bstr() if $x-&gt;{sign} !~ /^[+-]$/; # inf, nan etc

    return $upgrade -&gt; as_oct($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    my $oct = $LIB-&gt;_as_oct($x-&gt;{value});
    return $x-&gt;{sign} eq '-' ? "-$oct" : $oct;
}

sub as_bin {
    # return as binary string, with prefixed 0b

    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    return $x-&gt;bstr() if $x-&gt;{sign} !~ /^[+-]$/; # inf, nan etc

    return $upgrade -&gt; as_bin($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    my $bin = $LIB-&gt;_as_bin($x-&gt;{value});
    return $x-&gt;{sign} eq '-' ? "-$bin" : $bin;
}

*as_bytes = \&amp;to_bytes;

###############################################################################
# Other conversion methods
###############################################################################

sub numify {
    # Make a Perl scalar number from a Math::BigInt object.
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    carp "Rounding is not supported for ", (caller(0))[3], "()" if @r;

    if ($x -&gt; is_nan()) {
        require Math::Complex;
        my $inf = $Math::Complex::Inf;
        return $inf - $inf;
    }

    if ($x -&gt; is_inf()) {
        require Math::Complex;
        my $inf = $Math::Complex::Inf;
        return $x -&gt; is_negative() ? -$inf : $inf;
    }

    return $upgrade -&gt; numify($x, @r)
      if defined($upgrade) &amp;&amp; !$x -&gt; isa(__PACKAGE__);

    my $num = 0 + $LIB-&gt;_num($x-&gt;{value});
    return $x-&gt;{sign} eq '-' ? -$num : $num;
}

###############################################################################
# Private methods and functions.
###############################################################################

sub objectify {
    # Convert strings and "foreign objects" to the objects we want.

    # The first argument, $count, is the number of following arguments that
    # objectify() looks at and converts to objects. The first is a classname.
    # If the given count is 0, all arguments will be used.

    # After the count is read, objectify obtains the name of the class to which
    # the following arguments are converted. If the second argument is a
    # reference, use the reference type as the class name. Otherwise, if it is
    # a string that looks like a class name, use that. Otherwise, use $class.

    # Caller:                        Gives us:
    #
    # $x-&gt;badd(1);                =&gt; ref x, scalar y
    # Class-&gt;badd(1, 2);           =&gt; classname x (scalar), scalar x, scalar y
    # Class-&gt;badd(Class-&gt;(1), 2);  =&gt; classname x (scalar), ref x, scalar y
    # Math::BigInt::badd(1, 2);    =&gt; scalar x, scalar y

    # A shortcut for the common case $x-&gt;unary_op(), in which case the argument
    # list is (0, $x) or (1, $x).

    return (ref($_[1]), $_[1]) if @_ == 2 &amp;&amp; ($_[0] || 0) == 1 &amp;&amp; ref($_[1]);

    # Check the context.

    unless (wantarray) {
        croak(__PACKAGE__ . "::objectify() needs list context");
    }

    # Get the number of arguments to objectify.

    my $count = shift;

    # Initialize the output array.

    my @a = @_;

    # If the first argument is a reference, use that reference type as our
    # class name. Otherwise, if the first argument looks like a class name,
    # then use that as our class name. Otherwise, use the default class name.

    my $class;
    if (ref($a[0])) {                   # reference?
        $class = ref($a[0]);
    } elsif ($a[0] =~ /^[A-Z].*::/) {   # string with class name?
        $class = shift @a;
    } else {
        $class = __PACKAGE__;           # default class name
    }

    $count ||= @a;
    unshift @a, $class;

    # What we upgrade to, if anything. Note that we need the whole upgrade
    # chain, since there might be multiple levels of upgrading. E.g., class A
    # upgrades to class B, which upgrades to class C. Delay getting the chain
    # until we actually need it.

    my @upg = ();
    my $have_upgrade_chain = 0;

    # Disable downgrading, because Math::BigFloat -&gt; foo('1.0', '2.0') needs
    # floats.

    my $dng = $class -&gt; downgrade();
    $class -&gt; downgrade(undef);

  ARG: for my $i (1 .. $count) {

        my $ref = ref $a[$i];

        # Perl scalars are fed to the appropriate constructor.

        unless ($ref) {
            $a[$i] = $class -&gt; new($a[$i]);
            next;
        }

        # If it is an object of the right class, all is fine.

        next if $ref -&gt; isa($class);

        # Upgrading is OK, so skip further tests if the argument is upgraded,
        # but first get the whole upgrade chain if we haven't got it yet.

        unless ($have_upgrade_chain) {
            my $cls = $class;
            my $upg = $cls -&gt; upgrade();
            while (defined $upg) {
                last if $upg eq $cls;
                push @upg, $upg;
                $cls = $upg;
                $upg = $cls -&gt; upgrade();
            }
            $have_upgrade_chain = 1;
        }

        for my $upg (@upg) {
            next ARG if $ref -&gt; isa($upg);
        }

        # See if we can call one of the as_xxx() methods. We don't know whether
        # the as_xxx() method returns an object or a scalar, so re-check
        # afterwards.

        my $recheck = 0;

        if ($class -&gt; isa('Math::BigInt')) {
            if ($a[$i] -&gt; can('as_int')) {
                $a[$i] = $a[$i] -&gt; as_int();
                $recheck = 1;
            } elsif ($a[$i] -&gt; can('as_number')) {
                $a[$i] = $a[$i] -&gt; as_number();
                $recheck = 1;
            }
        }

        elsif ($class -&gt; isa('Math::BigRat')) {
            if ($a[$i] -&gt; can('as_rat')) {
                $a[$i] = $a[$i] -&gt; as_rat();
                $recheck = 1;
            }
        }

        elsif ($class -&gt; isa('Math::BigFloat')) {
            if ($a[$i] -&gt; can('as_float')) {
                $a[$i] = $a[$i] -&gt; as_float();
                $recheck = 1;
            }
        }

        # If we called one of the as_xxx() methods, recheck.

        if ($recheck) {
            $ref = ref($a[$i]);

            # Perl scalars are fed to the appropriate constructor.

            unless ($ref) {
                $a[$i] = $class -&gt; new($a[$i]);
                next;
            }

            # If it is an object of the right class, all is fine.

            next if $ref -&gt; isa($class);
        }

        # Last resort.

        $a[$i] = $class -&gt; new($a[$i]);
    }

    # Restore the downgrading.

    $class -&gt; downgrade($dng);

    return @a;
}

sub import {
    my $class = shift;
    $IMPORT++;                  # remember we did import()
    my @a;                      # unrecognized arguments

    while (@_) {
        my $param = shift;

        # Enable overloading of constants.

        if ($param eq ':constant') {
            overload::constant

                integer =&gt; sub {
                    $class -&gt; new(shift);
                },

                float   =&gt; sub {
                    $class -&gt; new(shift);
                },

                binary  =&gt; sub {
                    # E.g., a literal 0377 shall result in an object whose value
                    # is decimal 255, but new("0377") returns decimal 377.
                    return $class -&gt; from_oct($_[0]) if $_[0] =~ /^0_*[0-7]/;
                    $class -&gt; new(shift);
                };
            next;
        }

        # Upgrading.

        if ($param eq 'upgrade') {
            $class -&gt; upgrade(shift);
            next;
        }

        # Downgrading.

        if ($param eq 'downgrade') {
            $class -&gt; downgrade(shift);
            next;
        }

        # Accuracy.

        if ($param eq 'accuracy') {
            $class -&gt; accuracy(shift);
            next;
        }

        # Precision.

        if ($param eq 'precision') {
            $class -&gt; precision(shift);
            next;
        }

        # Rounding mode.

        if ($param eq 'round_mode') {
            $class -&gt; round_mode(shift);
            next;
        }

        # Fall-back accuracy.

        if ($param eq 'div_scale') {
            $class -&gt; div_scale(shift);
            next;
        }

        # Backend library.

        if ($param =~ /^(lib|try|only)\z/) {
            # try  =&gt; 0 (no warn if unavailable module)
            # lib  =&gt; 1 (warn on fallback)
            # only =&gt; 2 (die on fallback)

            # Get the list of user-specified libraries.

            croak "Library argument for import parameter '$param' is missing"
              unless @_;
            my $libs = shift;
            croak "Library argument for import parameter '$param' is undefined"
              unless defined($libs);

            # Check and clean up the list of user-specified libraries.

            my @libs;
            for my $lib (split /,/, $libs) {
                $lib =~ s/^\s+//;
                $lib =~ s/\s+$//;

                if ($lib =~ /[^a-zA-Z0-9_:]/) {
                    carp "Library name '$lib' contains invalid characters";
                    next;
                }

                if (! CORE::length $lib) {
                    carp "Library name is empty";
                    next;
                }

                $lib = "Math::BigInt::$lib" if $lib !~ /^Math::BigInt::/i;

                # If a library has already been loaded, that is OK only if the
                # requested library is identical to the loaded one.

                if (defined($LIB)) {
                    if ($lib ne $LIB) {
                        #carp "Library '$LIB' has already been loaded, so",
                        #  " ignoring requested library '$lib'";
                    }
                    next;
                }

                push @libs, $lib;
            }

            next if defined $LIB;

            croak "Library list contains no valid libraries" unless @libs;

            # Try to load the specified libraries, if any.

            for (my $i = 0 ; $i &lt;= $#libs ; $i++) {
                my $lib = $libs[$i];
                eval "require $lib";
                unless ($@) {
                    $LIB = $lib;
                    last;
                }
            }

            next if defined $LIB;

            # No library has been loaded, and none of the requested libraries
            # could be loaded, and fallback and the user doesn't allow fallback.

            if ($param eq 'only') {
                croak "Couldn't load the specified math lib(s) ",
                  join(", ", map "'$_'", @libs),
                  ", and fallback to '$DEFAULT_LIB' is not allowed";
            }

            # No library has been loaded, and none of the requested libraries
            # could be loaded, but the user accepts the use of a fallback
            # library, so try to load it.

            eval "require $DEFAULT_LIB";
            if ($@) {
                croak "Couldn't load the specified math lib(s) ",
                  join(", ", map "'$_'", @libs),
                  ", not even the fallback lib '$DEFAULT_LIB'";
            }

            # The fallback library was successfully loaded, but the user
            # might want to know that we are using the fallback.

            if ($param eq 'lib') {
                carp "Couldn't load the specified math lib(s) ",
                  join(", ", map "'$_'", @libs),
                  ", so using fallback lib '$DEFAULT_LIB'";
            }

            next;
        }

        # Unrecognized parameter.

        push @a, $param;
    }

    # Any non-':constant' stuff is handled by our parent, Exporter

    $class -&gt; SUPER::import(@a);                        # for subclasses
    $class -&gt; export_to_level(1, $class, @a) if @a;     # need this, too

    # We might not have loaded any backend library yet, either because the user
    # didn't specify any, or because the specified libraries failed to load and
    # the user allows the use of a fallback library.

    unless (defined $LIB) {
        eval "require $DEFAULT_LIB";
        if ($@) {
            croak "No lib specified, and couldn't load the default",
              " lib '$DEFAULT_LIB'";
        }
        $LIB = $DEFAULT_LIB;
    }

    # import done
}

sub _trailing_zeros {
    # return the amount of trailing zeros in $x (as scalar)
    my $x = shift;
    $x = __PACKAGE__-&gt;new($x) unless ref $x;

    return 0 if $x-&gt;{sign} !~ /^[+-]$/; # NaN, inf, -inf etc

    $LIB-&gt;_zeros($x-&gt;{value}); # must handle odd values, 0 etc
}

sub _scan_for_nonzero {
    # internal, used by bround() to scan for non-zeros after a '5'
    my ($x, $pad, $xs, $len) = @_;

    return 0 if $len == 1;      # "5" is trailed by invisible zeros
    my $follow = $pad - 1;
    return 0 if $follow &gt; $len || $follow &lt; 1;

    # use the string form to check whether only '0's follow or not
    substr ($xs, -$follow) =~ /[^0]/ ? 1 : 0;
}

sub _find_round_parameters {
    # After any operation or when calling round(), the result is rounded by
    # regarding the A &amp; P from arguments, local parameters, or globals.

    # !!!!!!! If you change this, remember to change round(), too! !!!!!!!!!!

    # This procedure finds the round parameters, but it is for speed reasons
    # duplicated in round. Otherwise, it is tested by the testsuite and used
    # by bdiv().

    # returns ($self) or ($self, $a, $p, $r) - sets $self to NaN of both A and P
    # were requested/defined (locally or globally or both)

    my ($self, $a, $p, $r, @args) = @_;
    # $a accuracy, if given by caller
    # $p precision, if given by caller
    # $r round_mode, if given by caller
    # @args all 'other' arguments (0 for unary, 1 for binary ops)

    my $class = ref($self);       # find out class of argument(s)

    # convert to normal scalar for speed and correctness in inner parts
    $a = $a-&gt;can('numify') ? $a-&gt;numify() : "$a" if defined $a &amp;&amp; ref($a);
    $p = $p-&gt;can('numify') ? $p-&gt;numify() : "$p" if defined $p &amp;&amp; ref($p);

    # now pick $a or $p, but only if we have got "arguments"
    if (!defined $a) {
        foreach ($self, @args) {
            # take the defined one, or if both defined, the one that is smaller
            $a = $_-&gt;{accuracy}
              if (defined $_-&gt;{accuracy}) &amp;&amp; (!defined $a || $_-&gt;{accuracy} &lt; $a);
        }
    }
    if (!defined $p) {
        # even if $a is defined, take $p, to signal error for both defined
        foreach ($self, @args) {
            # take the defined one, or if both defined, the one that is bigger
            # -2 &gt; -3, and 3 &gt; 2
            $p = $_-&gt;{precision}
              if (defined $_-&gt;{precision}) &amp;&amp; (!defined $p || $_-&gt;{precision} &gt; $p);
        }
    }

    # if still none defined, use globals (#2)
    $a = $class -&gt; accuracy()  unless defined $a;
    $p = $class -&gt; precision() unless defined $p;

    # A == 0 is useless, so undef it to signal no rounding
    $a = undef if defined $a &amp;&amp; $a == 0;

    # no rounding today?
    return ($self) unless defined $a || defined $p; # early out

    # set A and set P is an fatal error
    return ($self-&gt;bnan()) if defined $a &amp;&amp; defined $p; # error

    $r = $class -&gt; round_mode() unless defined $r;
    if ($r !~ /^(even|odd|[+-]inf|zero|trunc|common)$/) {
        croak("Unknown round mode '$r'");
    }

    $a = int($a) if defined $a;
    $p = int($p) if defined $p;

    ($self, $a, $p, $r);
}

# Return true if the input is numeric and false if it is a string.

sub _is_numeric {
    shift;              # class name
    my $value = shift;
    no warnings 'numeric';
    # detect numbers
    # string &amp; "" -&gt; ""
    # number &amp; "" -&gt; 0 (with warning)
    # nan and inf can detect as numbers, so check with * 0
    return unless CORE::length((my $dummy = "") &amp; $value);
    return unless 0 + $value eq $value;
    return 1 if $value * 0 == 0;
    return -1;          # Inf/NaN
}

# Trims the sign of the significand, the (absolute value of the) significand,
# the sign of the exponent, and the (absolute value of the) exponent. The
# returned values have no underscores ("_") or unnecessary leading or trailing
# zeros.

sub _trim_split_parts {
    shift;               # class name

    my $sig_sgn = shift() || '+';
    my $sig_str = shift() || '0';
    my $exp_sgn = shift() || '+';
    my $exp_str = shift() || '0';

    $sig_str =~ tr/_//d;                        # "1.0_0_0" -&gt; "1.000"
    $sig_str =~ s/^0+//;                        # "01.000" -&gt; "1.000"
    $sig_str =~ s/\.0*$//                       # "1.000" -&gt; "1"
      || $sig_str =~ s/(\..*[^0])0+$/$1/;       # "1.010" -&gt; "1.01"
    $sig_str = '0' unless CORE::length($sig_str);

    return '+', '0', '+', '0' if $sig_str eq '0';

    $exp_str =~ tr/_//d;                        # "01_234" -&gt; "01234"
    $exp_str =~ s/^0+//;                        # "01234" -&gt; "1234"
    $exp_str = '0' unless CORE::length($exp_str);
    $exp_sgn = '+' if $exp_str eq '0';          # "+3e-0" -&gt; "+3e+0"

    return $sig_sgn, $sig_str, $exp_sgn, $exp_str;
}

# Takes any string representing a valid decimal number and splits it into four
# strings: the sign of the significand, the absolute value of the significand,
# the sign of the exponent, and the absolute value of the exponent. Both the
# significand and the exponent are in base 10.
#
# Perl accepts literals like the following. The value is 100.1.
#
#   1__0__.__0__1__e+0__1__     (prints "Misplaced _ in number")
#   1_0.0_1e+0_1
#
# Strings representing decimal numbers do not allow underscores, so only the
# following is valid
#
#   "10.01e+01"

sub _dec_str_to_dec_str_parts {
    my $class = shift;
    my $str   = shift;

    if ($str =~ /
                    ^

                    # optional leading whitespace
                    \s*

                    # optional sign
                    ( [+-]? )

                    # significand
                    (
                        # integer part and optional fraction part ...
                        \d+ (?: _+ \d+ )* _*
                        (?:
                            \.
                            (?: _* \d+ (?: _+ \d+ )* _* )?
                        )?
                    |
                        # ... or mandatory fraction part
                        \.
                        \d+ (?: _+ \d+ )* _*
                    )

                    # optional exponent
                    (?:
                        [Ee]
                        ( [+-]? )
                        ( \d+ (?: _+ \d+ )* _* )
                    )?

                    # optional trailing whitespace
                    \s*

                    $
                /x)
    {
        return $class -&gt; _trim_split_parts($1, $2, $3, $4);
    }

    return;
}

# Takes any string representing a valid hexadecimal number and splits it into
# four strings: the sign of the significand, the absolute value of the
# significand, the sign of the exponent, and the absolute value of the exponent.
# The significand is in base 16, and the exponent is in base 2.
#
# Perl accepts literals like the following. The "x" might be a capital "X". The
# value is 32.0078125.
#
#   0x__1__0__.0__1__p+0__1__   (prints "Misplaced _ in number")
#   0x1_0.0_1p+0_1
#
# The CORE::hex() function does not accept floating point accepts
#
#   "0x_1_0"
#   "x_1_0"
#   "_1_0"

sub _hex_str_to_hex_str_parts {
    my $class = shift;
    my $str   = shift;

    if ($str =~ /
                    ^

                    # optional leading whitespace
                    \s*

                    # optional sign
                    ( [+-]? )

                    # optional hex prefix
                    (?: 0? [Xx] _* )?

                    # significand using the hex digits 0..9 and a..f
                    (
                        # integer part and optional fraction part ...
                        [0-9a-fA-F]+ (?: _+ [0-9a-fA-F]+ )* _*
                        (?:
                            \.
                            (?: _* [0-9a-fA-F]+ (?: _+ [0-9a-fA-F]+ )* _* )?
                        )?
                    |
                        # ... or mandatory fraction part
                        \.
                        [0-9a-fA-F]+ (?: _+ [0-9a-fA-F]+ )* _*
                    )

                    # optional exponent (power of 2) using decimal digits
                    (?:
                        [Pp]
                        ( [+-]? )
                        ( \d+ (?: _+ \d+ )* _* )
                    )?

                    # optional trailing whitespace
                    \s*

                    $
                /x)
    {
        return $class -&gt; _trim_split_parts($1, $2, $3, $4);
    }

    return;
}

# Takes any string representing a valid octal number and splits it into four
# strings: the sign of the significand, the absolute value of the significand,
# the sign of the exponent, and the absolute value of the exponent. The
# significand is in base 8, and the exponent is in base 2.

sub _oct_str_to_oct_str_parts {
    my $class = shift;
    my $str   = shift;

    if ($str =~ /
                    ^

                    # optional leading whitespace
                    \s*

                    # optional sign
                    ( [+-]? )

                    # optional octal prefix
                    (?: 0? [Oo] _* )?

                    # significand using the octal digits 0..7
                    (
                        # integer part and optional fraction part ...
                        [0-7]+ (?: _+ [0-7]+ )* _*
                        (?:
                            \.
                            (?: _* [0-7]+ (?: _+ [0-7]+ )* _* )?
                        )?
                    |
                        # ... or mandatory fraction part
                        \.
                        [0-7]+ (?: _+ [0-7]+ )* _*
                    )

                    # optional exponent (power of 2) using decimal digits
                    (?:
                        [Pp]
                        ( [+-]? )
                        ( \d+ (?: _+ \d+ )* _* )
                    )?

                    # optional trailing whitespace
                    \s*

                    $
                /x)
    {
        return $class -&gt; _trim_split_parts($1, $2, $3, $4);
    }

    return;
}

# Takes any string representing a valid binary number and splits it into four
# strings: the sign of the significand, the absolute value of the significand,
# the sign of the exponent, and the absolute value of the exponent. The
# significand is in base 2, and the exponent is in base 2.

sub _bin_str_to_bin_str_parts {
    my $class = shift;
    my $str   = shift;

    if ($str =~ /
                    ^

                    # optional leading whitespace
                    \s*

                    # optional sign
                    ( [+-]? )

                    # optional binary prefix
                    (?: 0? [Bb] _* )?

                    # significand using the binary digits 0 and 1
                    (
                        # integer part and optional fraction part ...
                        [01]+ (?: _+ [01]+ )* _*
                        (?:
                            \.
                            (?: _* [01]+ (?: _+ [01]+ )* _* )?
                        )?
                    |
                        # ... or mandatory fraction part
                        \.
                        [01]+ (?: _+ [01]+ )* _*
                    )

                    # optional exponent (power of 2) using decimal digits
                    (?:
                        [Pp]
                        ( [+-]? )
                        ( \d+ (?: _+ \d+ )* _* )
                    )?

                    # optional trailing whitespace
                    \s*

                    $
                /x)
    {
        return $class -&gt; _trim_split_parts($1, $2, $3, $4);
    }

    return;
}

# Takes any string representing a valid decimal number and splits it into four
# parts: the sign of the significand, the absolute value of the significand as a
# libray thingy, the sign of the exponent, and the absolute value of the
# exponent as a library thingy.

sub _dec_str_parts_to_flt_lib_parts {
    shift;               # class name

    my ($sig_sgn, $sig_str, $exp_sgn, $exp_str) = @_;

    # Handle zero.

    if ($sig_str eq '0') {
        return '+', $LIB -&gt; _zero(), '+', $LIB -&gt; _zero();
    }

    # Absolute value of exponent as library "object".

    my $exp_lib = $LIB -&gt; _new($exp_str);

    # If there is a dot in the significand, remove it so the significand
    # becomes an integer and adjust the exponent accordingly. Also remove
    # leading zeros which might now appear in the significand. E.g.,
    #
    #     12.345e-2  -&gt;  12345e-5
    #     12.345e+2  -&gt;  12345e-1
    #     0.0123e+5  -&gt;  00123e+1  -&gt;  123e+1

    my $idx = index $sig_str, '.';
    if ($idx &gt;= 0) {
        substr($sig_str, $idx, 1) = '';

        # delta = length - index
        my $delta = $LIB -&gt; _new(CORE::length($sig_str));
        $delta = $LIB -&gt; _sub($delta, $LIB -&gt; _new($idx));

        # exponent - delta
        ($exp_lib, $exp_sgn) = $LIB -&gt; _ssub($exp_lib, $exp_sgn, $delta, '+');

        $sig_str =~ s/^0+//;
    }

    # If there are trailing zeros in the significand, remove them and
    # adjust the exponent. E.g.,
    #
    #     12340e-5  -&gt;  1234e-4
    #     12340e-1  -&gt;  1234e0
    #     12340e+3  -&gt;  1234e4

    if ($sig_str =~ s/(0+)\z//) {
        my $len = CORE::length($1);
        ($exp_lib, $exp_sgn) =
          $LIB -&gt; _sadd($exp_lib, $exp_sgn, $LIB -&gt; _new($len), '+');
    }

    # At this point, the significand is empty or an integer with no trailing
    # zeros. The exponent is in base 10.

    unless (CORE::length $sig_str) {
        return '+', $LIB -&gt; _zero(), '+', $LIB -&gt; _zero();
    }

    # Absolute value of significand as library "object".

    my $sig_lib = $LIB -&gt; _new($sig_str);

    return $sig_sgn, $sig_lib, $exp_sgn, $exp_lib;
}

# Takes any string representing a valid binary number and splits it into four
# parts: the sign of the significand, the absolute value of the significand as a
# libray thingy, the sign of the exponent, and the absolute value of the
# exponent as a library thingy.

sub _bin_str_parts_to_flt_lib_parts {
    shift;               # class name

    my ($sig_sgn, $sig_str, $exp_sgn, $exp_str, $bpc) = @_;
    my $bpc_lib = $LIB -&gt; _new($bpc);

    # Handle zero.

    if ($sig_str eq '0') {
        return '+', $LIB -&gt; _zero(), '+', $LIB -&gt; _zero();
    }

    # Absolute value of exponent as library "object".

    my $exp_lib = $LIB -&gt; _new($exp_str);

    # If there is a dot in the significand, remove it so the significand
    # becomes an integer and adjust the exponent accordingly. Also remove
    # leading zeros which might now appear in the significand. E.g., with
    # hexadecimal numbers
    #
    #     12.345p-2  -&gt;  12345p-14
    #     12.345p+2  -&gt;  12345p-10
    #     0.0123p+5  -&gt;  00123p-11  -&gt;  123p-11

    my $idx = index $sig_str, '.';
    if ($idx &gt;= 0) {
        substr($sig_str, $idx, 1) = '';

        # delta = (length - index) * bpc
        my $delta = $LIB -&gt; _new(CORE::length($sig_str));
        $delta = $LIB -&gt; _sub($delta, $LIB -&gt; _new($idx));
        $delta = $LIB -&gt; _mul($delta, $bpc_lib) if $bpc != 1;

        # exponent - delta
        ($exp_lib, $exp_sgn) = $LIB -&gt; _ssub($exp_lib, $exp_sgn, $delta, '+');

        $sig_str =~ s/^0+//;
    }

    # If there are trailing zeros in the significand, remove them and
    # adjust the exponent accordingly. E.g., with hexadecimal numbers
    #
    #     12340p-5  -&gt;  1234p-1
    #     12340p-1  -&gt;  1234p+3
    #     12340p+3  -&gt;  1234p+7

    if ($sig_str =~ s/(0+)\z//) {

        # delta = length * bpc
        my $delta = $LIB -&gt; _new(CORE::length($1));
        $delta = $LIB -&gt; _mul($delta, $bpc_lib) if $bpc != 1;

        # exponent + delta
        ($exp_lib, $exp_sgn) = $LIB -&gt; _sadd($exp_lib, $exp_sgn, $delta, '+');
    }

    # At this point, the significand is empty or an integer with no leading
    # or trailing zeros. The exponent is in base 2.

    unless (CORE::length $sig_str) {
        return '+', $LIB -&gt; _zero(), '+', $LIB -&gt; _zero();
    }

    # Absolute value of significand as library "object".

    my $sig_lib = $bpc == 1 ? $LIB -&gt; _from_bin('0b' . $sig_str)
                : $bpc == 3 ? $LIB -&gt; _from_oct('0'  . $sig_str)
                : $bpc == 4 ? $LIB -&gt; _from_hex('0x' . $sig_str)
                : die "internal error: invalid exponent multiplier";

    # If the exponent (in base 2) is positive or zero ...

    if ($exp_sgn eq '+') {

        if (!$LIB -&gt; _is_zero($exp_lib)) {

            # Multiply significand by 2 raised to the exponent.

            my $p = $LIB -&gt; _pow($LIB -&gt; _two(), $exp_lib);
            $sig_lib = $LIB -&gt; _mul($sig_lib, $p);
            $exp_lib = $LIB -&gt; _zero();
        }
    }

    # ... else if the exponent is negative ...

    else {

        # Rather than dividing the significand by 2 raised to the absolute
        # value of the exponent, multiply the significand by 5 raised to the
        # absolute value of the exponent and let the exponent be in base 10:
        #
        # a * 2^(-b) = a * 5^b * 10^(-b) = c * 10^(-b), where c = a * 5^b

        my $p = $LIB -&gt; _pow($LIB -&gt; _new("5"), $exp_lib);
        $sig_lib = $LIB -&gt; _mul($sig_lib, $p);
    }

    # Adjust for the case when the conversion to decimal introduced trailing
    # zeros in the significand.

    my $n = $LIB -&gt; _zeros($sig_lib);
    if ($n) {
        $n = $LIB -&gt; _new($n);
        $sig_lib = $LIB -&gt; _rsft($sig_lib, $n, 10);
        ($exp_lib, $exp_sgn) = $LIB -&gt; _sadd($exp_lib, $exp_sgn, $n, '+');
    }

    return $sig_sgn, $sig_lib, $exp_sgn, $exp_lib;
}

# Takes any string representing a valid hexadecimal number and splits it into
# four parts: the sign of the significand, the absolute value of the significand
# as a libray thingy, the sign of the exponent, and the absolute value of the
# exponent as a library thingy.

sub _hex_str_to_flt_lib_parts {
    my $class = shift;
    my $str   = shift;
    if (my @parts = $class -&gt; _hex_str_to_hex_str_parts($str)) {
        return $class -&gt; _bin_str_parts_to_flt_lib_parts(@parts, 4);  # 4 bits pr. chr
    }
    return;
}

# Takes any string representing a valid octal number and splits it into four
# parts: the sign of the significand, the absolute value of the significand as a
# libray thingy, the sign of the exponent, and the absolute value of the
# exponent as a library thingy.

sub _oct_str_to_flt_lib_parts {
    my $class = shift;
    my $str   = shift;
    if (my @parts = $class -&gt; _oct_str_to_oct_str_parts($str)) {
        return $class -&gt; _bin_str_parts_to_flt_lib_parts(@parts, 3);  # 3 bits pr. chr
    }
    return;
}

# Takes any string representing a valid binary number and splits it into four
# parts: the sign of the significand, the absolute value of the significand as a
# libray thingy, the sign of the exponent, and the absolute value of the
# exponent as a library thingy.

sub _bin_str_to_flt_lib_parts {
    my $class = shift;
    my $str   = shift;
    if (my @parts = $class -&gt; _bin_str_to_bin_str_parts($str)) {
        return $class -&gt; _bin_str_parts_to_flt_lib_parts(@parts, 1);  # 1 bit pr. chr
    }
    return;
}

# Decimal string is split into the sign of the signficant, the absolute value of
# the significand as library thingy, the sign of the exponent, and the absolute
# value of the exponent as a a library thingy.

sub _dec_str_to_flt_lib_parts {
    my $class = shift;
    my $str   = shift;
    if (my @parts = $class -&gt; _dec_str_to_dec_str_parts($str)) {
        return $class -&gt; _dec_str_parts_to_flt_lib_parts(@parts);
    }
    return;
}

# Hexdecimal string to a string using decimal floating point notation.

sub hex_str_to_dec_flt_str {
    my $class = shift;
    my $str   = shift;
    if (my @parts = $class -&gt; _hex_str_to_flt_lib_parts($str)) {
        return $class -&gt; _flt_lib_parts_to_flt_str(@parts);
    }
    return;
}

# Octal string to a string using decimal floating point notation.

sub oct_str_to_dec_flt_str {
    my $class = shift;
    my $str   = shift;
    if (my @parts = $class -&gt; _oct_str_to_flt_lib_parts($str)) {
        return $class -&gt; _flt_lib_parts_to_flt_str(@parts);
    }
    return;
}

# Binary string to a string decimal floating point notation.

sub bin_str_to_dec_flt_str {
    my $class = shift;
    my $str   = shift;
    if (my @parts = $class -&gt; _bin_str_to_flt_lib_parts($str)) {
        return $class -&gt; _flt_lib_parts_to_flt_str(@parts);
    }
    return;
}

# Decimal string to a string using decimal floating point notation.

sub dec_str_to_dec_flt_str {
    my $class = shift;
    my $str   = shift;
    if (my @parts = $class -&gt; _dec_str_to_flt_lib_parts($str)) {
        return $class -&gt; _flt_lib_parts_to_flt_str(@parts);
    }
    return;
}

# Hexdecimal string to decimal notation (no exponent).

sub hex_str_to_dec_str {
    my $class = shift;
    my $str   = shift;
    if (my @parts = $class -&gt; _dec_str_to_flt_lib_parts($str)) {
        return $class -&gt; _flt_lib_parts_to_dec_str(@parts);
    }
    return;
}

# Octal string to decimal notation (no exponent).

sub oct_str_to_dec_str {
    my $class = shift;
    my $str   = shift;
    if (my @parts = $class -&gt; _oct_str_to_flt_lib_parts($str)) {
        return $class -&gt; _flt_lib_parts_to_dec_str(@parts);
    }
    return;
}

# Binary string to decimal notation (no exponent).

sub bin_str_to_dec_str {
    my $class = shift;
    my $str   = shift;
    if (my @parts = $class -&gt; _bin_str_to_flt_lib_parts($str)) {
        return $class -&gt; _flt_lib_parts_to_dec_str(@parts);
    }
    return;
}

# Decimal string to decimal notation (no exponent).

sub dec_str_to_dec_str {
    my $class = shift;
    my $str   = shift;
    if (my @parts = $class -&gt; _dec_str_to_flt_lib_parts($str)) {
        return $class -&gt; _flt_lib_parts_to_dec_str(@parts);
    }
    return;
}

sub _flt_lib_parts_to_flt_str {
    my $class = shift;
    my @parts = @_;
    return $parts[0] . $LIB -&gt; _str($parts[1])
      . 'e' . $parts[2] . $LIB -&gt; _str($parts[3]);
}

sub _flt_lib_parts_to_dec_str {
    my $class = shift;
    my @parts = @_;

    # The number is an integer iff the exponent is non-negative.

    if ($parts[2] eq '+') {
        my $str = $parts[0]
          . $LIB -&gt; _str($LIB -&gt; _lsft($parts[1], $parts[3], 10));
        return $str;
    }

    # If it is not an integer, add a decimal point.

    else {
        my $mant     = $LIB -&gt; _str($parts[1]);
        my $mant_len = CORE::length($mant);
        my $expo     = $LIB -&gt; _num($parts[3]);
        my $len_cmp = $mant_len &lt;=&gt; $expo;
        if ($len_cmp &lt;= 0) {
            return $parts[0] . '0.' . '0' x ($expo - $mant_len) . $mant;
        } else {
            substr $mant, $mant_len - $expo, 0, '.';
            return $parts[0] . $mant;
        }
    }
}

# Takes four arguments, the sign of the significand, the absolute value of the
# significand as a libray thingy, the sign of the exponent, and the absolute
# value of the exponent as a library thingy, and returns three parts: the sign
# of the rational number, the absolute value of the numerator as a libray
# thingy, and the absolute value of the denominator as a library thingy.
#
# For example, to convert data representing the value "+12e-2", then
#
#   $sm = "+";
#   $m  = $LIB -&gt; _new("12");
#   $se = "-";
#   $e  = $LIB -&gt; _new("2");
#   ($sr, $n, $d) = $class -&gt; _flt_lib_parts_to_rat_lib_parts($sm, $m, $se, $e);
#
# returns data representing the same value written as the fraction "+3/25"
#
#   $sr = "+"
#   $n  = $LIB -&gt; _new("3");
#   $d  = $LIB -&gt; _new("12");

sub _flt_lib_parts_to_rat_lib_parts {
    my $self = shift;
    my ($msgn, $mabs, $esgn, $eabs) = @_;

    if ($esgn eq '-') {                 # "12e-2" -&gt; "12/100" -&gt; "3/25"
        my $num_lib = $LIB -&gt; _copy($mabs);
        my $den_lib = $LIB -&gt; _1ex($LIB -&gt; _num($eabs));
        my $gcd_lib = $LIB -&gt; _gcd($LIB -&gt; _copy($num_lib), $den_lib);
        $num_lib = $LIB -&gt; _div($LIB -&gt; _copy($num_lib), $gcd_lib);
        $den_lib = $LIB -&gt; _div($den_lib, $gcd_lib);
        return $msgn, $num_lib, $den_lib;
    }

    elsif (!$LIB -&gt; _is_zero($eabs)) {  # "12e+2" -&gt; "1200" -&gt; "1200/1"
        return $msgn, $LIB -&gt; _lsft($LIB -&gt; _copy($mabs), $eabs, 10),
                      $LIB -&gt; _one();
    }

    else {                              # "12e+0" -&gt; "12" -&gt; "12/1"
        return $msgn, $mabs, $LIB -&gt; _one();
    }
}

# Add the function _register_callback() to Math::BigInt. It is provided for
# backwards compabibility so that old version of Math::BigRat etc. don't
# complain about missing it.

sub _register_callback { }

###############################################################################
# this method returns 0 if the object can be modified, or 1 if not.
# We use a fast constant sub() here, to avoid costly calls. Subclasses
# may override it with special code (f.i. Math::BigInt::Constant does so)

sub modify () { 0; }

1;

__END__

=pod

=head1 NAME

Math::BigInt - arbitrary size integer math package

=head1 SYNOPSIS

  use Math::BigInt;

  # or make it faster with huge numbers: install (optional)
  # Math::BigInt::GMP and always use (it falls back to
  # pure Perl if the GMP library is not installed):
  # (See also the L&lt;MATH LIBRARY&gt; section!)

  # to warn if Math::BigInt::GMP cannot be found, use
  use Math::BigInt lib =&gt; 'GMP';

  # to suppress the warning if Math::BigInt::GMP cannot be found, use
  # use Math::BigInt try =&gt; 'GMP';

  # to die if Math::BigInt::GMP cannot be found, use
  # use Math::BigInt only =&gt; 'GMP';

  # Configuration methods (may be used as class methods and instance methods)

  Math::BigInt-&gt;accuracy();     # get class accuracy
  Math::BigInt-&gt;accuracy($n);   # set class accuracy
  Math::BigInt-&gt;precision();    # get class precision
  Math::BigInt-&gt;precision($n);  # set class precision
  Math::BigInt-&gt;round_mode();   # get class rounding mode
  Math::BigInt-&gt;round_mode($m); # set global round mode, must be one of
                                # 'even', 'odd', '+inf', '-inf', 'zero',
                                # 'trunc', or 'common'
  Math::BigInt-&gt;div_scale($n);  # set fallback accuracy
  Math::BigInt-&gt;trap_inf($b);   # trap infinities or not
  Math::BigInt-&gt;trap_nan($b);   # trap NaNs or not
  Math::BigInt-&gt;config();       # return hash with configuration

  # Constructor methods (when the class methods below are used as instance
  # methods, the value is assigned the invocand)

  $x = Math::BigInt-&gt;new($str);             # defaults to 0
  $x = Math::BigInt-&gt;new('0x123');          # from hexadecimal
  $x = Math::BigInt-&gt;new('0b101');          # from binary
  $x = Math::BigInt-&gt;from_hex('cafe');      # from hexadecimal
  $x = Math::BigInt-&gt;from_oct('377');       # from octal
  $x = Math::BigInt-&gt;from_bin('1101');      # from binary
  $x = Math::BigInt-&gt;from_base('why', 36);  # from any base
  $x = Math::BigInt-&gt;from_base_num([1, 0], 2);  # from any base
  $x = Math::BigInt-&gt;bzero();               # create a +0
  $x = Math::BigInt-&gt;bone();                # create a +1
  $x = Math::BigInt-&gt;bone('-');             # create a -1
  $x = Math::BigInt-&gt;binf();                # create a +inf
  $x = Math::BigInt-&gt;binf('-');             # create a -inf
  $x = Math::BigInt-&gt;bnan();                # create a Not-A-Number
  $x = Math::BigInt-&gt;bpi();                 # returns pi

  $y = $x-&gt;copy();        # make a copy (unlike $y = $x)
  $y = $x-&gt;as_int();      # return as a Math::BigInt
  $y = $x-&gt;as_float();    # return as a Math::BigFloat
  $y = $x-&gt;as_rat();      # return as a Math::BigRat

  # Boolean methods (these don't modify the invocand)

  $x-&gt;is_zero();          # if $x is 0
  $x-&gt;is_one();           # if $x is +1
  $x-&gt;is_one("+");        # ditto
  $x-&gt;is_one("-");        # if $x is -1
  $x-&gt;is_inf();           # if $x is +inf or -inf
  $x-&gt;is_inf("+");        # if $x is +inf
  $x-&gt;is_inf("-");        # if $x is -inf
  $x-&gt;is_nan();           # if $x is NaN

  $x-&gt;is_positive();      # if $x &gt; 0
  $x-&gt;is_pos();           # ditto
  $x-&gt;is_negative();      # if $x &lt; 0
  $x-&gt;is_neg();           # ditto

  $x-&gt;is_odd();           # if $x is odd
  $x-&gt;is_even();          # if $x is even
  $x-&gt;is_int();           # if $x is an integer

  # Comparison methods

  $x-&gt;bcmp($y);           # compare numbers (undef, &lt; 0, == 0, &gt; 0)
  $x-&gt;bacmp($y);          # compare absolutely (undef, &lt; 0, == 0, &gt; 0)
  $x-&gt;beq($y);            # true if and only if $x == $y
  $x-&gt;bne($y);            # true if and only if $x != $y
  $x-&gt;blt($y);            # true if and only if $x &lt; $y
  $x-&gt;ble($y);            # true if and only if $x &lt;= $y
  $x-&gt;bgt($y);            # true if and only if $x &gt; $y
  $x-&gt;bge($y);            # true if and only if $x &gt;= $y

  # Arithmetic methods

  $x-&gt;bneg();             # negation
  $x-&gt;babs();             # absolute value
  $x-&gt;bsgn();             # sign function (-1, 0, 1, or NaN)
  $x-&gt;bnorm();            # normalize (no-op)
  $x-&gt;binc();             # increment $x by 1
  $x-&gt;bdec();             # decrement $x by 1
  $x-&gt;badd($y);           # addition (add $y to $x)
  $x-&gt;bsub($y);           # subtraction (subtract $y from $x)
  $x-&gt;bmul($y);           # multiplication (multiply $x by $y)
  $x-&gt;bmuladd($y,$z);     # $x = $x * $y + $z
  $x-&gt;bdiv($y);           # division (floored), set $x to quotient
                          # return (quo,rem) or quo if scalar
  $x-&gt;btdiv($y);          # division (truncated), set $x to quotient
                          # return (quo,rem) or quo if scalar
  $x-&gt;bmod($y);           # modulus (x % y)
  $x-&gt;btmod($y);          # modulus (truncated)
  $x-&gt;bmodinv($mod);      # modular multiplicative inverse
  $x-&gt;bmodpow($y,$mod);   # modular exponentiation (($x ** $y) % $mod)
  $x-&gt;binv()              # inverse (1/$x)
  $x-&gt;bpow($y);           # power of arguments (x ** y)
  $x-&gt;blog();             # logarithm of $x to base e (Euler's number)
  $x-&gt;blog($base);        # logarithm of $x to base $base (e.g., base 2)
  $x-&gt;bexp();             # calculate e ** $x where e is Euler's number
  $x-&gt;bilog2();           # log2($x) rounded down to nearest int
  $x-&gt;bilog10();          # log10($x) rounded down to nearest int
  $x-&gt;bclog2();           # log2($x) rounded up to nearest int
  $x-&gt;bclog10();          # log19($x) rounded up to nearest int
  $x-&gt;bnok($y);           # x over y (binomial coefficient n over k)
  $x-&gt;buparrow($n, $y);   # Knuth's up-arrow notation
  $x-&gt;backermann($y);     # the Ackermann function
  $x-&gt;bsin();             # sine
  $x-&gt;bcos();             # cosine
  $x-&gt;batan();            # inverse tangent
  $x-&gt;batan2($y);         # two-argument inverse tangent
  $x-&gt;bsqrt();            # calculate square root
  $x-&gt;broot($y);          # $y'th root of $x (e.g. $y == 3 =&gt; cubic root)
  $x-&gt;bfac();             # factorial of $x (1*2*3*4*..$x)
  $x-&gt;bdfac();            # double factorial of $x ($x*($x-2)*($x-4)*...)
  $x-&gt;btfac();            # triple factorial of $x ($x*($x-3)*($x-6)*...)
  $x-&gt;bmfac($k);          # $k'th multi-factorial of $x ($x*($x-$k)*...)

  $x-&gt;blsft($n);          # left shift $n places in base 2
  $x-&gt;blsft($n,$b);       # left shift $n places in base $b
                          # returns (quo,rem) or quo (scalar context)
  $x-&gt;brsft($n);          # right shift $n places in base 2
  $x-&gt;brsft($n,$b);       # right shift $n places in base $b
                          # returns (quo,rem) or quo (scalar context)

  # Bitwise methods

  $x-&gt;bblsft($y);         # bitwise left shift
  $x-&gt;bbrsft($y);         # bitwise right shift
  $x-&gt;band($y);           # bitwise and
  $x-&gt;bior($y);           # bitwise inclusive or
  $x-&gt;bxor($y);           # bitwise exclusive or
  $x-&gt;bnot();             # bitwise not (two's complement)

  # Rounding methods
  $x-&gt;round($A,$P,$mode); # round to accuracy or precision using
                          # rounding mode $mode
  $x-&gt;bround($n);         # accuracy: preserve $n digits
  $x-&gt;bfround($n);        # $n &gt; 0: round to $nth digit left of dec. point
                          # $n &lt; 0: round to $nth digit right of dec. point
  $x-&gt;bfloor();           # round towards minus infinity
  $x-&gt;bceil();            # round towards plus infinity
  $x-&gt;bint();             # round towards zero

  # Other mathematical methods

  $x-&gt;bgcd($y);            # greatest common divisor
  $x-&gt;blcm($y);            # least common multiple

  # Object property methods (do not modify the invocand)

  $x-&gt;sign();              # the sign, either +, - or NaN
  $x-&gt;digit($n);           # the nth digit, counting from the right
  $x-&gt;digit(-$n);          # the nth digit, counting from the left
  $x-&gt;length();            # return number of digits in number
  ($xl,$f) = $x-&gt;length(); # length of number and length of fraction
                           # part, latter is always 0 digits long
                           # for Math::BigInt objects
  $x-&gt;mantissa();          # return (signed) mantissa as a Math::BigInt
  $x-&gt;exponent();          # return exponent as a Math::BigInt
  $x-&gt;parts();             # return (mantissa,exponent) as a Math::BigInt
  $x-&gt;sparts();            # mantissa and exponent (as integers)
  $x-&gt;nparts();            # mantissa and exponent (normalised)
  $x-&gt;eparts();            # mantissa and exponent (engineering notation)
  $x-&gt;dparts();            # integer and fraction part
  $x-&gt;fparts();            # numerator and denominator
  $x-&gt;numerator();         # numerator
  $x-&gt;denominator();       # denominator

  # Conversion methods (do not modify the invocand)

  $x-&gt;bstr();         # decimal notation, possibly zero padded
  $x-&gt;bsstr();        # string in scientific notation with integers
  $x-&gt;bnstr();        # string in normalized notation
  $x-&gt;bestr();        # string in engineering notation
  $x-&gt;bfstr();        # string in fractional notation

  $x-&gt;to_hex();       # as signed hexadecimal string
  $x-&gt;to_bin();       # as signed binary string
  $x-&gt;to_oct();       # as signed octal string
  $x-&gt;to_bytes();     # as byte string
  $x-&gt;to_base($b);    # as string in any base
  $x-&gt;to_base_num($b);   # as array of integers in any base

  $x-&gt;as_hex();       # as signed hexadecimal string with prefixed 0x
  $x-&gt;as_bin();       # as signed binary string with prefixed 0b
  $x-&gt;as_oct();       # as signed octal string with prefixed 0

  # Other conversion methods

  $x-&gt;numify();           # return as scalar (might overflow or underflow)

=head1 DESCRIPTION

Math::BigInt provides support for arbitrary precision integers. Overloading is
also provided for Perl operators.

=head2 Input

Input values to these routines may be any scalar number or string that looks
like a number and represents an integer. Anything that is accepted by Perl as a
literal numeric constant should be accepted by this module, except that finite
non-integers return NaN.

=over

=item *

Leading and trailing whitespace is ignored.

=item *

Leading zeros are ignored, except for floating point numbers with a binary
exponent, in which case the number is interpreted as an octal floating point
number. For example, "01.4p+0" gives 1.5, "00.4p+0" gives 0.5, but "0.4p+0"
gives a NaN. And while "0377" gives 255, "0377p0" gives 255.

=item *

If the string has a "0x" or "0X" prefix, it is interpreted as a hexadecimal
number.

=item *

If the string has a "0o" or "0O" prefix, it is interpreted as an octal number. A
floating point literal with a "0" prefix is also interpreted as an octal number.

=item *

If the string has a "0b" or "0B" prefix, it is interpreted as a binary number.

=item *

Underline characters are allowed in the same way as they are allowed in literal
numerical constants.

=item *

If the string can not be interpreted, or does not represent a finite integer,
NaN is returned.

=item *

For hexadecimal, octal, and binary floating point numbers, the exponent must be
separated from the significand (mantissa) by the letter "p" or "P", not "e" or
"E" as with decimal numbers.

=back

Some examples of valid string input

    Input string                Resulting value

    123                         123
    1.23e2                      123
    12300e-2                    123

    67_538_754                  67538754
    -4_5_6.7_8_9e+0_1_0         -4567890000000

    0x13a                       314
    0x13ap0                     314
    0x1.3ap+8                   314
    0x0.00013ap+24              314
    0x13a000p-12                314

    0o472                       314
    0o1.164p+8                  314
    0o0.0001164p+20             314
    0o1164000p-10               314

    0472                        472     Note!
    01.164p+8                   314
    00.0001164p+20              314
    01164000p-10                314

    0b100111010                 314
    0b1.0011101p+8              314
    0b0.00010011101p+12         314
    0b100111010000p-3           314

Input given as scalar numbers might lose precision. Quote your input to ensure
that no digits are lost:

    $x = Math::BigInt-&gt;new( 56789012345678901234 );   # bad
    $x = Math::BigInt-&gt;new('56789012345678901234');   # good

Currently, C&lt;Math::BigInt-&gt;new()&gt; (no input argument) and
C&lt;Math::BigInt-&gt;new("")&gt; return 0. This might change in the future, so always
use the following explicit forms to get a zero:

    $zero = Math::BigInt-&gt;bzero();

=head2 Output

Output values are usually Math::BigInt objects.

Boolean operators C&lt;is_zero()&gt;, C&lt;is_one()&gt;, C&lt;is_inf()&gt;, etc. return true or
false.

Comparison operators C&lt;bcmp()&gt; and C&lt;bacmp()&gt;) return -1, 0, 1, or
undef.

=head1 METHODS

=head2 Configuration methods

Each of the methods below (except config(), accuracy() and precision()) accepts
three additional parameters. These arguments C&lt;$A&gt;, C&lt;$P&gt; and C&lt;$R&gt; are
C&lt;accuracy&gt;, C&lt;precision&gt; and C&lt;round_mode&gt;. Please see the section about
L&lt;/ACCURACY and PRECISION&gt; for more information.

Setting a class variable effects all object instance that are created
afterwards.

=over

=item accuracy()

    Math::BigInt-&gt;accuracy(5);      # set class accuracy
    $x-&gt;accuracy(5);                # set instance accuracy

    $A = Math::BigInt-&gt;accuracy();  # get class accuracy
    $A = $x-&gt;accuracy();            # get instance accuracy

Set or get the accuracy, i.e., the number of significant digits. The accuracy
must be an integer. If the accuracy is set to C&lt;undef&gt;, no rounding is done.

Alternatively, one can round the results explicitly using one of L&lt;/round()&gt;,
L&lt;/bround()&gt; or L&lt;/bfround()&gt; or by passing the desired accuracy to the method
as an additional parameter:

    my $x = Math::BigInt-&gt;new(30000);
    my $y = Math::BigInt-&gt;new(7);
    print scalar $x-&gt;copy()-&gt;bdiv($y, 2);               # prints 4300
    print scalar $x-&gt;copy()-&gt;bdiv($y)-&gt;bround(2);       # prints 4300

Please see the section about L&lt;/ACCURACY and PRECISION&gt; for further details.

    $y = Math::BigInt-&gt;new(1234567);    # $y is not rounded
    Math::BigInt-&gt;accuracy(4);          # set class accuracy to 4
    $x = Math::BigInt-&gt;new(1234567);    # $x is rounded automatically
    print "$x $y";                      # prints "1235000 1234567"

    print $x-&gt;accuracy();       # prints "4"
    print $y-&gt;accuracy();       # also prints "4", since
                                #   class accuracy is 4

    Math::BigInt-&gt;accuracy(5);  # set class accuracy to 5
    print $x-&gt;accuracy();       # prints "4", since instance
                                #   accuracy is 4
    print $y-&gt;accuracy();       # prints "5", since no instance
                                #   accuracy, and class accuracy is 5

Note: Each class has it's own globals separated from Math::BigInt, but it is
possible to subclass Math::BigInt and make the globals of the subclass aliases
to the ones from Math::BigInt.

=item precision()

    Math::BigInt-&gt;precision(-2);     # set class precision
    $x-&gt;precision(-2);               # set instance precision

    $P = Math::BigInt-&gt;precision();  # get class precision
    $P = $x-&gt;precision();            # get instance precision

Set or get the precision, i.e., the place to round relative to the decimal
point. The precision must be a integer. Setting the precision to $P means that
each number is rounded up or down, depending on the rounding mode, to the
nearest multiple of 10**$P. If the precision is set to C&lt;undef&gt;, no rounding is
done.

You might want to use L&lt;/accuracy()&gt; instead. With L&lt;/accuracy()&gt; you set the
number of digits each result should have, with L&lt;/precision()&gt; you set the
place where to round.

Please see the section about L&lt;/ACCURACY and PRECISION&gt; for further details.

    $y = Math::BigInt-&gt;new(1234567);    # $y is not rounded
    Math::BigInt-&gt;precision(4);         # set class precision to 4
    $x = Math::BigInt-&gt;new(1234567);    # $x is rounded automatically
    print $x;                           # prints "1230000"

Note: Each class has its own globals separated from Math::BigInt, but it is
possible to subclass Math::BigInt and make the globals of the subclass aliases
to the ones from Math::BigInt.

=item div_scale()

Set/get the fallback accuracy. This is the accuracy used when neither accuracy
nor precision is set explicitly. It is used when a computation might otherwise
attempt to return an infinite number of digits.

=item round_mode()

Set/get the rounding mode.

=item trap_inf()

Set/get the value determining whether infinities should cause a fatal error or
not.

=item trap_nan()

Set/get the value determining whether NaNs should cause a fatal error or not.

=item upgrade()

Set/get the class for upgrading. When a computation might result in a
non-integer, the operands are upgraded to this class. This is used for instance
by L&lt;bignum&gt;. The default is C&lt;undef&gt;, i.e., no upgrading.

    # with no upgrading
    $x = Math::BigInt-&gt;new(12);
    $y = Math::BigInt-&gt;new(5);
    print $x / $y, "\n";                # 2 as a Math::BigInt

    # with upgrading to Math::BigFloat
    Math::BigInt -&gt; upgrade("Math::BigFloat");
    print $x / $y, "\n";                # 2.4 as a Math::BigFloat

    # with upgrading to Math::BigRat (after loading Math::BigRat)
    Math::BigInt -&gt; upgrade("Math::BigRat");
    print $x / $y, "\n";                # 12/5 as a Math::BigRat

=item downgrade()

Set/get the class for downgrading. The default is C&lt;undef&gt;, i.e., no
downgrading. Downgrading is not done by Math::BigInt.

=item modify()

    $x-&gt;modify('bpowd');

This method returns 0 if the object can be modified with the given operation,
or 1 if not.

This is used for instance by L&lt;Math::BigInt::Constant&gt;.

=item config()

    Math::BigInt-&gt;config("trap_nan" =&gt; 1);      # set
    $accu = Math::BigInt-&gt;config("accuracy");   # get

Set or get class variables. Read-only parameters are marked as RO. Read-write
parameters are marked as RW. The following parameters are supported.

    Parameter       RO/RW   Description
                            Example
    ============================================================
    lib             RO      Name of the math backend library
                            Math::BigInt::Calc
    lib_version     RO      Version of the math backend library
                            0.30
    class           RO      The class of config you just called
                            Math::BigRat
    version         RO      version number of the class you used
                            0.10
    upgrade         RW      To which class numbers are upgraded
                            undef
    downgrade       RW      To which class numbers are downgraded
                            undef
    precision       RW      Global precision
                            undef
    accuracy        RW      Global accuracy
                            undef
    round_mode      RW      Global round mode
                            even
    div_scale       RW      Fallback accuracy for division etc.
                            40
    trap_nan        RW      Trap NaNs
                            undef
    trap_inf        RW      Trap +inf/-inf
                            undef

=back

=head2 Constructor methods

=over

=item new()

    $x = Math::BigInt-&gt;new($str,$A,$P,$R);

Creates a new Math::BigInt object from a scalar or another Math::BigInt object.
The input is accepted as decimal, hexadecimal (with leading '0x'), octal (with
leading ('0o') or binary (with leading '0b').

See L&lt;/Input&gt; for more info on accepted input formats.

=item from_dec()

    $x = Math::BigInt-&gt;from_dec("314159");    # input is decimal

Interpret input as a decimal. It is equivalent to new(), but does not accept
anything but strings representing finite, decimal numbers.

=item from_hex()

    $x = Math::BigInt-&gt;from_hex("0xcafe");    # input is hexadecimal

Interpret input as a hexadecimal string. A "0x" or "x" prefix is optional. A
single underscore character may be placed right after the prefix, if present,
or between any two digits. If the input is invalid, a NaN is returned.

=item from_oct()

    $x = Math::BigInt-&gt;from_oct("0775");      # input is octal

Interpret the input as an octal string and return the corresponding value. A
"0" (zero) prefix is optional. A single underscore character may be placed
right after the prefix, if present, or between any two digits. If the input is
invalid, a NaN is returned.

=item from_bin()

    $x = Math::BigInt-&gt;from_bin("0b10011");   # input is binary

Interpret the input as a binary string. A "0b" or "b" prefix is optional. A
single underscore character may be placed right after the prefix, if present,
or between any two digits. If the input is invalid, a NaN is returned.

=item from_bytes()

    $x = Math::BigInt-&gt;from_bytes("\xf3\x6b");  # $x = 62315

Interpret the input as a byte string, assuming big endian byte order. The
output is always a non-negative, finite integer.

In some special cases, from_bytes() matches the conversion done by unpack():

    $b = "\x4e";                             # one char byte string
    $x = Math::BigInt-&gt;from_bytes($b);       # = 78
    $y = unpack "C", $b;                     # ditto, but scalar

    $b = "\xf3\x6b";                         # two char byte string
    $x = Math::BigInt-&gt;from_bytes($b);       # = 62315
    $y = unpack "S&gt;", $b;                    # ditto, but scalar

    $b = "\x2d\xe0\x49\xad";                 # four char byte string
    $x = Math::BigInt-&gt;from_bytes($b);       # = 769673645
    $y = unpack "L&gt;", $b;                    # ditto, but scalar

    $b = "\x2d\xe0\x49\xad\x2d\xe0\x49\xad"; # eight char byte string
    $x = Math::BigInt-&gt;from_bytes($b);       # = 3305723134637787565
    $y = unpack "Q&gt;", $b;                    # ditto, but scalar

=item from_base()

Given a string, a base, and an optional collation sequence, interpret the
string as a number in the given base. The collation sequence describes the
value of each character in the string.

If a collation sequence is not given, a default collation sequence is used. If
the base is less than or equal to 36, the collation sequence is the string
consisting of the 36 characters "0" to "9" and "A" to "Z". In this case, the
letter case in the input is ignored. If the base is greater than 36, and
smaller than or equal to 62, the collation sequence is the string consisting of
the 62 characters "0" to "9", "A" to "Z", and "a" to "z". A base larger than 62
requires the collation sequence to be specified explicitly.

These examples show standard binary, octal, and hexadecimal conversion. All
cases return 250.

    $x = Math::BigInt-&gt;from_base("11111010", 2);
    $x = Math::BigInt-&gt;from_base("372", 8);
    $x = Math::BigInt-&gt;from_base("fa", 16);

When the base is less than or equal to 36, and no collation sequence is given,
the letter case is ignored, so both of these also return 250:

    $x = Math::BigInt-&gt;from_base("6Y", 16);
    $x = Math::BigInt-&gt;from_base("6y", 16);

When the base greater than 36, and no collation sequence is given, the default
collation sequence contains both uppercase and lowercase letters, so
the letter case in the input is not ignored:

    $x = Math::BigInt-&gt;from_base("6S", 37);         # $x is 250
    $x = Math::BigInt-&gt;from_base("6s", 37);         # $x is 276
    $x = Math::BigInt-&gt;from_base("121", 3);         # $x is 16
    $x = Math::BigInt-&gt;from_base("XYZ", 36);        # $x is 44027
    $x = Math::BigInt-&gt;from_base("Why", 42);        # $x is 58314

The collation sequence can be any set of unique characters. These two cases
are equivalent

    $x = Math::BigInt-&gt;from_base("100", 2, "01");   # $x is 4
    $x = Math::BigInt-&gt;from_base("|--", 2, "-|");   # $x is 4

=item from_base_num()

Returns a new Math::BigInt object given an array of values and a base. This
method is equivalent to C&lt;from_base()&gt;, but works on numbers in an array rather
than characters in a string. Unlike C&lt;from_base()&gt;, all input values may be
arbitrarily large.

    $x = Math::BigInt-&gt;from_base_num([1, 1, 0, 1], 2)     # $x is 13
    $x = Math::BigInt-&gt;from_base_num([3, 125, 39], 128)   # $x is 65191

=item bzero()

    $x = Math::BigInt-&gt;bzero();
    $x-&gt;bzero();

Returns a new Math::BigInt object representing zero. If used as an instance
method, assigns the value to the invocand.

=item bone()

    $x = Math::BigInt-&gt;bone();          # +1
    $x = Math::BigInt-&gt;bone("+");       # +1
    $x = Math::BigInt-&gt;bone("-");       # -1
    $x-&gt;bone();                         # +1
    $x-&gt;bone("+");                      # +1
    $x-&gt;bone('-');                      # -1

Creates a new Math::BigInt object representing one. The optional argument is
either '-' or '+', indicating whether you want plus one or minus one. If used
as an instance method, assigns the value to the invocand.

=item binf()

    $x = Math::BigInt-&gt;binf($sign);

Creates a new Math::BigInt object representing infinity. The optional argument
is either '-' or '+', indicating whether you want infinity or minus infinity.
If used as an instance method, assigns the value to the invocand.

    $x-&gt;binf();
    $x-&gt;binf('-');

=item bnan()

    $x = Math::BigInt-&gt;bnan();

Creates a new Math::BigInt object representing NaN (Not A Number). If used as
an instance method, assigns the value to the invocand.

    $x-&gt;bnan();

=item bpi()

    $x = Math::BigInt-&gt;bpi(100);        # 3
    $x-&gt;bpi(100);                       # 3

Creates a new Math::BigInt object representing PI. If used as an instance
method, assigns the value to the invocand. With Math::BigInt this always
returns 3.

If upgrading is in effect, returns PI, rounded to N digits with the current
rounding mode:

    use Math::BigFloat;
    use Math::BigInt upgrade =&gt; "Math::BigFloat";
    print Math::BigInt-&gt;bpi(3), "\n";           # 3.14
    print Math::BigInt-&gt;bpi(100), "\n";         # 3.1415....

=item copy()

    $x-&gt;copy();         # make a true copy of $x (unlike $y = $x)

=item as_int()

=item as_number()

These methods are called when Math::BigInt encounters an object it doesn't know
how to handle. For instance, assume $x is a Math::BigInt, or subclass thereof,
and $y is defined, but not a Math::BigInt, or subclass thereof. If you do

    $x -&gt; badd($y);

$y needs to be converted into an object that $x can deal with. This is done by
first checking if $y is something that $x might be upgraded to. If that is the
case, no further attempts are made. The next is to see if $y supports the
method C&lt;as_int()&gt;. If it does, C&lt;as_int()&gt; is called, but if it doesn't, the
next thing is to see if $y supports the method C&lt;as_number()&gt;. If it does,
C&lt;as_number()&gt; is called. The method C&lt;as_int()&gt; (and C&lt;as_number()&gt;) is
expected to return either an object that has the same class as $x, a subclass
thereof, or a string that C&lt;ref($x)-E&lt;gt&gt;new()&gt; can parse to create an object.

C&lt;as_number()&gt; is an alias to C&lt;as_int()&gt;. C&lt;as_number&gt; was introduced in
v1.22, while C&lt;as_int()&gt; was introduced in v1.68.

In Math::BigInt, C&lt;as_int()&gt; has the same effect as C&lt;copy()&gt;.

=item as_float()

Return the argument as a Math::BigFloat object.

=item as_rat()

Return the argument as a Math::BigRat object.

=back

=head2 Boolean methods

None of these methods modify the invocand object.

=over

=item is_zero()

    $x-&gt;is_zero();              # true if $x is 0

Returns true if the invocand is zero and false otherwise.

=item is_one( [ SIGN ])

    $x-&gt;is_one();               # true if $x is +1
    $x-&gt;is_one("+");            # ditto
    $x-&gt;is_one("-");            # true if $x is -1

Returns true if the invocand is one and false otherwise.

=item is_finite()

    $x-&gt;is_finite();    # true if $x is not +inf, -inf or NaN

Returns true if the invocand is a finite number, i.e., it is neither +inf,
-inf, nor NaN.

=item is_inf( [ SIGN ] )

    $x-&gt;is_inf();               # true if $x is +inf
    $x-&gt;is_inf("+");            # ditto
    $x-&gt;is_inf("-");            # true if $x is -inf

Returns true if the invocand is infinite and false otherwise.

=item is_nan()

    $x-&gt;is_nan();               # true if $x is NaN

=item is_positive()

=item is_pos()

    $x-&gt;is_positive();          # true if &gt; 0
    $x-&gt;is_pos();               # ditto

Returns true if the invocand is positive and false otherwise. A C&lt;NaN&gt; is
neither positive nor negative.

=item is_negative()

=item is_neg()

    $x-&gt;is_negative();          # true if &lt; 0
    $x-&gt;is_neg();               # ditto

Returns true if the invocand is negative and false otherwise. A C&lt;NaN&gt; is
neither positive nor negative.

=item is_non_positive()

    $x-&gt;is_non_positive();      # true if &lt;= 0

Returns true if the invocand is negative or zero.

=item is_non_negative()

    $x-&gt;is_non_negative();      # true if &gt;= 0

Returns true if the invocand is positive or zero.

=item is_odd()

    $x-&gt;is_odd();               # true if odd, false for even

Returns true if the invocand is odd and false otherwise. C&lt;NaN&gt;, C&lt;+inf&gt;, and
C&lt;-inf&gt; are neither odd nor even.

=item is_even()

    $x-&gt;is_even();              # true if $x is even

Returns true if the invocand is even and false otherwise. C&lt;NaN&gt;, C&lt;+inf&gt;,
C&lt;-inf&gt; are not integers and are neither odd nor even.

=item is_int()

    $x-&gt;is_int();               # true if $x is an integer

Returns true if the invocand is an integer and false otherwise. C&lt;NaN&gt;,
C&lt;+inf&gt;, C&lt;-inf&gt; are not integers.

=back

=head2 Comparison methods

None of these methods modify the invocand object. Note that a C&lt;NaN&gt; is neither
less than, greater than, or equal to anything else, even a C&lt;NaN&gt;.

=over

=item bcmp()

    $x-&gt;bcmp($y);

Returns -1, 0, 1 depending on whether $x is less than, equal to, or grater than
$y. Returns undef if any operand is a NaN.

=item bacmp()

    $x-&gt;bacmp($y);

Returns -1, 0, 1 depending on whether the absolute value of $x is less than,
equal to, or grater than the absolute value of $y. Returns undef if any operand
is a NaN.

=item beq()

    $x -&gt; beq($y);

Returns true if and only if $x is equal to $y, and false otherwise.

=item bne()

    $x -&gt; bne($y);

Returns true if and only if $x is not equal to $y, and false otherwise.

=item blt()

    $x -&gt; blt($y);

Returns true if and only if $x is equal to $y, and false otherwise.

=item ble()

    $x -&gt; ble($y);

Returns true if and only if $x is less than or equal to $y, and false
otherwise.

=item bgt()

    $x -&gt; bgt($y);

Returns true if and only if $x is greater than $y, and false otherwise.

=item bge()

    $x -&gt; bge($y);

Returns true if and only if $x is greater than or equal to $y, and false
otherwise.

=back

=head2 Arithmetic methods

These methods modify the invocand object and returns it.

=over

=item bneg()

    $x-&gt;bneg();

Negate the number, e.g. change the sign between '+' and '-', or between '+inf'
and '-inf', respectively. Does nothing for NaN or zero.

=item babs()

    $x-&gt;babs();

Set the number to its absolute value, e.g. change the sign from '-' to '+'
and from '-inf' to '+inf', respectively. Does nothing for NaN or positive
numbers.

=item bsgn()

    $x-&gt;bsgn();

Signum function. Set the number to -1, 0, or 1, depending on whether the
number is negative, zero, or positive, respectively. Does not modify NaNs.

=item bnorm()

    $x-&gt;bnorm();                        # normalize (no-op)

Normalize the number. This is a no-op and is provided only for backwards
compatibility.

=item binc()

    $x-&gt;binc();                 # increment x by 1

=item bdec()

    $x-&gt;bdec();                 # decrement x by 1

=item badd()

    $x-&gt;badd($y);               # addition (add $y to $x)

=item bsub()

    $x-&gt;bsub($y);               # subtraction (subtract $y from $x)

=item bmul()

    $x-&gt;bmul($y);               # multiplication (multiply $x by $y)

=item bmuladd()

    $x-&gt;bmuladd($y,$z);

Multiply $x by $y, and then add $z to the result,

This method was added in v1.87 of Math::BigInt (June 2007).

=item binv()

    $x-&gt;binv();

Invert the value of $x, i.e., compute 1/$x.

=item bdiv()

    $x-&gt;bdiv($y);               # divide, set $x to quotient

Divides $x by $y by doing floored division (F-division), where the quotient is
the floored (rounded towards negative infinity) quotient of the two operands.
In list context, returns the quotient and the remainder. The remainder is
either zero or has the same sign as the second operand. In scalar context, only
the quotient is returned.

The quotient is always the greatest integer less than or equal to the
real-valued quotient of the two operands, and the remainder (when it is
non-zero) always has the same sign as the second operand; so, for example,

      1 /  4  =&gt; ( 0,  1)
      1 / -4  =&gt; (-1, -3)
     -3 /  4  =&gt; (-1,  1)
     -3 / -4  =&gt; ( 0, -3)
    -11 /  2  =&gt; (-5,  1)
     11 / -2  =&gt; (-5, -1)

The behavior of the overloaded operator % agrees with the behavior of Perl's
built-in % operator (as documented in the perlop manpage), and the equation

    $x == ($x / $y) * $y + ($x % $y)

holds true for any finite $x and finite, non-zero $y.

Perl's "use integer" might change the behaviour of % and / for scalars. This is
because under 'use integer' Perl does what the underlying C library thinks is
right, and this varies. However, "use integer" does not change the way things
are done with Math::BigInt objects.

=item btdiv()

    $x-&gt;btdiv($y);              # divide, set $x to quotient

Divides $x by $y by doing truncated division (T-division), where quotient is
the truncated (rouneded towards zero) quotient of the two operands. In list
context, returns the quotient and the remainder. The remainder is either zero
or has the same sign as the first operand. In scalar context, only the quotient
is returned.

=item bmod()

    $x-&gt;bmod($y);               # modulus (x % y)

Returns $x modulo $y, i.e., the remainder after floored division (F-division).
This method is like Perl's % operator. See L&lt;/bdiv()&gt;.

=item btmod()

    $x-&gt;btmod($y);              # modulus

Returns the remainer after truncated division (T-division). See L&lt;/btdiv()&gt;.

=item bmodinv()

    $x-&gt;bmodinv($mod);          # modular multiplicative inverse

Returns the multiplicative inverse of C&lt;$x&gt; modulo C&lt;$mod&gt;. If

    $y = $x -&gt; copy() -&gt; bmodinv($mod)

then C&lt;$y&gt; is the number closest to zero, and with the same sign as C&lt;$mod&gt;,
satisfying

    ($x * $y) % $mod = 1 % $mod

If C&lt;$x&gt; and C&lt;$y&gt; are non-zero, they must be relative primes, i.e.,
C&lt;bgcd($y, $mod)==1&gt;. 'C&lt;NaN&gt;' is returned when no modular multiplicative
inverse exists.

=item bmodpow()

    $num-&gt;bmodpow($exp,$mod);           # modular exponentiation
                                        # ($num**$exp % $mod)

Returns the value of C&lt;$num&gt; taken to the power C&lt;$exp&gt; in the modulus
C&lt;$mod&gt; using binary exponentiation.  C&lt;bmodpow&gt; is far superior to
writing

    $num ** $exp % $mod

because it is much faster - it reduces internal variables into
the modulus whenever possible, so it operates on smaller numbers.

C&lt;bmodpow&gt; also supports negative exponents.

    bmodpow($num, -1, $mod)

is exactly equivalent to

    bmodinv($num, $mod)

=item bpow()

    $x-&gt;bpow($y);               # power of arguments (x ** y)

C&lt;bpow()&gt; (and the rounding functions) now modifies the first argument and
returns it, unlike the old code which left it alone and only returned the
result. This is to be consistent with C&lt;badd()&gt; etc. The first three modifies
$x, the last one won't:

    print bpow($x,$i),"\n";         # modify $x
    print $x-&gt;bpow($i),"\n";        # ditto
    print $x **= $i,"\n";           # the same
    print $x ** $i,"\n";            # leave $x alone

The form C&lt;$x **= $y&gt; is faster than C&lt;$x = $x ** $y;&gt;, though.

=item blog()

    $x-&gt;blog($base, $accuracy);         # logarithm of x to the base $base

If C&lt;$base&gt; is not defined, Euler's number (e) is used:

    print $x-&gt;blog(undef, 100);         # log(x) to 100 digits

=item bexp()

    $x-&gt;bexp($accuracy);                # calculate e ** X

Calculates the expression C&lt;e ** $x&gt; where C&lt;e&gt; is Euler's number.

This method was added in v1.82 of Math::BigInt (April 2007).

See also L&lt;/blog()&gt;.

=item bilog2()

Base 2 logarithm rounded down towards the nearest integer.

    $x-&gt;bilog2();               # int(log2(x)) = int(log(x)/log(2))

In list context a second argument is returned. This is 1 if the result is
exact, i.e., the input is an exact power of 2, and 0 otherwise.

=item bilog10()

Base 10 logarithm rounded down towards the nearest integer.

    $x-&gt;bilog10();              # int(log10(x)) = int(log(x)/log(10))

In list context a second argument is returned. This is 1 if the result is
exact, i.e., the input is an exact power of 10, and 0 otherwise.

=item bclog2()

Base 2 logarithm rounded up towards the nearest integer.

    $x-&gt;bclog2();               # ceil(log2(x)) = ceil(log(x)/log(2))

In list context a second argument is returned. This is 1 if the result is
exact, i.e., the input is an exact power of 2, and 0 otherwise.

=item bclog10()

Base 10 logarithm rounded up towards the nearest integer.

    $x-&gt;bclog10();              # ceil(log10(x)) = ceil(log(x)/log(10))

In list context a second argument is returned. This is 1 if the result is
exact, i.e., the input is an exact power of 10, and 0 otherwise.

=item bnok()

    $x-&gt;bnok($y);               # x over y (binomial coefficient n over k)

Calculates the binomial coefficient n over k, also called the "choose"
function, which is

    ( n )       n!
    |   |  = --------
    ( k )    k!(n-k)!

when n and k are non-negative. This method implements the full Kronenburg
extension (Kronenburg, M.J. "The Binomial Coefficient for Negative Arguments."
18 May 2011. http://arxiv.org/abs/1105.3689/) illustrated by the following
pseudo-code:

    if n &gt;= 0 and k &gt;= 0:
        return binomial(n, k)
    if k &gt;= 0:
        return (-1)^k*binomial(-n+k-1, k)
    if k &lt;= n:
        return (-1)^(n-k)*binomial(-k-1, n-k)
    else
        return 0

The behaviour is identical to the behaviour of the Maple and Mathematica
function for negative integers n, k.

=item buparrow()

=item uparrow()

    $a -&gt; buparrow($n, $b);         # modifies $a
    $x = $a -&gt; uparrow($n, $b);     # does not modify $a

This method implements Knuth's up-arrow notation, where $n is a non-negative
integer representing the number of up-arrows. $n = 0 gives multiplication, $n =
1 gives exponentiation, $n = 2 gives tetration, $n = 3 gives hexation etc. The
following illustrates the relation between the first values of $n.

See L&lt;https://en.wikipedia.org/wiki/Knuth%27s_up-arrow_notation&gt;.

=item backermann()

=item ackermann()

    $m -&gt; backermann($n);           # modifies $a
    $x = $m -&gt; ackermann($n);       # does not modify $a

This method implements the Ackermann function:

             / n + 1              if m = 0
   A(m, n) = | A(m-1, 1)          if m &gt; 0 and n = 0
             \ A(m-1, A(m, n-1))  if m &gt; 0 and n &gt; 0

Its value grows rapidly, even for small inputs. For example, A(4, 2) is an
integer of 19729 decimal digits.

See https://en.wikipedia.org/wiki/Ackermann_function

=item bsin()

    my $x = Math::BigInt-&gt;new(1);
    print $x-&gt;bsin(100), "\n";

Calculate the sine of $x, modifying $x in place.

In Math::BigInt, unless upgrading is in effect, the result is truncated to an
integer.

This method was added in v1.87 of Math::BigInt (June 2007).

=item bcos()

    my $x = Math::BigInt-&gt;new(1);
    print $x-&gt;bcos(100), "\n";

Calculate the cosine of $x, modifying $x in place.

In Math::BigInt, unless upgrading is in effect, the result is truncated to an
integer.

This method was added in v1.87 of Math::BigInt (June 2007).

=item batan()

    my $x = Math::BigFloat-&gt;new(0.5);
    print $x-&gt;batan(100), "\n";

Calculate the arcus tangens of $x, modifying $x in place.

In Math::BigInt, unless upgrading is in effect, the result is truncated to an
integer.

This method was added in v1.87 of Math::BigInt (June 2007).

=item batan2()

    my $x = Math::BigInt-&gt;new(1);
    my $y = Math::BigInt-&gt;new(1);
    print $y-&gt;batan2($x), "\n";

Calculate the arcus tangens of C&lt;$y&gt; divided by C&lt;$x&gt;, modifying $y in place.

In Math::BigInt, unless upgrading is in effect, the result is truncated to an
integer.

This method was added in v1.87 of Math::BigInt (June 2007).

=item bsqrt()

    $x-&gt;bsqrt();                # calculate square root

C&lt;bsqrt()&gt; returns the square root truncated to an integer.

If you want a better approximation of the square root, then use:

    $x = Math::BigFloat-&gt;new(12);
    Math::BigFloat-&gt;precision(0);
    Math::BigFloat-&gt;round_mode('even');
    print $x-&gt;copy-&gt;bsqrt(),"\n";           # 4

    Math::BigFloat-&gt;precision(2);
    print $x-&gt;bsqrt(),"\n";                 # 3.46
    print $x-&gt;bsqrt(3),"\n";                # 3.464

=item broot()

    $x-&gt;broot($N);

Calculates the N'th root of C&lt;$x&gt;.

=item bfac()

    $x-&gt;bfac();             # factorial of $x

Returns the factorial of C&lt;$x&gt;, i.e., $x*($x-1)*($x-2)*...*2*1, the product of
all positive integers up to and including C&lt;$x&gt;. C&lt;$x&gt; must be &gt; -1. The
factorial of N is commonly written as N!, or N!1, when using the multifactorial
notation.

=item bdfac()

    $x-&gt;bdfac();                # double factorial of $x

Returns the double factorial of C&lt;$x&gt;, i.e., $x*($x-2)*($x-4)*... C&lt;$x&gt; must be
&gt; -2. The double factorial of N is commonly written as N!!, or N!2, when using
the multifactorial notation.

=item btfac()

    $x-&gt;btfac();            # triple factorial of $x

Returns the triple factorial of C&lt;$x&gt;, i.e., $x*($x-3)*($x-6)*... C&lt;$x&gt; must be
&gt; -3. The triple factorial of N is commonly written as N!!!, or N!3, when using
the multifactorial notation.

=item bmfac()

    $x-&gt;bmfac($k);          # $k'th multifactorial of $x

Returns the multi-factorial of C&lt;$x&gt;, i.e., $x*($x-$k)*($x-2*$k)*... C&lt;$x&gt; must
be &gt; -$k. The multi-factorial of N is commonly written as N!K.

=item bfib()

    $F = $n-&gt;bfib();            # a single Fibonacci number
    @F = $n-&gt;bfib();            # a list of Fibonacci numbers

In scalar context, returns a single Fibonacci number. In list context, returns
a list of Fibonacci numbers. The invocand is the last element in the output.

The Fibonacci sequence is defined by

    F(0) = 0
    F(1) = 1
    F(n) = F(n-1) + F(n-2)

In list context, F(0) and F(n) is the first and last number in the output,
respectively. For example, if $n is 12, then C&lt;&lt; @F = $n-&gt;bfib() &gt;&gt; returns the
following values, F(0) to F(12):

    0, 1, 1, 2, 3, 5, 8, 13, 21, 34, 55, 89, 144

The sequence can also be extended to negative index n using the re-arranged
recurrence relation

    F(n-2) = F(n) - F(n-1)

giving the bidirectional sequence

       n  -7  -6  -5  -4  -3  -2  -1   0   1   2   3   4   5   6   7
    F(n)  13  -8   5  -3   2  -1   1   0   1   1   2   3   5   8  13

If $n is -12, the following values, F(0) to F(12), are returned:

    0, 1, -1, 2, -3, 5, -8, 13, -21, 34, -55, 89, -144

=item blucas()

    $F = $n-&gt;blucas();          # a single Lucas number
    @F = $n-&gt;blucas();          # a list of Lucas numbers

In scalar context, returns a single Lucas number. In list context, returns a
list of Lucas numbers. The invocand is the last element in the output.

The Lucas sequence is defined by

    L(0) = 2
    L(1) = 1
    L(n) = L(n-1) + L(n-2)

In list context, L(0) and L(n) is the first and last number in the output,
respectively. For example, if $n is 12, then C&lt;&lt; @L = $n-&gt;blucas() &gt;&gt; returns
the following values, L(0) to L(12):

    2, 1, 3, 4, 7, 11, 18, 29, 47, 76, 123, 199, 322

The sequence can also be extended to negative index n using the re-arranged
recurrence relation

    L(n-2) = L(n) - L(n-1)

giving the bidirectional sequence

       n  -7  -6  -5  -4  -3  -2  -1   0   1   2   3   4   5   6   7
    L(n)  29 -18  11  -7   4  -3   1   2   1   3   4   7  11  18  29

If $n is -12, the following values, L(0) to L(-12), are returned:

    2, 1, -3, 4, -7, 11, -18, 29, -47, 76, -123, 199, -322

=item brsft()

Right shift.

    $x-&gt;brsft($n);              # right shift $n places in base 2
    $x-&gt;brsft($n, $b);          # right shift $n places in base $b

The latter is equivalent to

    $x -&gt; bdiv($b -&gt; copy() -&gt; bpow($n));

=item blsft()

Left shift.

    $x-&gt;blsft($n);              # left shift $n places in base 2
    $x-&gt;blsft($n, $b);          # left shift $n places in base $b

The latter is equivalent to

    $x -&gt; bmul($b -&gt; copy() -&gt; bpow($n));

=back

=head2 Bitwise methods

For all bitwise methods, the operands are truncated to integers, i.e., rounded
towards zero, if necessary, before the method is applied. The bitwise methods
never upgrade, and they always return an integer.

=over

=item bbrsft()

Bitwise right shift. This is equivalent to Perl's C&lt;E&lt;gt&gt;E&lt;gt&gt;&gt; operator.

    $x -&gt; bbrsft($n);           # right shift $n places in base 2

If C&lt;$n&gt; is negative, the shifting is done in the opposite direction, so these
two are equivalent for all C&lt;$x&gt; and C&lt;$n&gt;

    $y = $x -&gt; bbrsft($n);
    $y = $x -&gt; bblsft(-$n);

and also equivalent to

    $y = $x -&gt; bdiv(ref($x) -&gt; new(2) -&gt; bpow($n));   # if $n &gt; 0
    $y = $x -&gt; bmul(ref($x) -&gt; new(2) -&gt; bpow(-$n));  # if $n &lt; 0

=item bblsft()

Bitwise left shift. This is equivalent to Perl's C&lt;E&lt;lt&gt;E&lt;lt&gt;&gt; operator.

    $x -&gt; bblsft($n);           # left shift $n places in base 2

If C&lt;$n&gt; is negative, the shifting is done in the opposite direction, so these
two are equivalent for all C&lt;$x&gt; and C&lt;$n&gt;

    $y = $x -&gt; bblsft($n);
    $y = $x -&gt; bbrsft(-$n);

and also equivalent to

    $y = $x -&gt; bmul(ref($x) -&gt; new(2) -&gt; bpow($n));   # if $n &gt; 0
    $y = $x -&gt; bdiv(ref($x) -&gt; new(2) -&gt; bpow($n));   # if $n &lt; 0

=item band()

    $x-&gt;band($y);               # bitwise and

=item bior()

    $x-&gt;bior($y);               # bitwise inclusive or

=item bxor()

    $x-&gt;bxor($y);               # bitwise exclusive or

=item bnot()

    $x-&gt;bnot();                 # bitwise not (two's complement)

Two's complement (bitwise not). This is equivalent to, but faster than,

    $x-&gt;binc()-&gt;bneg();

=back

=head2 Rounding methods

=over

=item round()

    $x-&gt;round($A,$P,$round_mode);

Round $x to accuracy C&lt;$A&gt; or precision C&lt;$P&gt; using the round mode
C&lt;$round_mode&gt;.

=item bround()

    $x-&gt;bround($N);               # accuracy: preserve $N digits

Rounds $x to an accuracy of $N digits.

=item bfround()

    $x-&gt;bfround($N);

Rounds to a multiple of 10**$N. Examples:

    Input            N          Result

    123456.123456    3          123500
    123456.123456    2          123450
    123456.123456   -2          123456.12
    123456.123456   -3          123456.123

=item bfloor()

    $x-&gt;bfloor();

Round $x towards minus infinity, i.e., set $x to the largest integer less than
or equal to $x.

=item bceil()

    $x-&gt;bceil();

Round $x towards plus infinity, i.e., set $x to the smallest integer greater
than or equal to $x).

=item bint()

    $x-&gt;bint();

Round $x towards zero.

=back

=head2 Other mathematical methods

=over

=item bgcd()

    $x -&gt; bgcd($y);             # GCD of $x and $y
    $x -&gt; bgcd($y, $z, ...);    # GCD of $x, $y, $z, ...

Returns the greatest common divisor (GCD).

=item blcm()

    $x -&gt; blcm($y);             # LCM of $x and $y
    $x -&gt; blcm($y, $z, ...);    # LCM of $x, $y, $z, ...

Returns the least common multiple (LCM).

=back

=head2 Object property methods

=over

=item sign()

    $x-&gt;sign();

Return the sign, of $x, meaning either C&lt;+&gt;, C&lt;-&gt;, C&lt;-inf&gt;, C&lt;+inf&gt; or NaN.

If you want $x to have a certain sign, use one of the following methods:

    $x-&gt;babs();                 # '+'
    $x-&gt;babs()-&gt;bneg();         # '-'
    $x-&gt;bnan();                 # 'NaN'
    $x-&gt;binf();                 # '+inf'
    $x-&gt;binf('-');              # '-inf'

=item digit()

    $x-&gt;digit($n);       # return the nth digit, counting from right

If C&lt;$n&gt; is negative, returns the digit counting from left.

=item digitsum()

    $x-&gt;digitsum();

Computes the sum of the base 10 digits and returns it.

=item bdigitsum()

    $x-&gt;bdigitsum();

Computes the sum of the base 10 digits and assigns the result to the invocand.

=item length()

    $x-&gt;length();
    ($xl, $fl) = $x-&gt;length();

Returns the number of digits in the decimal representation of the number. In
list context, returns the length of the integer and fraction part. For
Math::BigInt objects, the length of the fraction part is always 0.

The following probably doesn't do what you expect:

    $c = Math::BigInt-&gt;new(123);
    print $c-&gt;length(),"\n";                # prints 30

It prints both the number of digits in the number and in the fraction part
since print calls C&lt;length()&gt; in list context. Use something like:

    print scalar $c-&gt;length(),"\n";         # prints 3

=item mantissa()

    $x-&gt;mantissa();

Return the signed mantissa of $x as a Math::BigInt.

=item exponent()

    $x-&gt;exponent();

Return the exponent of $x as a Math::BigInt.

=item parts()

    $x-&gt;parts();

Returns the significand (mantissa) and the exponent as integers. In
Math::BigFloat, both are returned as Math::BigInt objects.

=item sparts()

Returns the significand (mantissa) and the exponent as integers. In scalar
context, only the significand is returned. The significand is the integer with
the smallest absolute value. The output of C&lt;sparts()&gt; corresponds to the
output from C&lt;bsstr()&gt;.

In Math::BigInt, this method is identical to C&lt;parts()&gt;.

=item nparts()

Returns the significand (mantissa) and exponent corresponding to normalized
notation. In scalar context, only the significand is returned. For finite
non-zero numbers, the significand's absolute value is greater than or equal to
1 and less than 10. The output of C&lt;nparts()&gt; corresponds to the output from
C&lt;bnstr()&gt;. In Math::BigInt, if the significand can not be represented as an
integer, upgrading is performed or NaN is returned.

=item eparts()

Returns the significand (mantissa) and exponent corresponding to engineering
notation. In scalar context, only the significand is returned. For finite
non-zero numbers, the significand's absolute value is greater than or equal to
1 and less than 1000, and the exponent is a multiple of 3. The output of
C&lt;eparts()&gt; corresponds to the output from C&lt;bestr()&gt;. In Math::BigInt, if the
significand can not be represented as an integer, upgrading is performed or NaN
is returned.

=item dparts()

Returns the integer part and the fraction part. If the fraction part can not be
represented as an integer, upgrading is performed or NaN is returned. The
output of C&lt;dparts()&gt; corresponds to the output from C&lt;bdstr()&gt;.

=item fparts()

Returns the smallest possible numerator and denominator so that the numerator
divided by the denominator gives back the original value. For finite numbers,
both values are integers. Mnemonic: fraction.

=item numerator()

Together with L&lt;/denominator()&gt;, returns the smallest integers so that the
numerator divided by the denominator reproduces the original value. With
Math::BigInt, numerator() simply returns a copy of the invocand.

=item denominator()

Together with L&lt;/numerator()&gt;, returns the smallest integers so that the
numerator divided by the denominator reproduces the original value. With
Math::BigInt, denominator() always returns either a 1 or a NaN.

=back

=head2 String conversion methods

=over

=item bstr()

Returns a string representing the number using decimal notation. In
Math::BigFloat, the output is zero padded according to the current accuracy or
precision, if any of those are defined.

=item bsstr()

Returns a string representing the number using scientific notation where both
the significand (mantissa) and the exponent are integers. The output
corresponds to the output from C&lt;sparts()&gt;.

      123 is returned as "123e+0"
     1230 is returned as "123e+1"
    12300 is returned as "123e+2"
    12000 is returned as "12e+3"
    10000 is returned as "1e+4"

=item bnstr()

Returns a string representing the number using normalized notation, the most
common variant of scientific notation. For finite non-zero numbers, the
absolute value of the significand is greater than or equal to 1 and less than
10. The output corresponds to the output from C&lt;nparts()&gt;.

      123 is returned as "1.23e+2"
     1230 is returned as "1.23e+3"
    12300 is returned as "1.23e+4"
    12000 is returned as "1.2e+4"
    10000 is returned as "1e+4"

=item bestr()

Returns a string representing the number using engineering notation. For finite
non-zero numbers, the absolute value of the significand is greater than or
equal to 1 and less than 1000, and the exponent is a multiple of 3. The output
corresponds to the output from C&lt;eparts()&gt;.

      123 is returned as "123e+0"
     1230 is returned as "1.23e+3"
    12300 is returned as "12.3e+3"
    12000 is returned as "12e+3"
    10000 is returned as "10e+3"

=item bdstr()

Returns a string representing the number using decimal notation. The output
corresponds to the output from C&lt;dparts()&gt;.

      123 is returned as "123"
     1230 is returned as "1230"
    12300 is returned as "12300"
    12000 is returned as "12000"
    10000 is returned as "10000"

=item bfstr()

Returns a string representing the number using fractional notation. The output
corresponds to the output from C&lt;fparts()&gt;.

        12.345 is returned as "2469/200"
       123.45 is returned as "2469/20"
      1234.5 is returned as "2469/2"
     12345 is returned as "12345"
    123450 is returned as "123450"

=item to_hex()

    $x-&gt;to_hex();

Returns a hexadecimal string representation of the number. See also from_hex().

=item to_bin()

    $x-&gt;to_bin();

Returns a binary string representation of the number. See also from_bin().

=item to_oct()

    $x-&gt;to_oct();

Returns an octal string representation of the number. See also from_oct().

=item to_bytes()

    $x = Math::BigInt-&gt;new("1667327589");
    $s = $x-&gt;to_bytes();                    # $s = "cafe"

Returns a byte string representation of the number using big endian byte order.
The invocand must be a non-negative, finite integer. See also from_bytes().

=item to_base()

    $x = Math::BigInt-&gt;new("250");
    $x-&gt;to_base(2);     # returns "11111010"
    $x-&gt;to_base(8);     # returns "372"
    $x-&gt;to_base(16);    # returns "fa"

Returns a string representation of the number in the given base. If a collation
sequence is given, the collation sequence determines which characters are used
in the output.

Here are some more examples

    $x = Math::BigInt-&gt;new("16")-&gt;to_base(3);       # returns "121"
    $x = Math::BigInt-&gt;new("44027")-&gt;to_base(36);   # returns "XYZ"
    $x = Math::BigInt-&gt;new("58314")-&gt;to_base(42);   # returns "Why"
    $x = Math::BigInt-&gt;new("4")-&gt;to_base(2, "-|");  # returns "|--"

See from_base() for information and examples.

=item to_base_num()

Converts the given number to the given base. This method is equivalent to
C&lt;_to_base()&gt;, but returns numbers in an array rather than characters in a
string. In the output, the first element is the most significant. Unlike
C&lt;_to_base()&gt;, all input values may be arbitrarily large.

    $x = Math::BigInt-&gt;new(13);
    $x-&gt;to_base_num(2);                         # returns [1, 1, 0, 1]

    $x = Math::BigInt-&gt;new(65191);
    $x-&gt;to_base_num(128);                       # returns [3, 125, 39]

=item as_hex()

    $x-&gt;as_hex();

As, C&lt;to_hex()&gt;, but with a "0x" prefix.

=item as_bin()

    $x-&gt;as_bin();

As, C&lt;to_bin()&gt;, but with a "0b" prefix.

=item as_oct()

    $x-&gt;as_oct();

As, C&lt;to_oct()&gt;, but with a "0" prefix.

=item as_bytes()

This is just an alias for C&lt;to_bytes()&gt;.

=back

=head2 Other conversion methods

=over

=item numify()

    print $x-&gt;numify();

Returns a Perl scalar from $x. It is used automatically whenever a scalar is
needed, for instance in array index operations.

=back

=head2 Utility methods

These utility methods are made public

=over

=item dec_str_to_dec_flt_str()

Takes a string representing any valid number using decimal notation and converts
it to a string representing the same number using decimal floating point
notation. The output consists of five parts joined together: the sign of the
significand, the absolute value of the significand as the smallest possible
integer, the letter "e", the sign of the exponent, and the absolute value of the
exponent. If the input is invalid, nothing is returned.

    $str2 = $class -&gt; dec_str_to_dec_flt_str($str1);

Some examples

    Input           Output
    31400.00e-4     +314e-2
    -0.00012300e8   -123e+2
    0               +0e+0

=item hex_str_to_dec_flt_str()

Takes a string representing any valid number using hexadecimal notation and
converts it to a string representing the same number using decimal floating
point notation. The output has the same format as that of
L&lt;/dec_str_to_dec_flt_str()&gt;.

    $str2 = $class -&gt; hex_str_to_dec_flt_str($str1);

Some examples

    Input           Output
    0xff            +255e+0

Some examples

=item oct_str_to_dec_flt_str()

Takes a string representing any valid number using octal notation and converts
it to a string representing the same number using decimal floating point
notation. The output has the same format as that of
L&lt;/dec_str_to_dec_flt_str()&gt;.

    $str2 = $class -&gt; oct_str_to_dec_flt_str($str1);

=item bin_str_to_dec_flt_str()

Takes a string representing any valid number using binary notation and converts
it to a string representing the same number using decimal floating point
notation. The output has the same format as that of
L&lt;/dec_str_to_dec_flt_str()&gt;.

    $str2 = $class -&gt; bin_str_to_dec_flt_str($str1);

=item dec_str_to_dec_str()

Takes a string representing any valid number using decimal notation and converts
it to a string representing the same number using decimal notation. If the
number represents an integer, the output consists of a sign and the absolute
value. If the number represents a non-integer, the output consists of a sign,
the integer part of the number, the decimal point ".", and the fraction part of
the number without any trailing zeros. If the input is invalid, nothing is
returned.

=item hex_str_to_dec_str()

Takes a string representing any valid number using hexadecimal notation and
converts it to a string representing the same number using decimal notation. The
output has the same format as that of L&lt;/dec_str_to_dec_str()&gt;.

=item oct_str_to_dec_str()

Takes a string representing any valid number using octal notation and converts
it to a string representing the same number using decimal notation. The
output has the same format as that of L&lt;/dec_str_to_dec_str()&gt;.

=item bin_str_to_dec_str()

Takes a string representing any valid number using binary notation and converts
it to a string representing the same number using decimal notation. The output
has the same format as that of L&lt;/dec_str_to_dec_str()&gt;.

=back

=head1 ACCURACY and PRECISION

Math::BigInt and Math::BigFloat have full support for accuracy and precision
based rounding, both automatically after every operation, as well as manually.

This section describes the accuracy/precision handling in Math::BigInt and
Math::BigFloat as it used to be and as it is now, complete with an explanation
of all terms and abbreviations.

Not yet implemented things (but with correct description) are marked with '!',
things that need to be answered are marked with '?'.

In the next paragraph follows a short description of terms used here (because
these may differ from terms used by others people or documentation).

During the rest of this document, the shortcuts A (for accuracy), P (for
precision), F (fallback) and R (rounding mode) are be used.

=head2 Precision P

Precision is a fixed number of digits before (positive) or after (negative) the
decimal point. For example, 123.45 has a precision of -2. 0 means an integer
like 123 (or 120). A precision of 2 means at least two digits to the left of
the decimal point are zero, so 123 with P = 1 becomes 120. Note that numbers
with zeros before the decimal point may have different precisions, because 1200
can have P = 0, 1 or 2 (depending on what the initial value was). It could also
have p &lt; 0, when the digits after the decimal point are zero.

The string output (of floating point numbers) is padded with zeros:

    Initial value    P      A       Result          String
    ------------------------------------------------------------
    1234.01         -3              1000            1000
    1234            -2              1200            1200
    1234.5          -1              1230            1230
    1234.001         1              1234            1234.0
    1234.01          0              1234            1234
    1234.01          2              1234.01         1234.01
    1234.01          5              1234.01         1234.01000

For Math::BigInt objects, no padding occurs.

=head2 Accuracy A

Number of significant digits. Leading zeros are not counted. A number may have
an accuracy greater than the non-zero digits when there are zeros in it or
trailing zeros. For example, 123.456 has A of 6, 10203 has 5, 123.0506 has 7,
123.45000 has 8 and 0.000123 has 3.

The string output (of floating point numbers) is padded with zeros:

    Initial value    P      A       Result          String
    ------------------------------------------------------------
    1234.01                 3       1230            1230
    1234.01                 6       1234.01         1234.01
    1234.1                  8       1234.1          1234.1000

For Math::BigInt objects, no padding occurs.

=head2 Fallback F

When both A and P are undefined, this is used as a fallback accuracy when
dividing numbers.

=head2 Rounding mode R

When rounding a number, different 'styles' or 'kinds' of rounding are possible.
(Note that random rounding, as in Math::Round, is not implemented.)

=head3 Directed rounding

These round modes always round in the same direction.

=over

=item 'trunc'

Round towards zero. Remove all digits following the rounding place, i.e.,
replace them with zeros. Thus, 987.65 rounded to tens (P=1) becomes 980, and
rounded to the fourth significant digit becomes 987.6 (A=4). 123.456 rounded to
the second place after the decimal point (P=-2) becomes 123.46. This
corresponds to the IEEE 754 rounding mode 'roundTowardZero'.

=back

=head3 Rounding to nearest

These rounding modes round to the nearest digit. They differ in how they
determine which way to round in the ambiguous case when there is a tie.

=over

=item 'even'

Round towards the nearest even digit, e.g., when rounding to nearest integer,
-5.5 becomes -6, 4.5 becomes 4, but 4.501 becomes 5. This corresponds to the
IEEE 754 rounding mode 'roundTiesToEven'.

=item 'odd'

Round towards the nearest odd digit, e.g., when rounding to nearest integer,
4.5 becomes 5, -5.5 becomes -5, but 5.501 becomes 6. This corresponds to the
IEEE 754 rounding mode 'roundTiesToOdd'.

=item '+inf'

Round towards plus infinity, i.e., always round up. E.g., when rounding to the
nearest integer, 4.5 becomes 5, -5.5 becomes -5, and 4.501 also becomes 5. This
corresponds to the IEEE 754 rounding mode 'roundTiesToPositive'.

=item '-inf'

Round towards minus infinity, i.e., always round down. E.g., when rounding to
the nearest integer, 4.5 becomes 4, -5.5 becomes -6, but 4.501 becomes 5. This
corresponds to the IEEE 754 rounding mode 'roundTiesToNegative'.

=item 'zero'

Round towards zero, i.e., round positive numbers down and negative numbers up.
E.g., when rounding to the nearest integer, 4.5 becomes 4, -5.5 becomes -5, but
4.501 becomes 5. This corresponds to the IEEE 754 rounding mode
'roundTiesToZero'.

=item 'common'

Round away from zero, i.e., round to the number with the largest absolute
value. E.g., when rounding to the nearest integer, -1.5 becomes -2, 1.5 becomes
2 and 1.49 becomes 1. This corresponds to the IEEE 754 rounding mode
'roundTiesToAway'.

=back

The handling of A &amp; P in MBI/MBF (the old core code shipped with Perl versions
&lt;= 5.7.2) is like this:

=over

=item Precision

  * bfround($p) is able to round to $p number of digits after the decimal
    point
  * otherwise P is unused

=item Accuracy (significant digits)

  * bround($a) rounds to $a significant digits
  * only bdiv() and bsqrt() take A as (optional) parameter
    + other operations simply create the same number (bneg etc), or
      more (bmul) of digits
    + rounding/truncating is only done when explicitly calling one
      of bround or bfround, and never for Math::BigInt (not implemented)
  * bsqrt() simply hands its accuracy argument over to bdiv.
  * the documentation and the comment in the code indicate two
    different ways on how bdiv() determines the maximum number
    of digits it should calculate, and the actual code does yet
    another thing
    POD:
      max($Math::BigFloat::div_scale,length(dividend)+length(divisor))
    Comment:
      result has at most max(scale, length(dividend), length(divisor)) digits
    Actual code:
      scale = max(scale, length(dividend)-1,length(divisor)-1);
      scale += length(divisor) - length(dividend);
    So for lx = 3, ly = 9, scale = 10, scale will actually be 16 (10
    So for lx = 3, ly = 9, scale = 10, scale will actually be 16
    (10+9-3). Actually, the 'difference' added to the scale is cal-
    culated from the number of "significant digits" in dividend and
    divisor, which is derived by looking at the length of the man-
    tissa. Which is wrong, since it includes the + sign (oops) and
    actually gets 2 for '+100' and 4 for '+101'. Oops again. Thus
    124/3 with div_scale=1 will get you '41.3' based on the strange
    assumption that 124 has 3 significant digits, while 120/7 will
    get you '17', not '17.1' since 120 is thought to have 2 signif-
    icant digits. The rounding after the division then uses the
    remainder and $y to determine whether it must round up or down.
 ?  I have no idea which is the right way. That's why I used a slightly more
 ?  simple scheme and tweaked the few failing testcases to match it.

=back

This is how it works now:

=over

=item Setting/Accessing

  * You can set the A global via Math::BigInt-&gt;accuracy() or
    Math::BigFloat-&gt;accuracy() or whatever class you are using.
  * You can also set P globally by using Math::SomeClass-&gt;precision()
    likewise.
  * Globals are classwide, and not inherited by subclasses.
  * to undefine A, use Math::SomeClass-&gt;accuracy(undef);
  * to undefine P, use Math::SomeClass-&gt;precision(undef);
  * Setting Math::SomeClass-&gt;accuracy() clears automatically
    Math::SomeClass-&gt;precision(), and vice versa.
  * To be valid, A must be &gt; 0, P can have any value.
  * If P is negative, this means round to the P'th place to the right of the
    decimal point; positive values mean to the left of the decimal point.
    P of 0 means round to integer.
  * to find out the current global A, use Math::SomeClass-&gt;accuracy()
  * to find out the current global P, use Math::SomeClass-&gt;precision()
  * use $x-&gt;accuracy() respective $x-&gt;precision() for the local
    setting of $x.
  * Please note that $x-&gt;accuracy() respective $x-&gt;precision()
    return eventually defined global A or P, when $x's A or P is not
    set.

=item Creating numbers

  * When you create a number, you can give the desired A or P via:
    $x = Math::BigInt-&gt;new($number,$A,$P);
  * Only one of A or P can be defined, otherwise the result is NaN
  * If no A or P is give ($x = Math::BigInt-&gt;new($number) form), then the
    globals (if set) will be used. Thus changing the global defaults later on
    will not change the A or P of previously created numbers (i.e., A and P of
    $x will be what was in effect when $x was created)
  * If given undef for A and P, NO rounding will occur, and the globals will
    NOT be used. This is used by subclasses to create numbers without
    suffering rounding in the parent. Thus a subclass is able to have its own
    globals enforced upon creation of a number by using
    $x = Math::BigInt-&gt;new($number,undef,undef):

        use Math::BigInt::SomeSubclass;
        use Math::BigInt;

        Math::BigInt-&gt;accuracy(2);
        Math::BigInt::SomeSubclass-&gt;accuracy(3);
        $x = Math::BigInt::SomeSubclass-&gt;new(1234);

    $x is now 1230, and not 1200. A subclass might choose to implement
    this otherwise, e.g. falling back to the parent's A and P.

=item Usage

  * If A or P are enabled/defined, they are used to round the result of each
    operation according to the rules below
  * Negative P is ignored in Math::BigInt, since Math::BigInt objects never
    have digits after the decimal point
  * Math::BigFloat uses Math::BigInt internally, but setting A or P inside
    Math::BigInt as globals does not tamper with the parts of a Math::BigFloat.
    A flag is used to mark all Math::BigFloat numbers as 'never round'.

=item Precedence

  * It only makes sense that a number has only one of A or P at a time.
    If you set either A or P on one object, or globally, the other one will
    be automatically cleared.
  * If two objects are involved in an operation, and one of them has A in
    effect, and the other P, this results in an error (NaN).
  * A takes precedence over P (Hint: A comes before P).
    If neither of them is defined, nothing is used, i.e. the result will have
    as many digits as it can (with an exception for bdiv/bsqrt) and will not
    be rounded.
  * There is another setting for bdiv() (and thus for bsqrt()). If neither of
    A or P is defined, bdiv() will use a fallback (F) of $div_scale digits.
    If either the dividend's or the divisor's mantissa has more digits than
    the value of F, the higher value will be used instead of F.
    This is to limit the digits (A) of the result (just consider what would
    happen with unlimited A and P in the case of 1/3 :-)
  * bdiv will calculate (at least) 4 more digits than required (determined by
    A, P or F), and, if F is not used, round the result
    (this will still fail in the case of a result like 0.12345000000001 with A
    or P of 5, but this can not be helped - or can it?)
  * Thus you can have the math done by on Math::Big* class in two modi:
    + never round (this is the default):
      This is done by setting A and P to undef. No math operation
      will round the result, with bdiv() and bsqrt() as exceptions to guard
      against overflows. You must explicitly call bround(), bfround() or
      round() (the latter with parameters).
      Note: Once you have rounded a number, the settings will 'stick' on it
      and 'infect' all other numbers engaged in math operations with it, since
      local settings have the highest precedence. So, to get SaferRound[tm],
      use a copy() before rounding like this:

        $x = Math::BigFloat-&gt;new(12.34);
        $y = Math::BigFloat-&gt;new(98.76);
        $z = $x * $y;                           # 1218.6984
        print $x-&gt;copy()-&gt;bround(3);            # 12.3 (but A is now 3!)
        $z = $x * $y;                           # still 1218.6984, without
                                                # copy would have been 1210!

    + round after each op:
      After each single operation (except for testing like is_zero()), the
      method round() is called and the result is rounded appropriately. By
      setting proper values for A and P, you can have all-the-same-A or
      all-the-same-P modes. For example, Math::Currency might set A to undef,
      and P to -2, globally.

 ?Maybe an extra option that forbids local A &amp; P settings would be in order,
 ?so that intermediate rounding does not 'poison' further math?

=item Overriding globals

  * you will be able to give A, P and R as an argument to all the calculation
    routines; the second parameter is A, the third one is P, and the fourth is
    R (shift right by one for binary operations like badd). P is used only if
    the first parameter (A) is undefined. These three parameters override the
    globals in the order detailed as follows, i.e. the first defined value
    wins:
    (local: per object, global: global default, parameter: argument to sub)
      + parameter A
      + parameter P
      + local A (if defined on both of the operands: smaller one is taken)
      + local P (if defined on both of the operands: bigger one is taken)
      + global A
      + global P
      + global F
  * bsqrt() will hand its arguments to bdiv(), as it used to, only now for two
    arguments (A and P) instead of one

=item Local settings

  * You can set A or P locally by using $x-&gt;accuracy() or
    $x-&gt;precision()
    and thus force different A and P for different objects/numbers.
  * Setting A or P this way immediately rounds $x to the new value.
  * $x-&gt;accuracy() clears $x-&gt;precision(), and vice versa.

=item Rounding

  * the rounding routines will use the respective global or local settings.
    bround() is for accuracy rounding, while bfround() is for precision
  * the two rounding functions take as the second parameter one of the
    following rounding modes (R):
    'even', 'odd', '+inf', '-inf', 'zero', 'trunc', 'common'
  * you can set/get the global R by using Math::SomeClass-&gt;round_mode()
    or by setting $Math::SomeClass::round_mode
  * after each operation, $result-&gt;round() is called, and the result may
    eventually be rounded (that is, if A or P were set either locally,
    globally or as parameter to the operation)
  * to manually round a number, call $x-&gt;round($A,$P,$round_mode);
    this will round the number by using the appropriate rounding function
    and then normalize it.
  * rounding modifies the local settings of the number:

        $x = Math::BigFloat-&gt;new(123.456);
        $x-&gt;accuracy(5);
        $x-&gt;bround(4);

    Here 4 takes precedence over 5, so 123.5 is the result and $x-&gt;accuracy()
    will be 4 from now on.

=item Default values

  * R: 'even'
  * F: 40
  * A: undef
  * P: undef

=item Remarks

  * The defaults are set up so that the new code gives the same results as
    the old code (except in a few cases on bdiv):
    + Both A and P are undefined and thus will not be used for rounding
      after each operation.
    + round() is thus a no-op, unless given extra parameters A and P

=back

=head1 Infinity and Not a Number

While Math::BigInt has extensive handling of inf and NaN, certain quirks
remain.

=over

=item oct()/hex()

These perl routines currently (as of Perl v.5.8.6) cannot handle passed inf.

    te@linux:~&gt; perl -wle 'print 2 ** 3333'
    Inf
    te@linux:~&gt; perl -wle 'print 2 ** 3333 == 2 ** 3333'
    1
    te@linux:~&gt; perl -wle 'print oct(2 ** 3333)'
    0
    te@linux:~&gt; perl -wle 'print hex(2 ** 3333)'
    Illegal hexadecimal digit 'I' ignored at -e line 1.
    0

The same problems occur if you pass them Math::BigInt-&gt;binf() objects. Since
overloading these routines is not possible, this cannot be fixed from
Math::BigInt.

=back

=head1 INTERNALS

You should neither care about nor depend on the internal representation; it
might change without notice. Use B&lt;ONLY&gt; method calls like C&lt;&lt; $x-&gt;sign(); &gt;&gt;
instead relying on the internal representation.

=head2 MATH LIBRARY

The mathematical computations are performed by a backend library. It is not
required to specify which backend library to use, but some backend libraries
are much faster than the default library.

=head3 The default library

The default library is L&lt;Math::BigInt::Calc&gt;, which is implemented in pure Perl
and hence does not require a compiler.

=head3 Specifying a library

The simple case

    use Math::BigInt;

is equivalent to saying

    use Math::BigInt try =&gt; 'Calc';

You can use a different backend library with, e.g.,

    use Math::BigInt try =&gt; 'GMP';

which attempts to load the L&lt;Math::BigInt::GMP&gt; library, and falls back to the
default library if the specified library can't be loaded.

Multiple libraries can be specified by separating them by a comma, e.g.,

    use Math::BigInt try =&gt; 'GMP,Pari';

If you request a specific set of libraries and do not allow fallback to the
default library, specify them using "only",

    use Math::BigInt only =&gt; 'GMP,Pari';

If you prefer a specific set of libraries, but want to see a warning if the
fallback library is used, specify them using "lib",

    use Math::BigInt lib =&gt; 'GMP,Pari';

The following first tries to find Math::BigInt::Foo, then Math::BigInt::Bar, and
if this also fails, reverts to Math::BigInt::Calc:

    use Math::BigInt try =&gt; 'Foo,Math::BigInt::Bar';

=head3 Which library to use?

B&lt;Note&gt;: General purpose packages should not be explicit about the library to
use; let the script author decide which is best.

L&lt;Math::BigInt::GMP&gt;, L&lt;Math::BigInt::Pari&gt;, and L&lt;Math::BigInt::GMPz&gt; are in
cases involving big numbers much faster than L&lt;Math::BigInt::Calc&gt;. However
these libraries are slower when dealing with very small numbers (less than about
20 digits) and when converting very large numbers to decimal (for instance for
printing, rounding, calculating their length in decimal etc.).

So please select carefully what library you want to use.

Different low-level libraries use different formats to store the numbers, so
mixing them won't work. You should not depend on the number having a specific
internal format.

See the respective math library module documentation for further details.

=head3 Loading multiple libraries

The first library that is successfully loaded is the one that will be used. Any
further attempts at loading a different module will be ignored. This is to avoid
the situation where module A requires math library X, and module B requires math
library Y, causing modules A and B to be incompatible. For example,

    use Math::BigInt;                   # loads default "Calc"
    use Math::BigFloat only =&gt; "GMP";   # ignores "GMP"

=head2 SIGN

The sign is either '+', '-', 'NaN', '+inf' or '-inf'.

A sign of 'NaN' is used to represent the result when input arguments are not
numbers or as a result of 0/0. '+inf' and '-inf' represent plus respectively
minus infinity. You get '+inf' when dividing a positive number by 0, and '-inf'
when dividing any negative number by 0.

=head1 EXAMPLES

  use Math::BigInt;

  sub bigint { Math::BigInt-&gt;new(shift); }

  $x = Math::BigInt-&gt;bstr("1234")       # string "1234"
  $x = "$x";                            # same as bstr()
  $x = Math::BigInt-&gt;bneg("1234");      # Math::BigInt "-1234"
  $x = Math::BigInt-&gt;babs("-12345");    # Math::BigInt "12345"
  $x = Math::BigInt-&gt;bnorm("-0.00");    # Math::BigInt "0"
  $x = bigint(1) + bigint(2);           # Math::BigInt "3"
  $x = bigint(1) + "2";                 # ditto ("2" becomes a Math::BigInt)
  $x = bigint(1);                       # Math::BigInt "1"
  $x = $x + 5 / 2;                      # Math::BigInt "3"
  $x = $x ** 3;                         # Math::BigInt "27"
  $x *= 2;                              # Math::BigInt "54"
  $x = Math::BigInt-&gt;new(0);            # Math::BigInt "0"
  $x--;                                 # Math::BigInt "-1"
  $x = Math::BigInt-&gt;badd(4,5)          # Math::BigInt "9"
  print $x-&gt;bsstr();                    # 9e+0

Examples for rounding:

  use Math::BigFloat;
  use Test::More;

  $x = Math::BigFloat-&gt;new(123.4567);
  $y = Math::BigFloat-&gt;new(123.456789);
  Math::BigFloat-&gt;accuracy(4);          # no more A than 4

  is ($x-&gt;copy()-&gt;bround(),123.4);      # even rounding
  print $x-&gt;copy()-&gt;bround(),"\n";      # 123.4
  Math::BigFloat-&gt;round_mode('odd');    # round to odd
  print $x-&gt;copy()-&gt;bround(),"\n";      # 123.5
  Math::BigFloat-&gt;accuracy(5);          # no more A than 5
  Math::BigFloat-&gt;round_mode('odd');    # round to odd
  print $x-&gt;copy()-&gt;bround(),"\n";      # 123.46
  $y = $x-&gt;copy()-&gt;bround(4),"\n";      # A = 4: 123.4
  print "$y, ",$y-&gt;accuracy(),"\n";     # 123.4, 4

  Math::BigFloat-&gt;accuracy(undef);      # A not important now
  Math::BigFloat-&gt;precision(2);         # P important
  print $x-&gt;copy()-&gt;bnorm(),"\n";       # 123.46
  print $x-&gt;copy()-&gt;bround(),"\n";      # 123.46

Examples for converting:

  my $x = Math::BigInt-&gt;new('0b1'.'01' x 123);
  print "bin: ",$x-&gt;as_bin()," hex:",$x-&gt;as_hex()," dec: ",$x,"\n";

=head1 NUMERIC LITERALS

After C&lt;use Math::BigInt ':constant'&gt; all numeric literals in the given scope
are converted to C&lt;Math::BigInt&gt; objects. This conversion happens at compile
time. Every non-integer is convert to a NaN.

For example,

    perl -MMath::BigInt=:constant -le 'print 2**150'

prints the exact value of C&lt;2**150&gt;. Note that without conversion of constants
to objects the expression C&lt;2**150&gt; is calculated using Perl scalars, which
leads to an inaccurate result.

Please note that strings are not affected, so that

    use Math::BigInt qw/:constant/;

    $x = "1234567890123456789012345678901234567890"
            + "123456789123456789";

does give you what you expect. You need an explicit Math::BigInt-&gt;new() around
at least one of the operands. You should also quote large constants to prevent
loss of precision:

    use Math::BigInt;

    $x = Math::BigInt-&gt;new("1234567889123456789123456789123456789");

Without the quotes Perl first converts the large number to a floating point
constant at compile time, and then converts the result to a Math::BigInt object
at run time, which results in an inaccurate result.

=head2 Hexadecimal, octal, and binary floating point literals

Perl (and this module) accepts hexadecimal, octal, and binary floating point
literals, but use them with care with Perl versions before v5.32.0, because some
versions of Perl silently give the wrong result. Below are some examples of
different ways to write the number decimal 314.

Hexadecimal floating point literals:

    0x1.3ap+8         0X1.3AP+8
    0x1.3ap8          0X1.3AP8
    0x13a0p-4         0X13A0P-4

Octal floating point literals (with "0" prefix):

    01.164p+8         01.164P+8
    01.164p8          01.164P8
    011640p-4         011640P-4

Octal floating point literals (with "0o" prefix) (requires v5.34.0):

    0o1.164p+8        0O1.164P+8
    0o1.164p8         0O1.164P8
    0o11640p-4        0O11640P-4

Binary floating point literals:

    0b1.0011101p+8    0B1.0011101P+8
    0b1.0011101p8     0B1.0011101P8
    0b10011101000p-2  0B10011101000P-2

=head1 PERFORMANCE

Using the form $x += $y; etc over $x = $x + $y is faster, since a copy of $x
must be made in the second case. For long numbers, the copy can eat up to 20%
of the work (in the case of addition/subtraction, less for
multiplication/division). If $y is very small compared to $x, the form $x += $y
is MUCH faster than $x = $x + $y since making the copy of $x takes more time
then the actual addition.

With a technique called copy-on-write, the cost of copying with overload could
be minimized or even completely avoided. A test implementation of COW did show
performance gains for overloaded math, but introduced a performance loss due to
a constant overhead for all other operations. So Math::BigInt does currently
not COW.

The rewritten version of this module (vs. v0.01) is slower on certain
operations, like C&lt;new()&gt;, C&lt;bstr()&gt; and C&lt;numify()&gt;. The reason are that it
does now more work and handles much more cases. The time spent in these
operations is usually gained in the other math operations so that code on the
average should get (much) faster. If they don't, please contact the author.

Some operations may be slower for small numbers, but are significantly faster
for big numbers. Other operations are now constant (O(1), like C&lt;bneg()&gt;,
C&lt;babs()&gt; etc), instead of O(N) and thus nearly always take much less time.
These optimizations were done on purpose.

If you find the Calc module to slow, try to install any of the replacement
modules and see if they help you.

=head2 Alternative math libraries

You can use an alternative library to drive Math::BigInt. See the section
L&lt;/MATH LIBRARY&gt; for more information.

For more benchmark results see L&lt;http://bloodgate.com/perl/benchmarks.html&gt;.

=head1 SUBCLASSING

=head2 Subclassing Math::BigInt

The basic design of Math::BigInt allows simple subclasses with very little
work, as long as a few simple rules are followed:

=over

=item *

The public API must remain consistent, i.e. if a sub-class is overloading
addition, the sub-class must use the same name, in this case badd(). The reason
for this is that Math::BigInt is optimized to call the object methods directly.

=item *

The private object hash keys like C&lt;&lt; $x-&gt;{sign} &gt;&gt; may not be changed, but
additional keys can be added, like C&lt;&lt; $x-&gt;{_custom} &gt;&gt;.

=item *

Accessor functions are available for all existing object hash keys and should
be used instead of directly accessing the internal hash keys. The reason for
this is that Math::BigInt itself has a pluggable interface which permits it to
support different storage methods.

=back

More complex sub-classes may have to replicate more of the logic internal of
Math::BigInt if they need to change more basic behaviors. A subclass that needs
to merely change the output only needs to overload C&lt;bstr()&gt;.

All other object methods and overloaded functions can be directly inherited
from the parent class.

At the very minimum, any subclass needs to provide its own C&lt;new()&gt; and can
store additional hash keys in the object. There are also some package globals
that must be defined, e.g.:

    # Globals
    our $accuracy = 2;          # round to 2 decimal places
    our $precision = undef;
    our $round_mode = 'even';
    our $div_scale = 40;

Additionally, you might want to provide the following two globals to allow
auto-upgrading and auto-downgrading:

    our $upgrade = undef;
    our $downgrade = undef;

This allows Math::BigInt to correctly retrieve package globals from the
subclass, like C&lt;$SubClass::precision&gt;. See C&lt;t/Math/BigInt/Subclass.pm&gt;,
C&lt;t/Math/BigFloat/SubClass.pm&gt;, or C&lt;t/Math/BigRat/SubClass.pm&gt; for subclass
examples.

Don't forget to

    use overload;

in your subclass to automatically inherit the overloading from the parent. If
you like, you can change part of the overloading, look at Math::String for an
example.

=head1 UPGRADING

When used like this:

    use Math::BigInt upgrade =&gt; 'Foo::Bar';

any operation whose result cannot be represented as an integer is upgraded to
the class Foo::Bar. Usually this is used in conjunction with Math::BigFloat:

    use Math::BigInt upgrade =&gt; 'Math::BigFloat';

For example, the following returns 3 as a Math::BigInt when no upgrading is
defined, and 3.125 as a Math::BigFloat if Math::BigInt is set to upgrade to
Math::BigFloat:

    $x = Math::BigInt -&gt; new(25) -&gt; bdiv(8);

As a shortcut, you can use the module L&lt;bignum&gt;:

    use bignum;

which is also good for one-liners:

    perl -Mbignum -le 'print 2 ** 255'

This makes it possible to mix arguments of different classes (as in 2.5 + 2) as
well es preserve accuracy (as in sqrt(3)).

Beware: This feature is not fully implemented yet.

=head2 Auto-upgrade

The following methods upgrade themselves unconditionally; that is if upgrade is
in effect, they always hands up their work:

    div bsqrt blog bexp bpi bsin bcos batan batan2

All other methods upgrade themselves only when one (or all) of their arguments
are of the class mentioned in $upgrade.

=head1 EXPORTS

C&lt;Math::BigInt&gt; exports nothing by default, but can export the following
methods:

    bgcd
    blcm

=head1 CAVEATS

Some things might not work as you expect them. Below is documented what is
known to be troublesome:

=over

=item Comparing numbers as strings

Both C&lt;bstr()&gt; and C&lt;bsstr()&gt; as well as stringify via overload drop the
leading '+'. This is to be consistent with Perl and to make C&lt;cmp&gt; (especially
with overloading) to work as you expect. It also solves problems with
C&lt;Test.pm&gt; and L&lt;Test::More&gt;, which stringify arguments before comparing them.

Mark Biggar said, when asked about to drop the '+' altogether, or make only
C&lt;cmp&gt; work:

    I agree (with the first alternative), don't add the '+' on positive
    numbers.  It's not as important anymore with the new internal form
    for numbers.  It made doing things like abs and neg easier, but
    those have to be done differently now anyway.

So, the following examples now works as expected:

    use Test::More tests =&gt; 1;
    use Math::BigInt;

    my $x = Math::BigInt -&gt; new(3*3);
    my $y = Math::BigInt -&gt; new(3*3);

    is($x,3*3, 'multiplication');
    print "$x eq 9" if $x eq $y;
    print "$x eq 9" if $x eq '9';
    print "$x eq 9" if $x eq 3*3;

Additionally, the following still works:

    print "$x == 9" if $x == $y;
    print "$x == 9" if $x == 9;
    print "$x == 9" if $x == 3*3;

There is now a C&lt;bsstr()&gt; method to get the string in scientific notation aka
C&lt;1e+2&gt; instead of C&lt;100&gt;. Be advised that overloaded 'eq' always uses bstr()
for comparison, but Perl represents some numbers as 100 and others as 1e+308.
If in doubt, convert both arguments to Math::BigInt before comparing them as
strings:

    use Test::More tests =&gt; 3;
    use Math::BigInt;

    $x = Math::BigInt-&gt;new('1e56');
    $y = 1e56;
    is($x,$y);                     # fails
    is($x-&gt;bsstr(), $y);           # okay
    $y = Math::BigInt-&gt;new($y);
    is($x, $y);                    # okay

Alternatively, simply use C&lt;&lt; &lt;=&gt; &gt;&gt; for comparisons, this always gets it
right. There is not yet a way to get a number automatically represented as a
string that matches exactly the way Perl represents it.

See also the section about L&lt;Infinity and Not a Number&gt; for problems in
comparing NaNs.

=item int()

C&lt;int()&gt; returns (at least for Perl v5.7.1 and up) another Math::BigInt, not a
Perl scalar:

    $x = Math::BigInt-&gt;new(123);
    $y = int($x);                           # 123 as a Math::BigInt
    $x = Math::BigFloat-&gt;new(123.45);
    $y = int($x);                           # 123 as a Math::BigFloat

If you want a real Perl scalar, use C&lt;numify()&gt;:

    $y = $x-&gt;numify();                      # 123 as a scalar

This is seldom necessary, though, because this is done automatically, like when
you access an array:

    $z = $array[$x];                        # does work automatically

=item Modifying and =

Beware of:

    $x = Math::BigFloat-&gt;new(5);
    $y = $x;

This makes a second reference to the B&lt;same&gt; object and stores it in $y. Thus
anything that modifies $x (except overloaded operators) also modifies $y, and
vice versa. Or in other words, C&lt;=&gt; is only safe if you modify your
Math::BigInt objects only via overloaded math. As soon as you use a method call
it breaks:

    $x-&gt;bmul(2);
    print "$x, $y\n";       # prints '10, 10'

If you want a true copy of $x, use:

    $y = $x-&gt;copy();

You can also chain the calls like this, this first makes a copy and then
multiply it by 2:

    $y = $x-&gt;copy()-&gt;bmul(2);

See also the documentation for overload.pm regarding C&lt;=&gt;.

=item Overloading -$x

The following:

    $x = -$x;

is slower than

    $x-&gt;bneg();

since overload calls C&lt;sub($x,0,1);&gt; instead of C&lt;neg($x)&gt;. The first variant
needs to preserve $x since it does not know that it later gets overwritten.
This makes a copy of $x and takes O(N), but $x-&gt;bneg() is O(1).

=item Mixing different object types

With overloaded operators, it is the first (dominating) operand that determines
which method is called. Here are some examples showing what actually gets
called in various cases.

    use Math::BigInt;
    use Math::BigFloat;

    $mbf  = Math::BigFloat-&gt;new(5);
    $mbi2 = Math::BigInt-&gt;new(5);
    $mbi  = Math::BigInt-&gt;new(2);
                                    # what actually gets called:
    $float = $mbf + $mbi;           # $mbf-&gt;badd($mbi)
    $float = $mbf / $mbi;           # $mbf-&gt;bdiv($mbi)
    $integer = $mbi + $mbf;         # $mbi-&gt;badd($mbf)
    $integer = $mbi2 / $mbi;        # $mbi2-&gt;bdiv($mbi)
    $integer = $mbi2 / $mbf;        # $mbi2-&gt;bdiv($mbf)

For instance, Math::BigInt-&gt;bdiv() always returns a Math::BigInt, regardless of
whether the second operant is a Math::BigFloat. To get a Math::BigFloat you
either need to call the operation manually, make sure each operand already is a
Math::BigFloat, or cast to that type via Math::BigFloat-&gt;new():

    $float = Math::BigFloat-&gt;new($mbi2) / $mbi;     # = 2.5

Beware of casting the entire expression, as this would cast the
result, at which point it is too late:

    $float = Math::BigFloat-&gt;new($mbi2 / $mbi);     # = 2

Beware also of the order of more complicated expressions like:

    $integer = ($mbi2 + $mbi) / $mbf;               # int / float =&gt; int
    $integer = $mbi2 / Math::BigFloat-&gt;new($mbi);   # ditto

If in doubt, break the expression into simpler terms, or cast all operands
to the desired resulting type.

Scalar values are a bit different, since:

    $float = 2 + $mbf;
    $float = $mbf + 2;

both result in the proper type due to the way the overloaded math works.

This section also applies to other overloaded math packages, like Math::String.

One solution to you problem might be autoupgrading|upgrading. See the
pragmas L&lt;bignum&gt;, L&lt;bigint&gt; and L&lt;bigrat&gt; for an easy way to do this.

=back

=head1 BUGS

Please report any bugs or feature requests to
C&lt;bug-math-bigint at rt.cpan.org&gt;, or through the web interface at
L&lt;https://rt.cpan.org/Ticket/Create.html?Queue=Math-BigInt&gt; (requires login).
We will be notified, and then you'll automatically be notified of progress on
your bug as I make changes.

=head1 SUPPORT

You can find documentation for this module with the perldoc command.

    perldoc Math::BigInt

You can also look for information at:

=over 4

=item * GitHub

L&lt;https://github.com/pjacklam/p5-Math-BigInt&gt;

=item * RT: CPAN's request tracker

L&lt;https://rt.cpan.org/Dist/Display.html?Name=Math-BigInt&gt;

=item * MetaCPAN

L&lt;https://metacpan.org/release/Math-BigInt&gt;

=item * CPAN Testers Matrix

L&lt;http://matrix.cpantesters.org/?dist=Math-BigInt&gt;

=back

=head1 LICENSE

This program is free software; you may redistribute it and/or modify it under
the same terms as Perl itself.

=head1 SEE ALSO

L&lt;Math::BigFloat&gt; and L&lt;Math::BigRat&gt; as well as the backend libraries
L&lt;Math::BigInt::FastCalc&gt;, L&lt;Math::BigInt::GMP&gt;, and L&lt;Math::BigInt::Pari&gt;,
L&lt;Math::BigInt::GMPz&gt;, and L&lt;Math::BigInt::BitVect&gt;.

The pragmas L&lt;bigint&gt;, L&lt;bigfloat&gt;, and L&lt;bigrat&gt; might also be of interest. In
addition there is the L&lt;bignum&gt; pragma which does upgrading and downgrading.

=head1 AUTHORS

=over 4

=item *

Mark Biggar, overloaded interface by Ilya Zakharevich, 1996-2001.

=item *

Completely rewritten by Tels L&lt;http://bloodgate.com&gt;, 2001-2008.

=item *

Florian Ragwitz E&lt;lt&gt;flora@cpan.orgE&lt;gt&gt;, 2010.

=item *

Peter John Acklam E&lt;lt&gt;pjacklam@gmail.comE&lt;gt&gt;, 2011-.

=back

Many people contributed in one or more ways to the final beast, see the file
CREDITS for an (incomplete) list. If you miss your name, please drop me a
mail. Thank you!

=cut
</pre></body></html>